エクセルVBAを使用し、指定のパワーポイントをPDF保存する方法

エクセルVBAを使用して既存のパワーポイントをPDF保存したいのですが
検索してもPDF保存する方法が見つけられません。

エクセルでもワードでもExportAsFixedFormatを使用して保存ができるようなのですが
パワーポイントの場合は使用できないのでしょうか。

どなたかわかる方がいらっしゃればご教示ください。

No.2 ベストアンサー 回答者： Qchan1962 回答日時： 2020/05/27 13:30

＃１です

記憶が多分だったので、確かめる為、休憩時間にサンプルを作りました。
Microsoft PowerPoint xx.0 Object Library　を参照設定　必須
参考

Sub PPT_pdf()
　 Dim ppt As New PowerPoint.Application
　 Dim pres As PowerPoint.Presentation
　 Dim save_path As String, file_name As String
　 Dim Target As String
　 Target = Application.GetOpenFilename("PowerPoint,*.pptx")
　 If Target = "False" Then Exit Sub
　 Set pres = ppt.Presentations.Open(Target, WithWindow:=MsoTriState.msoFalse)

　 With pres
　　 save_path = CreateObject("WScript.Shell").SpecialFolders("Desktop")
　　 file_name = "Test"
　　 .ExportAsFixedFormat _
　　　　　 Path:=save_path & "\" & file_name & ".pdf", _
　　　　　 FixedFormatType:=ppFixedFormatTypePDF
　 End With
　 ppt.Quit
　 MsgBox ("PDF出力しました")
End Sub

デスクトップにTest名で保存されるはずです。。

この回答へのお礼

こんにちは。
いただいたサンプルで作成したところ成功しました。
大変助かりました。
ありがとうございました。

お礼日時：2020/05/27 14:00

No.1 回答者： Qchan1962 回答日時： 2020/05/27 12:11

こんにちは、

PowerPoint側を操作するので、
Microsoft PowerPoint xx.0 Object Library　を参照設定して
Presentationをアクティブにし
Presentation.ExportAsFixedFormatメソッドで実行できるかと思います。
例：
ActivePresentation.ExportAsFixedFormat _
Path:=フルパス & "\" & ファイル名 & ".pdf", _
FixedFormatType:=ppFixedFormatTypePDF