ExcelVBAで配列２つを結合させて重複アドレスを削除したいです

ExcelA列、B列の2行目からメールアドレスが行方向に複数記載されている状態で、条件が合うときにA列、B列記載のメールアドレス両方にメール配信したいため、配列２つを結合させて重複アドレスを削除したいです。どうすればできるでしょうか。

No.3 ベストアンサー 回答者： Qchan1962 回答日時： 2023/04/28 19:27

書き忘れ

ReDim Preserve arr(n)　は　上に条件を書く事を想定した場合・・
条件がない場合
ReDim arr(対象範囲.count)　で　ループ前に設定する方が処理が早いです

No.2 回答者： Qchan1962 回答日時： 2023/04/28 19:22

こんばんは

ご質問を斜めから見ると多分外してるｗ（的外れなら忘れてください）

＞条件が合うときに　は分かりませんが　A列B列にメールアドレスがあるのは　個人と会社とかPCとスマホとかでしょうか・・
会社（共通）などの場合は同じアドレスに複数同じメールが送信されるのを避けたいと言う事なのでしょうか？（個人、会社１通ずつは仕方ないとして）

そのような場合は、条件に合うメールアドレス（対象者）をまとめます
既にA列B列のデータがまとめたデータだとすると
そのアドレスデータの重複を削除すれば良い事になるので
元データを残す形の例として
シート関数のUniqueやおなじみのScripting.Dictionaryを使えば容易です

Unique　（要：Excel365同等）
Sub sample()
Dim cell As Variant
Dim arr()
Dim n As Long
'配列を作成（注：B列最終行を範囲としています）
For Each cell In Range(Cells(1, 1), Cells(Rows.Count, 2).End(xlUp))
ReDim Preserve arr(n)
arr(n) = cell
n = n + 1
Next
Dim arrUnique As Variant
'配列から重複を除く
arrUnique = WorksheetFunction.Unique(arr, True)
'D列に出力
Range("D1").Resize(UBound(arrUnique)) = Application.Transpose(arrUnique)
End Sub

Dictionaryならば
Sub sample_01()
Dim Dic
Set Dic = CreateObject("Scripting.Dictionary")
Dim address_data
'値を配列に
address_data = Range(Cells(1, 1), Cells(Rows.Count, 2).End(xlUp))
Dim i As Long, j As Long
For i = 1 To UBound(address_data, 1) '行方向
For j = 1 To UBound(address_data, 2) '列（次元）方向
'登録されていない場合
If Not Dic.exists(address_data(i, j)) Then
Dic.Add address_data(i, j), 0
End If
Next
Next
'D列に出力
Range("D1").Resize(Dic.Count) = Application.Transpose(Dic.keys)
Set Dic = Nothing
End Sub

No.1 回答者： fujillin 回答日時： 2023/04/25 16:41

こんにちは

VBAでとのご質問ですが、通常の操作でも簡単にできます。

　1）A列、B列をコピペで、C列1列に並べる。
　2）C列を選択して、「データ」-「重複の削除」を実行
以上で、お求めの結果が得られると思います。


どうしてもVBAでなさりたい場合は・・
上記の操作を「マクロの記録」で行えば、ほぼ出来上がります。