1,2,3を3,2,1に出来ますか

Office 2004を使用しております。
たとえば、
1,2,3,4と書いたところを4,3,2,1と逆にする事は出来るのでしょうか。
ご存知の方がおられましたらご教示よろしくお願い致します。
論文を書いていて、打ち直すがとても面倒で頭を痛めております。

No.3 回答者： Wendy02 回答日時： 2009/01/12 16:45

こんにちは。

なるべく、Normal.Dot に登録してください。Alt + F11 で、VBEditor を開き、挿入--標準モジュールを設けて、以下を貼り付けて、一旦、Word を閉じてください。

開けたら、マウスの右メニューに「テキスト逆転」という名称で登録されているはずですから、確認してください。

使い方：

1,2,3,4
とあったら、マウスで選択して、右クリック--「テキスト逆転」をクリックします。
このマクロは、半角空白があると、一旦、取り去られます。再び戻す段で、コンマ+半角空白が入ります。半角空白が不要なら、以下にコメントが書かれている場所を調整してください。

コンマのないものは、何も起こりません。また、「1,2,3,4と書いたところを」とまで選択してしまったら、「4と書いたところを, 3, 2, 1」となりますから、ご注意ください。失敗したら、Ctrl + Z として戻せばよいです。

'------------------------------------------

'標準モジュール

Sub AutoOpen()
　　On Error Resume Next
　　With Application.CommandBars("TEXT")
　　　　.Controls("テキスト逆転").Delete
　　End With
　 On Error GoTo 0
　　With Application.CommandBars("TEXT").Controls.Add _
　　　　(Type:=msoControlButton, Temporary:=True)
　　　　.BeginGroup = False
　　　　.Caption = "テキスト逆転"
　　　　.OnAction = "ConverseText"
　　End With
End Sub

Sub ConverseText()
　　Dim r As Range
　　Dim sData As String
　　Dim i As Integer
　　Dim j As Integer
　　Dim ar As Variant
　　Dim arT As Variant
　　Dim crFlg As Integer
　　
　　With Selection
　　　　sData = ""
　　　　crFlg = 0
　　　　Set r = Selection.Range
　　　　sData = Trim(r.Text)
　　　　If InStr(sData, vbCr) > 0 Then
　　　　　　sData = Replace(sData, vbCr, "")
　　　　　　crFlg = 1
　　　　End If
　　　　If Len(sData) - Len(Replace(sData, ",", "")) > 0 Then
　　　　　　ar = Split(sData, ",")
　　　　　　arT = ar
　　　　　　For i = UBound(ar) To LBound(ar) Step -1
　　　　　　　　arT(j) = Trim(ar(i))
　　　　　　　　j = j + 1
　　　　　　Next i
　　　　　　sData = Join(arT, ", ")
　　　　　　r.Text = sData & String(crFlg, vbCr)
　　　　End If
　　End With
End Sub

No.2 回答者： marbin 回答日時： 2009/01/12 13:53

Mac用？

エクセルなら
データ→区切り位置
で","を区切り文字に指定して分割転記
↓
セル範囲を降順でソート
↓
=A1&","&B1&","&・・・・

のように2,"を挟みながら文字列を結合
とできます。

Win用のエクセルで試してますのでMacで出来るかは
不明です。

VBAなら配列に格納して逆から文字列を取り出して行って
蓄積、というのもできます。

この回答への補足

早速ご教示有り難うございます。
説明不足のところを補わせていただきます。
Mac OS10.4, office 2004
Wordで、文章中に有る数値を、
123, 456, 789と書いたのを
789, 456, 123と何か操作で出来る方法はないかと悩んでおります。
具体的には、本来数値の大きい順位書くべきところを小さい順に書いてしまいました。
よろしくお願い致します。

補足日時：2009/01/12 15:03

No.1 回答者： TinyPine 回答日時： 2009/01/12 13:45

1,2,3,4と書いたところを4,3,2,1と逆にする事は出来るのでしょうか。

1,2,3,4と書かれた複数箇所を4,3,2,1にするなら、編集の置換で可能です。

1,2,3 や　5,6　など不特定の部分を直すと言う意味でしたら、その様に変換するプログラムを作成すれば可能ですが、普通の方には出来ないと思います。

この回答への補足

早速ご教示有り難うございます。
説明不足のところを補わせていただきます。
Mac OS10.4, office 2004
Wordで、文章中に有る数値を、
123, 456, 789と書いたのを
789, 456, 123と何か操作で出来る方法はないかと悩んでおります。
具体的には、本来数値の大きい順位書くべきところを小さい順に書いてしまいました。
よろしくお願い致します。

補足日時：2009/01/12 14:55