EXCEL VBA コントロールのコピー＆ペースト

いつも活用させて頂いております。

excelのvbaで、コピー元のセルを範囲指定して、ペーストするロジックを書いています。
コピー元のセルには、コントロール（テキストボックスなど）が配置されているのですが、これを一緒にコピー＆ペーストする事はできないでしょうか？
一緒にできないのであれば、セルのコピー＆ペーストのあとにコントロールのコピー＆ペーストができるような方法があれば、ご教授願います。

よろしくお願い致します。

No.1 ベストアンサー 回答者： nishi6 回答日時： 2001/05/16 01:45

コントロールは編集モードならコピーできると思いますが、実行モードで普通にコピー＆ペーストを行ってもできないと思われます。

素人の力技ですが下記マクロを作ってみました。おもしろい問題でけっこうはまってしまいました。
長くなるので選択状態のチェック等は行っていません。m(_ _)m
同一シートのみで可能です。標準モジュールに貼り付けます。
ショートカットキー Ctrl+Shift+A 等に割り当てて下さい。
コピー元を選択し、コントロールキーを押しながら貼り付け先の左上セルを選択します
順番は逆でもかまいません。複数セルが含まれる矩形セル範囲と単一のセルが指定されていることが要件です。
（これは単一セルと単一セルのコピーと他シートへのコピーは対応していません。）
参考にして下さい。

Public Sub ShapesCopy()
Dim rgCopy As Range 'コピー元セル範囲
Dim rgPaste As Range '貼り付けるセル（左上）
Dim rgShape As Range 'コピー元にあるコントロールの左上セル
Dim myShape As Object '１つのコントロール
Dim rowCopy, clmCopy As Long 'コピー元の左上セルの行、列番号
Dim rowPaste, clmPaste As Long '貼り付けるセルの行、列番号
Dim disRow, disClm As Long 'コピー元と貼り付け先の行・列の隔たり

'*** 選択セルをコピー元と貼り付け先に分離 ***
With Selection
If .Areas(1).Count = 1 Then
Set rgCopy = .Areas(2)
Set rgPaste = .Areas(1)
ElseIf .Areas(2).Count = 1 Then
Set rgCopy = .Areas(1)
Set rgPaste = .Areas(2)
Else
Exit Sub '厳重なチェックは省略しています。
End If
End With

'*** コピー元と貼り付け先の隔たりを計算 ***
rowCopy = rgCopy.Cells(1, 1).Row
clmCopy = rgCopy.Cells(1, 1).Column
rowPaste = rgPaste.Cells(1, 1).Row
clmPaste = rgPaste.Cells(1, 1).Column
disRow = rowPaste - rowCopy '行の隔たり
disClm = clmPaste - clmCopy '列の隔たり

'*** コピー実行 ***
'===== セル =====
rgCopy.Copy: rgPaste.Select: ActiveSheet.Paste
'===== コントロール =====
For Each myShape In ActiveSheet.Shapes 'シート内のコントロールを探す
Set rgShape = Range(myShape.TopLeftCell.Address)
If Union(rgCopy, rgShape).Address = rgCopy.Address Then
'コントロールの左上セルがコピー元内にある場合はコピーする
myShape.Copy
Range(rgShape.Address).Offset(disRow, disClm).Select
ActiveSheet.Paste
End If
Next
rgPaste.Select
End Sub

この回答へのお礼

力作をありがとうございます。

せっかく作成していただいて申し訳ないのですが、
VBAでコピー範囲を選択してペーストしたら図も一緒にペーストされました。

そのソースをいかに示します。
Dim xl As Object
xl.Application.Sheets("TEMP").Range("A1:AN34").Copy xl.Application.Sheets("DATA").Range("A" & CStr(1 + 34 * TotalPage))

これで、TEMPシートのA1:AN34をコピーして、
DATAシートのA列(1 + 34 * TotalPage)行目にペーストしました。

私は別の方法でコピー＆ペーストしていたのですが、
同僚がこのロジックで図のペーストができたというので試してみたら、本当にできました。

ご迷惑をおかけしました。
ありがとうございました。

お礼日時：2001/05/16 11:29