Excel関数 条件付き

エクセル初心者なもので、教えていただきたいと思います。

次のような表示をしたい場合の関数、もしくは設定方法をご存知方いらっしゃいましたらお願いします。

前提
・セルA1は「yes」「no」を選択する
・セルB1は数量を入力する
・セルC1は「a」「b」「c」のうち一つを選択する

質問1
セルA1で「no」を選択した場合、セルB1に数量を入力すると「-(マイナス)」の符号がつくようにしたい。
数量は入力時に自身で「-」をつけて入力した場合もつけずに入力した場合も、符号がつくようにしたい。

例
・セルA1で「yes」を選択→セルB1に「10」を入力→セルB1「10」と表示
・セルA1で「no」を選択→セルB1に「10」を入力→セルB1「-10」と表示
・セルA1で「no」を選択→セルB1に「-10」を入力→セルB1に「-10」と表示

質問2
セルA1で選択した結果により、セルC1で選択できる項目を制限したい。

例
セルA1で「yes」を選択→セルC1で「a」「b」が選択肢としてタブ(?)に表示される
セルB1で「no」を選択→セルC1で「b」「c」が選択肢としてタブに表示される


稚拙な文章で申し訳ございません。
エクセルに詳しい方いらっしゃいましたら、お力添えいただければと思います。
よろしくお願いします。

No.1 回答者： tom04 回答日時： 2016/12/25 23:27

こんばんは！

＞A1セルが「yes」の場合、B1セルの数値がマイナスでも手を付けなくてよいのですね？
（A1セルが「no」の場合のみB1セルをマイナスにする）

VBAになりますが一例です。
尚、A1セルは入力規則のリスト設定がしてあり、「yes」または「no」のどちらかが選択できる状態だとします。
C1セルは手を付けなくて大丈夫です。

シートモジュールにしてください。

Private Sub Worksheet_Change(ByVal Target As Range) 'この行から//
If Intersect(Target, Range("A1:B1")) Is Nothing Or Target.Count > 1 Then Exit Sub
With Target
If .Column = 1 Then '←A1セルの場合//
.Offset(, 2).ClearContents
If .Value = "no" Then
If .Offset(, 1) <> "" Then
.Offset(, 1) = Abs(.Offset(, 1)) * -1
End If
End If
If .Value = "yes" Then
With .Offset(, 2).Validation
.Delete
.Add Type:=xlValidateList, Operator:=xlEqual, Formula1:="a,b"
End With
Else
With .Offset(, 2).Validation
.Delete
.Add Type:=xlValidateList, Operator:=xlEqual, Formula1:="b,c"
End With
End If
Else '←B1セルの場合//
If .Value <> "" Then
If IsNumeric(.Value) Then
If .Offset(, -1) = "no" Then
Application.EnableEvents = False
.Value = Abs(.Value) * -1
Application.EnableEvents = True
End If
Else
MsgBox "数値を入力してください。"
.Select
End If
End If
End If
End With
End Sub 'この行まで//

※　じっくり考えればもっと簡単になるかもしれませんが、
まずはこの程度で・・・m(_ _)m

この回答へのお礼

ご教授頂きありがとうございます。
設定したところ、無事出来ました！
厚かましくも、追加でもう一点教えて頂きたいのですが、
C1で表示される選択肢が3つ以上あり(1-10)、
A1でnoを選択した場合、そのうちの1.4.5が表示される。yesの時はそれ以外。
としたい場合はどのようになりますでしょうか？

お礼日時：2016/12/26 08:57

No.2 ベストアンサー 回答者： tom04 回答日時： 2016/12/26 13:54

No.1です。

＞C1で表示される選択肢が3つ以上あり(1-10)、
＞A1でnoを選択した場合、そのうちの1.4.5が表示される。yesの時はそれ以外。
＞としたい場合はどのようになりますでしょうか？

前回のコードを2行だけ変更すれば大丈夫です。
どこの行とどこの行！といっても判りにくいと思いますので、
もう一度すべてのコードを載せておきます。

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, Range("A1:B1")) Is Nothing Or Target.Count > 1 Then Exit Sub
With Target
If .Column = 1 Then '←A1セルの場合//
.Offset(, 2).ClearContents
If .Value = "no" Then
If .Offset(, 1) <> "" Then
.Offset(, 1) = Abs(.Offset(, 1)) * -1
End If
End If
If .Value = "yes" Then
With .Offset(, 2).Validation
.Delete
.Add Type:=xlValidateList, Operator:=xlEqual, Formula1:="2,3,6,7,8,9,10" '★
End With
Else
With .Offset(, 2).Validation
.Delete
.Add Type:=xlValidateList, Operator:=xlEqual, Formula1:="1,4,5" '★
End With
End If
Else '←B1セルの場合//
If .Value <> "" Then
If IsNumeric(.Value) Then
If .Offset(, -1) = "no" Then
Application.EnableEvents = False
.Value = Abs(.Value) * -1
Application.EnableEvents = True
End If
Else
MsgBox "数値を入力してください。"
.Select
End If
End If
End If
End With
End Sub

※　コード内の「★」の行を変更しています。m(_ _)m

この回答へのお礼

丁寧なご説明ありがとうございます！
とてもとても助かりました！！
ベストアンサーに選ばせて頂きましたm(_ _)m

お礼日時：2016/12/27 08:10