EXCELで共通の日付を合わせたい。

列１には日付、列２にはデーター１
列３には別の日付、列４にはデーター２
列１の日付は、ばらばら（歯抜け）で、列３の日付もばらばら（歯抜け）です。
列１と列３を同じ日付のところだけを並べて横一列に共通の日付のデーター１，２を
比較したいのですができますでしょうか？

No.5 ベストアンサー 回答者： sakenomo 回答日時： 2003/10/19 12:14

#3です。

何度もすみません。

Ｇ1は、

=IF(COUNT($F$1:$F$13)<ROW(),"",INDEX($A$1:$B$13,SMALL($F$1:$F$13,ROW()),1))

としていただいたほうが、式がすっきりしていて良いかもしれません。

この回答へのお礼

うまくできました。ありがとうございます。でも式はけっこうたいへんですね

お礼日時：2003/10/20 16:37

No.4 回答者： sakenomo 回答日時： 2003/10/18 22:31

＃3です。

訂正です。

＞A1:13とC1:13に日付、A1:13 D1:13にデータがあるとします。

A1:13とC1:13に日付、B1:13 D1:13にデータがあるとします。

No.3 回答者： sakenomo 回答日時： 2003/10/18 16:42

A1:13とC1:13に日付、A1:13 D1:13にデータがあるとします。

F列を作業列として使います。

F1に、
=IF(COUNTIF($C$1:$C$13,A1),ROW(),"")

G1に、
=IF(ISERROR(INDEX($A$1:$B$13,SMALL($F$1:$F$13,ROW()),1)),"",INDEX($A$1:$B$13,SMALL($F$1:$F$13,ROW()),1))

H1に、
=IF(G1<>"",INDEX($A$1:$B$13,SMALL($F$1:$F$13,ROW()),2),"")

I1に、
=IF(G1<>"",VLOOKUP(G1,$C$1:$D$13,2,FALSE),"")

を入れて下へオートフィルでいかがでしょう。

なお、C列中に重複した日付があると、D列に拾えないデータが出ますのでご注意ください。

No.2 回答者： imogasi 回答日時： 2003/10/17 22:57

（データ）

A1:B3に
2003/10/1　　　　23
2003/10/3　　　　13
2003/10/12　　　　34
C1:D3に
2003/9/23　　　　　45
2003/10/123
2003/10/2517
として
（関数式）
F1に
=IF(ISERROR(VLOOKUP(C1,$A$1:$B$3,2,FALSE)),"",VLOOKUP(C1,$A$1:$B$3,2,FALSE))
といれ、F3まで複写する。
E2だけ３４となります。
一致する日付けだけ直ぐ右に持ってきて比べればよいなら
これで良いでしょうが、一致しないものを、上例で
AとB列をCとD列に持ってくるのは、やはり＝VLOOKUP（）
を使って出来ます。
C4に
=IF(ISERROR(VLOOKUP(A1,$C$1:$C$3,1,FALSE)),A1,"")
といれ下に複写、
E4に
=IF(ISERROR(VLOOKUP(A1,$C$1:$C$3,1,FALSE)),B1,"")
といれ下に複写です。
但し行は歯抜け状態になります。

No.1 回答者： ozigakura 回答日時： 2003/10/17 18:33

vlookup（列１のセル,範囲列3:列4,2,false)で

列１のセルと列３の同じ日付のデータが来ます。

データが無いなどエラーの出たセルは編集ジャンプで一括削除する。