エクセル関数 １つのセル内文字カウント

1つのセル内の文字をカウントしたいのですが、その中に、スペースや改行がはいっています。
スペースや改行ま1文字としてカウントせずに、無視して、文字だけカウントすることができるのでしょうか。
さらに、その際、
1)全角文字だけカウント
2)半角文字だけカウント
3)全角+半角それぞれ1としてカウント
したいのですが、そんなことできるのでしょうか？

No.3 ベストアンサー 回答者： saburo0 回答日時： 2008/08/12 22:04

＃１さんの回答を参考にさせて頂きました。

（こういった補足は＃１さんの意図に背いているのかもしれませんが、普通の方は分からないと思いますので。）

A1「a k3　b(改行)あ(改行)け　に 」（例）
B1「(改行)」
A2「=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A1," ",""),"　",""),B1,"")」・全角空白・半角空白・改行を削除
A3「=LEN(A2)」→7　(3)全角+半角それぞれ1としてカウント
A4「=LENB(A2)」→10　・全角2バイト・半角1バイトとしバイト数をカウント
A5「=A4-A3」→3　(1)全角文字だけカウント
A6「=A3-A5」→4　(2)半角文字だけカウント

ご確認お願いいたします。

この回答へのお礼

ありがとうございます。
エクセルが得意でないので、わかりやすい解説ありがとうございます。

お礼日時：2008/08/13 09:18

No.4 回答者： hallo-2007 回答日時： 2008/08/12 22:30

No2です。

改行も無視ですね
SUBSTITUTE(SUBSTITUTE(A1," ",""),"　","")
を
SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A$1,CHAR(10),"")," ",""),"　","")
に置き換えてください。

この回答へのお礼

ありがとうございます。
早速試してみます。

お礼日時：2008/08/13 09:17

No.2 回答者： hallo-2007 回答日時： 2008/08/12 21:59

取り合えず　半角スペース　全角スペース　を除いた文字列

3)全角+半角それぞれ1としてカウント
=LEN(SUBSTITUTE(SUBSTITUTE(A1," ",""),"　",""))
1)全角文字だけカウント
=LENB(SUBSTITUTE(SUBSTITUTE(A1," ",""),"　",""))-LEN(SUBSTITUTE(SUBSTITUTE(A1," ",""),"　",""))
2)半角文字だけカウント
=LEN(SUBSTITUTE(SUBSTITUTE(A$1," ",""),"　",""))*2-LENB(SUBSTITUTE(SUBSTITUTE(A$1," ",""),"　",""))
で試してみてください。

この回答へのお礼

ありがとうございます。
このままコピペで使わせていただきます。

お礼日時：2008/08/13 09:18

No.1 回答者： marbin 回答日時： 2008/08/12 21:14

LENB関数

LEN関数
SUBSTITUTE関数
を関数ヘルプで調べてみましょう。
参考になると思います。

この回答へのお礼

SUBSTITUTE関数
つかったことなかったので、見てみます。

お礼日時：2008/08/13 09:19