gooドクター有料プランが1ヶ月間無料!

Excel2013で開いているブックを丸ごとコピーして、コピーしたブックの名前の月を翌月に進めたいのですが、どうすればよいでしょうか?
現在は、とりあえず以下のような感じで一応コピーはできますが、名前は固定です。
「2014-11月.xlsm」のブックコピーのvbaを実行すると、「2014-12月.xlsm」のブックが作成され、、「2014-12月.xlsm」のブックのvba実行で、、「2015-1月.xlsm」のブックができるようにしていきたいです。

どうすれば実現できるでしょうか?

Sub ブックコピー()

ThisWorkbook.SaveCopyAs "D:\***\Desktop\サンプル\2014-12月.xlsm"

End Sub

gooドクター

A 回答 (3件)

>追加で、もし年が変わったら、例えば来年なら「2015年」のフォルダを>


>自動で作成してそちらに保存するようにできますか?
>フォルダの作成場所は現在の一つ上の階層に作りたいです。
>現ファイルは2014年のフォルダ内に存在しています。

現在のフォルダ「2014年」と同階層に「2015年」、「2016年」・・・を作成するようにしました。

>また、すでにファイルが存在している場合は、
>警告を出して複製しないようにしたいです。

既に存在する場合は上書きの確認ではなく、処理を中止するようにしています。


■VBAコード

Sub ブックコピー()
Dim myDir_path As String, myNew_path As String
'フォルダパスとファイルパスを作成
myDir_path = Left(ThisWorkbook.FullName, InStrRev(ThisWorkbook.FullName, "\") - 1)
myNew_path = Format(DateAdd("m", 1, DateValue(Replace(ThisWorkbook.Name, "月.xlsm", "-1"))), "yyyy-m") & "月.xlsm"
myDir_path = Left(myDir_path, InStrRev(myDir_path, "\")) & Left(myNew_path, 4) & "年\"
'フォルダの有無を確認、なければ作成
With CreateObject("Scripting.FileSystemObject")
  If Not .FolderExists(myDir_path) Then
    MkDir myDir_path
  End If
End With
'ファイルの有無を確認、なければ保存
If Dir(myDir_path & myNew_path) = "" Then
  ThisWorkbook.SaveCopyAs myDir_path & myNew_path
Else
  MsgBox "重複するファイルが存在します。", vbOKOnly, "保存失敗"
End If
End Sub
    • good
    • 0
この回答へのお礼

すばらしいです。
思い通りのものです。
解説もつけていただけたので、これをもとにさらに手を加えて、色んなファイルに応用していけます。
どうもありがとうございました。

お礼日時:2014/10/10 20:16

現在開いているブックがあるフォルダに作成するよにしてみました。



出力先のフォルダが固定であれば「dir_path 」の宣言部分、「フォルダパスを取得」部分を削除したうえで、
「新規ファイル名で複製」部分の「dir_path 」を「"出力先のフォルダパス\"」としてください。

翌月のデータが既に存在している場合、警告なしに上書きされます。
上書きせず、添え字を付けるまたは上書きの確認をする必要がある場合は補足願います。


■VBAコード

Sub ブックコピー()
Dim dir_path As String, file_path As String, next_Date As String
'フォルダパスを取得
dir_path = Left(ThisWorkbook.FullName, InStrRev(ThisWorkbook.FullName, "\"))
'現在のブック名を格納
file_path = ThisWorkbook.Name
'現在のファイル名から「年-月」を取得
next_Date = Left(file_path, InStr(1, file_path, "月") - 1)
'取得した日付に31日を加えて翌月の「年-月」を取得
next_Date = Format(DateValue(next_Date & "-1") + 31, "yyyy-m")
'新規ファイル名で複製
ThisWorkbook.SaveCopyAs dir_path & next_Date & "月.xlsm"
End Sub

この回答への補足

すいません、先ほどの補足にもれがあり追記しました。
両方ともばっちりうまく動作しました。
追加で、もし年が変わったら、例えば来年なら「2015年」のフォルダを自動で作成してそちらに保存するようにできますか?
フォルダの作成場所は現在の一つ上の階層に作りたいです。現ファイルは2014年のフォルダ内に存在しています。
また、すでにファイルが存在している場合は、警告を出して複製しないようにしたいです。
すいません、お手数ですがよろしくお願いします。

補足日時:2014/10/09 22:47
    • good
    • 2
この回答へのお礼

動作の説明を入れてくださって何となく動作がイメージできます。
どうもありがとうございます。

お礼日時:2014/10/10 20:27

こんな感じかな


実際に使うときは変数宣言やエラー処理なども入れた方が良いと思います。

Sub ブックコピー()
  sOldName = Replace(Replace(ThisWorkbook.Name, "-", "年"), ".xlsm", "1日")
  dNewName = DateAdd("m", 1, DateValue(sOldName))
  ThisWorkbook.SaveCopyAs "D:\***\Desktop\サンプル\" & Format(dNewName, "YYYY-M") & "月.xlsm"
End Sub
    • good
    • 0
この回答へのお礼

シンプルによくまとまったコードで、ばっちり動作しました。変数宣言を入れて試してみましたが問題なく動作しました。どうもありがとうございました。

お礼日時:2014/10/10 20:19

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!

このQ&Aを見た人はこんなQ&Aも見ています

gooドクター

このQ&Aを見た人がよく見るQ&A

人気Q&Aランキング