対応するExcelの計算式はありますか？

検査1から検査6までの結果をGの結果欄に反映したいのですが、下記の条件に当てはまる計算式はあるのでしょうか？あったら教えて頂きたいです。

①B-F全て○ならGは○
②B-Fに×が1つでもあったら×
③B-Fに空欄があっても×
A欄は基本的に空欄だが○か×が出る時がある
④Aが○でB-Fも○ならGは○
⑤Aが×でB-Fが○でもGは×
⑥Aが○でB-Fに×があればGは×

このような都合のいい計算式はあるのでしょうか？
分かりずらかったら申し訳ないです。

No.5 ベストアンサー 回答者： goomania 回答日時： 2023/10/06 12:50

No.2です。

前回回答数式を簡潔にするとすれば、

=IF(A2="×","×",IF(COUNTIF($B2:$F2,"○")<5,"×","○"))

でどうでしよう。

No.9 回答者： goomania 回答日時： 2023/10/06 13:34

No.8です。

前回回答の数式に()が漏れていました。お詫びして訂正いたします。
正しくは以下のとおりです。

=IF((A2="×")+(COUNTIF($B2:$F2,"○")<5),"×","○")

No.8 回答者： goomania 回答日時： 2023/10/06 13:28

No.5です。

数式中の×の登場回数を減らしてみました。

=IF((A2="×")+COUNTIF($B2:$F2,"○")<5,"×","○")

としても、同じ結果になると思います。

No.7 回答者： kigoshi 回答日時： 2023/10/06 13:18

No.4です。

回答式のフローチャートです。

No.6 回答者： angkor_h 回答日時： 2023/10/06 13:05

条件が６個もあるようですが、

結局のところ、
検査1が空白か○、且つ、検査2-6の全てが〇、
この時だけ結果〇、それ以外は結果×、
という事になっているようです。

これを関数にまとめれば、
G=IF(AND(A=OR("","〇")、COUNTIF(B:F,"〇")=5),"〇","×")

No.4 回答者： kigoshi 回答日時： 2023/10/06 12:50

G2　　=IF(COUNTIF(B2:F2,"○")=5,IF(A2="×","×","○"),"×")

で下方コピー。

No.3 回答者： fujillin 回答日時： 2023/10/06 12:43

こんにちは

整理しさえすればよい内容のご質問ですが・・・

それぞれのセルが、「〇であることや×であること」を確認する必要があるのか、
「×と×以外」のような考え方でも良いのかで式は大分変わります。

以下は、「×と×以外（＝〇、空白も含む）」として判断する方法です。
Ｇ2セルに
　=IF((A2="×")+COUNTIF(B2:F2,"×"),"×","○")
を入力して、下方にフィルコピーでいかがでしょうか？

※ 上式は「〇」の有無については、一切確認していません。

No.2 回答者： goomania 回答日時： 2023/10/06 12:37

「取り敢えず○×が表示される」というレベルの数式ですが、G2セルに

=IF(((A2="○")+(A2=""))*(B2="○")*(C2="○")*(D2="○")*(E2="○")*(F2="○"),"○","×")

をいれて、下方向へコピーすれば結果は得られると思います。

No.1 回答者： ピーナツ48 回答日時： 2023/10/06 12:32

こちらの条件は以下であってますよね？

条件1.BからFまでが全て○（◯が６個）ならGは◯
条件2.AからFまで全てが◯（◯が７個）ならGは◯
条件3.条件1、2のどちらかを満たさないならGは×

これはIF関数とCOUNTIF関数を組み合わせることで実装できます。それぞれの関数の特性を調べてみてください！