エクセル マクロ 範囲指定で、データの最終行・最終列を取得したい

●ソートさせるときの範囲を、データ最終位置まで自動で取得してソートさせたいです。。とりあえずエリアを指定してのソートは出来ました！
Range("A5:AQ120").Sort _
Key1:=Range("b5"), _
Order1:=xlAscending, _
Header:=xlYes
●列の幅を指定したいのですが、F~データのある最終列にしたいです。。
Columns("F:K").ColumnWidth = 12

No.2 ベストアンサー 回答者： tom04 回答日時： 2016/03/05 20:38

こんばんは！

一例です。

Sub Sample1()
Dim lastRow As Long, lastCol As Long
lastRow = Cells(Rows.Count, "A").End(xlUp).Row '←A列で最終行取得//
lastCol = Cells(5, Columns.Count).End(xlToLeft).Column '←5行目で最終列取得//
Range(Cells(5, "A"), Cells(lastRow, lastCol)).Sort key1:=Range("B5"), order1:=xlAscending, Header:=xlYes
Range(Columns("F"), Columns(lastCol)).ColumnWidth = 12
End Sub

こんな感じではどうでしょうか？m(_ _)m

この回答へのお礼

ありがとうございます！初心者の私にはわかりやすかったです^^　動作、バッチリでした！！覚えておいて今後どんどん活用していきたいです！

お礼日時：2016/03/05 21:14

No.3 回答者： soixante 回答日時： 2016/03/05 20:48

最終行の取得としては、たとえば、

Dim LstRow As Long
LstRow=Cells(Rows.Count,1).End(xlUp).Row
で行けます。
つまり、A列の最終行から上に遡ってぶち当たる行、ということです。

同様に最終列の取得は、たとえば
Dim LstCol As Long
LstCol =Cells(1,Columns.Count).End(xlToLeft).Column
で行けます。
１行目の最終列から左に遡ってぶち当たる列、ということです。

データの入力状況に応じて、上記の「A列」や、「１行目」のところはアレンジしてください。

それを踏まえて、ご質問の状況に当てはめれば、たとえば以下。

Dim Rng1 As Range, Rng2 As Range, LstRow As Long, LstCol As Long
LstRow=Cells(Rows.Count,1).End(xlUp).Row　　　’最終行を変数LstRowに入れる
LstCol =Cells(1,Columns.Count).End(xlToLeft).Column　’最終列を変数LstCol に入れる

Set Rng1 = Range(Cells(5,1),Cells(LstRow,43)) 'A5～AQ最終行の範囲を変数Rng1に格納
Rng.Sort _
Key1:=Cells(5,2), Order1:=xlAscending,Header:=xlYes

Set Rng2 = Range(Columns(6),Columns(LstCol)) 'F列から最終列の範囲を変数Rng2に格納
Rng2.ColumnWidth=12

Set Rng1=Nothing
Set Rng2=Nothing

とか。

この回答へのお礼

ありがとうございます、初心者の私には少し難しかったですが、遡ってぶち当たるという概念がわかりやすかったです！Rngに格納というのを使った事がまだありませんでしたので、大変参考になりました。

お礼日時：2016/03/05 21:18

No.1 回答者： mananama77 回答日時： 2016/03/05 20:21

最終行を取得する場合は、

Cells(1, 1).End(xlDown).Rowです。

http://excel-ubara.com/excelvba4/EXCEL222.html
こちらに詳しく載っていますので参考になさってください。

この回答へのお礼

ありがとうございます、ご案内いただきましたサイトを拝見させていただき参考になりました！

お礼日時：2016/03/05 21:13