エクセルで空白を無視して一番左にあるセル内容（文字列）を別セルに返したい

office365ユーザーです、お手数ですが、教えていただけると幸いです。

例えば、下記のような感じの一覧があるとします。
（**の部分は文字列です。）
　Ａ　Ｂ　Ｃ　Ｄ　Ｅ　Ｆ　Ｇ　 　　　　Ｈ
１　　**　　　** ** ** **
２　　　　**　　　**　**　　
３　　　　　　　　**　**　**
４　　　　**　　　**　　　**

1行目の抽出結果=１行の一番左にあるセル（Ｂ１セル）
2行目の抽出結果=２行の一番左にあるセル（Ｃ２セル）
　　　　　：
といった感じで空欄を無視して一番左側にある文字列をＨ列に返して一覧表を作成したいと考えています。
空欄に規則性はありません。あったりなかったりです。

条件付き書式、関数でできるものだと、とても助かります。

説明足らずなところはご指摘頂ければと思います。
以前同様の質問があったのですが、数値の為でしょうか、Ｎ／Ａエラーが出ました。
今回は文字列です。
参考：https://oshiete.goo.ne.jp/qa/4071300.html

No.3 ベストアンサー 回答者： googoo900 回答日時： 2018/11/24 11:55

IF関数を使ったやり方を紹介します。

データが質問文の配置どおりであれば、H1セルに下記の数式を入力して下方向にコピペです。
=IF(A1<>"",A1,IF(B1<>"",B1,IF(C1<>"",C1,IF(D1<>"",D1,IF(E1<>"",E1,IF(F1<>"",F1,G1))))))

文字列、数値、いずれでも使えると思います。

この回答へのお礼

こちらの回答で解決できました！
どうもありがとうございました。

お礼日時：2018/11/25 11:43

No.8 回答者： fxq11011 回答日時： 2018/11/25 10:43

補足

入力で表示辞典ではOKでしたが、文字の位置がずれてしまいました
文字列操作の関数で文字列をつなげて表示・・・の関数です。

No.7 回答者： fxq11011 回答日時： 2018/11/25 10:39

A1　 B1 C1　 D1　 E1　 F1　

１　　 2 3 123 ＝CONCATENATE(A1,B1,C1,D1,E1,F1) → 表示１２３に入力している関数です
ア」 い 宇 ア」い宇　→　上記関数をコピーして貼り付け
罫線省略されていますがB列、D列F列は空白セルです、
単純に＝A1＆B１＆C!＆・・・・・でも文字列なら可能です、関数を使えば＆の入力省略できるだけといえばそれまでですが。

No.6 回答者： esupuresso 回答日時： 2018/11/25 00:37

一応excel365も使用しておりますが・・・。

行単位で常に一番左側に入力されているセルの結果を表示したいという事ですね？
画像を添付しておきますが、添付画像では結果を分かり易くI列に表示するようにしております。
セルI1には　=INDEX(A1:G1,MATCH("*",A1:G1,0))　の数式を入れ下方向へ好きなだけ数式をコピーして下さい。
エラー処理をする場合の式は次の通りです。
=IFERROR(INDEX(A1:G1,MATCH("*",A1:G1,0)),"")　の式をセルI1に入れて下方向へ好きなだけ数式をコピーします。

H列に式を入れたいというのでしたら、同じ数式をセルH1に入れて下方向へ数式をオートフィルコピーします。

No.5 回答者： fxq11011 回答日時： 2018/11/24 18:03

IF(A1<>"",A1,IF(B1<>"",B1,IF(C1<>"",C1,IF(D1<>"",D1,IF(E1<>"",E1,IF(F1<>"",F1,G1))))))

A1が空白でなければA!、そうでなければ（空白なら）、B1が空白でなければBI、以降同じ。
したがってA1が空白でなければA1を表示し、以降のIF・・・・は必要なしになります。
A1から空白が続く場合のみ、以降のIFに従いますが、途中で空白でないセルがあればそこまで。
質問の内容には使えません
＝A１＆B1＆C1&D1・・・・・・・のほうがはるかに簡単です（ただし文字認識の入力に限ります、数字認識はたぶんエラー）。

No.4 回答者： mike_g 回答日時： 2018/11/24 12:17

H1: =INDEX(A1:G1,MIN(IF(A1:G1<>"",COLUMN(A1:G1))))

【お断り】上式は必ず配列数式として入力のこと
【備考】「**の部分は文字列で」あらうとなからうと構ひません。

No.2 回答者： ママチャリ 回答日時： 2018/11/24 11:47

「**の部分は文字列です」であれば、こんな感じでいけます。

=HLOOKUP("*",A1:G1,1,FALSE)

ただし、**が数字の場合は微妙です。数字が文字列として入力されていれば反応するのですが、数値として入力されているセルは無視されます。

No.1 回答者： fxq11011 回答日時： 2018/11/24 11:28

＝ＣＯＮＣＡＴＥＮＡＴＥ（Ａ１，Ｂ１・・・・・・）。