指定した範囲の値で順番にソートをかけて、指定した表を印刷していくVBAについて

Question

Excel2010を使っている者です。
指定した範囲の値で順番に表①の任意の列にソートをかけて印刷していくVBAを作りたいと思っております。

具体的には、A1からA20の各セルに値が入力してあるのですが、表①（セル範囲はA30からＳ500）のＦ列に順番にソートをかけて、順次、印刷したいと思っております。

なお、A1からA20についてですが、上から順番に必要がある場合のみ値を入れるようになっているため、全てのセルは使わない可能性が高いです。（Ａ1からＡ8のみ値が入っている日もあれば、Ａ1からＡ15まで値が入っている日もあれば、Ａ1からＡ3までしか値が入ってないときもあればです）

私はネットで調べながら以下のようにVBAを作ってみたのですが、実行しようとすると「Nextに続くForがありません」というメッセージが出てしまいます。

どのような記述にすれば良いのか、ご教示願います。

ーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーー

Sub 印刷()

Dim i As Long

 For i = 1 To 20
 If Cells(i, 1) = "" Then
 Exit Sub
   Range("A30:S500").AutoFilter Field:=7, Criteria1:=Cells(i, 1).Value
 Next i
    
   ActiveSheet.PrintOut
    
End Sub

tom04 · Accepted Answer

こんばんは！
少しだけコードの説明を！

①　For k = 31 To 500　　”31行から500行までＫを使ってループを行う
本来であれば最終行を取得しそこまでのループにすればよいのですが、
必ず500行目まではデータがある！という前提のコードでした。

②　If Rows(k).Hidden = False Then　　”もし、Ｋ行が表示されていれば
myFlg = True　　”myflgにはTrueを入れる。
Exit For　　”ループをやめる？
End If　　”？
Next k　　”次の行の処理に移る？

フィルタを掛けるというコトは30行目は項目行でデータは31行以降にあると思い
31行目からその行が「表示」されているかどうか？を調べています。
＞End If　　”？
の部分は
＞If Rows(k).Hidden = False Then
に対する「End If」です。
仮に「myFlg」が「FALSE」である場合は「TRUE」になるまで、もしくは500行目までループします。

「myFlg」はBoolean型で宣言していますので、「FALSE」（初期値）か「TRUE」のどちらかになります。
仮に31行目が表示されているというコトは少なくとも1つ以上の該当データがあるので
「myFlg」を「TRUE」とし、それ以降ループしても無意味なのでそこでループを抜けます。
ただ、該当データがない場合は500行目まで「FALSE」となり続けます。

最終的に「myFlg」が「TRUE」なのか？「FALSE」なのかを判定し
「TRUE」の場合　→　該当データが1つ以上はあるので印刷プレビューへ
「FALSE」の場合　→　該当データが存在しないのでメッセージボックスを表示！
といった流れにしています。

最後の
End If　　”？　　（あ）
myFlg = False　　”？（い）
End If　　"？（う）
Next i

（あ）は
If myFlg = False Then
に対する「If」の「End If」になる。

（い）は
次のループに入り前に「myFlg」を初期値の「FALSE」に戻します。
これを行わないと常に「TRUE」のままになりデータがない場合でも印刷プレビューが表示されてしまう。

（う）の「End If」は
＞Next i
の前にあるので
＞If Cells(i, j) <> "" Then
に対する「End If」になります。

※　こちらのVBE画面は↓のように記載し、「End If」はどこの「If・・・」にかかっているのか
タブ送りで判りやすく訂正しやすいようにしているのですが
それをそのままこの画面にコピー＆ペーストすると
左寄せになってしまうので判りにくいですよね。m(_ _)m

tom04 · Answer

あぁ～～～！そういうコトだったのですね。

↓のコードに変更してみてください。

Sub Sample3()
 Dim i As Long, j As Long, myCol As Long
 Dim k As Long, myFlg As Boolean
 For j = 1 To 2 '←A～B列まで//
    If j = 1 Then
        myCol = 6   '←A列の場合はF列で//
    Else
        myCol = 7   '←B列の場合はG列で//
    End If
 For i = 1 To 20
 If Cells(i, j) <> "" Then
        Range("A30:S500").AutoFilter field:=myCol, Criteria1:=Cells(i, j)
            For k = 31 To 500
                If Rows(k).Hidden = False Then
                    myFlg = True
                    Exit For
                End If
            Next k
 If myFlg = False Then
 MsgBox "「" & Cells(i, j) & "」のデータなし"
Else
 ActiveSheet.PrintPreview '←印刷プレビューでやめています。//
End If
 myFlg = False
 End If
 Next i
    ActiveSheet.AutoFilterMode = False
 Next j
 End Sub

今度はどうでしょうか？m(_ _)m

tom04 · Answer

何度もごめんなさい。

No.3を投稿後今一度タイトルが気になったので顔をだしました。
＞順番にソートをかけて、指定した表を印刷していく・・・

「ソート＝並び替え」　となりますが
要するに順にフィルタをかけて該当データがあれば印刷するという解釈でよいのでしょうか？
その場合は↓のコードにしてみてください。

Sub Sample2()
    Dim i As Long, j As Long
    Dim k As Long, myFlg As Boolean
    For j = 1 To 2
    For i = 1 To 20
        If Cells(i, j) <> "" Then
            Range("A30:S500").AutoFilter field:=6, Criteria1:=Cells(i, j)
            For k = 31 To 500
                If Rows(k).Hidden = False Then
                    myFlg = True
                    Exit For
                End If
            Next k
                If myFlg = False Then
                    MsgBox "「" & Cells(i, j) & "」のデータなし"
                Else
                    ActiveSheet.PrintPreview    '←印刷プレビューでやめています。//
                End If
            myFlg = False
        End If
    Next i
    Next j
End Sub

※　コードは「印刷プレビュー」でやめていますので、すぐに印刷を実行する場合は
＞ActiveSheet.PrintPreview
を変更してください。m(_ _)m

tom04 · Answer

続けてお邪魔します。質問内容のコードをもう一度よく見てみると一つずつフィルタをかけているのでその都度印刷プレビューを表示させるようにしていました。あくまで憶測ですが・・・ A1～B20にオートフィルタの項目を入力し、複数の条件でフィルタを掛けたい！というコトなのでしょうか？ ↓の画像でいえばA1～B20セルに　「日・月・火・金」がありますので、 6列目（F列）が「日」か「月」か「火」か「金」をキーとしてフィルタを掛ける！といったことがお望みであれば今までのコードはお望みの動きにならないはずです。結構面倒になります。 Excel2007以降で使える（Excel2003まではオートフィルタのキーは三つまでしか設定できない）コードにしてみました。 Sub Sample1() Dim i As Long, c As Range, myFlg As Boolean Dim myStr As String, myAry As Variant For Each c In Range("A1:B20") If c <> "" Then myStr = myStr & c & "," End If Next c If myStr <> "" Then myAry = Array(Split(Left(myStr, Len(myStr) - 1), ",")) Range("A30:S500").AutoFilter field:=6, Criteria1:=myAry, Operator:=xlFilterValues For i = 31 To 500 If Rows(i).Hidden = False Then myFlg = True Exit For End If Next i If myFlg = False Then MsgBox "該当データなし" Else ActiveSheet.PrintPreview End If End If End Sub これでF列が「日、月、火、金」の行が表示　→　印刷プレビュー該当データがない場合のみメッセージボックスを表示させるようにしています。的外れならごめんなさい。m(_ _)m

tom04 · Answer

No.1です。

＞当初のとおり「For i = 1 To 20」にしておくと問題があるのでしょうか（？）

前回、余計なお世話で書いたのは
最終行を取得し、そこまでのループでやめるための方法でしたが
A30～S500までデータがあるようなので、この方法は使えません。
また、
＞For i = 1 To Cells(Range("A1").End(xlDown).Row, "A")
は
＞For i = 1 To Range("A1").End(xlDown).Row
の間違いでした。どうも失礼しました。

ただこれはA1セルから下へ見ていき、空白セルの前までの行番号取得方法ですが、
データが21行目以降も続いている場合はこちらもダメですね。

今回の質問に関しては20行だけのループなので
まったく問題ないと思います。

ただ、コードを拝見すると30行目が項目行になっているという前提で

Dim i As Long
For i = 1 To 20
If Cells(i, 1) = "" Then Exit Sub
Range("A30:S500").AutoFilter Field:=6, Criteria1:=Cells(i, 1).Value
If MsgBox("印刷プレビューを行って良いですか？", vbYesNo + vbExclamation, "確認") = vbYes Then
    ActiveSheet.PrintPreview
End If
Next i

のように最後に「Next i」を持ってこないと
メッセージボックスも表示されないと思います。

※　上記コードではA1セル以降も印刷プレビューに表示されますが、
印刷範囲は指定しなくてよいのですよね？m(_ _)m

tom04 · Answer

こんばんは！

そのままのコードで使いたい場合は
＞If Cells(i, 1) = "" Then
＞Exit Sub
と2行になっているところを
＞If Cells(i, 1) = "" Then Exit Sub
のように1行にしてみてはどうでしょうか？

おそらく2行にするとそのあとに
＞End If
が必要になるはずです。

※　私的には
＞Exit Sub
ではなく
＞Exit For
という使い方をします。
ただその後の処理がないので「Exit Sub」でも問題はないと思いますが・・・

余計なお世話かもしれませんが、
＞For i = 1 To 20
を
＞For i = 1 To Cells(Rows.Count, "A").End(xlUp).Row
もしA21セル以降にもデータがある場合は
＞For i = 1 To Cells(Range("A1").End(xlDown).Row, "A")
とすれば
空白の場合の処理は不要だと思います。m(_ _)m

指定した範囲の値で順番にソートをかけて、指定した表を印刷していくVBAについて

こんばんは！

あぁ～～～！そういうコトだったのですね。

何度もごめんなさい。

続けてお邪魔します。

No.1です。

こんばんは！

似たような質問が見つかりました

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング