【Excel】複数の条件に一致するデータの抽出

VLOOKUPの検索値が複数あるようなイメージで、それらに
合致するデータを求める関数はありますか？
例えば下記のようなデータがあり、「ランク=A」かつ
「級=2」の率を求めるような式です（この場合率は4.0です）。
このデータはテーブルとして別シートに作成し、元の
シートにこのテーブルで求めた率をひっぱってきたいと
考えています。
説明が下手で分かりにくくて申し訳ありませんが、どなたか
お分かりになる方、教えて下さい。よろしくお願いします。

ランク　　　級　　　　率　　　　
A　　　　　1　　　　　4.1
A　　　　　2　　　　　4.0
A　　　　　3　　　　　3.2
B　　　　　1　　　　　4.0
B　　　　　2　　　　　3.8
B　　　　　3　　　　　3.0
・　　　　　・　　　　　　・
・　　　　　・　　　　　　・
・　　　　　・　　　　　　・　　　　　

No.1 ベストアンサー 回答者： mshr1962 回答日時： 2005/05/24 15:31

ランクの左に列を挿入

=B2&C2
の様にしてランクと級の結合データを作成して、検索のキーにする。
=IF(OR(A1="",B1=""),"",VLOOKUP(A1&B1,表の範囲,4,FALSE))
の様に計算

この回答へのお礼

ありがとうございます。率を表すことができました。
ほんの少しの工夫で便利になるのですね、感心です！

お礼日時：2005/05/25 08:21

No.5 回答者： ja7awu 回答日時： 2005/05/24 16:42

「ランク」という見出しが、セルA1にあるとして、

データに「ランク」に対する「級」が、同じデータが無いとすると
「ランク=A」かつ「級=2」の率を求めるような式は、

=SUMPRODUCT((A2:A10="A")*(B2:B10=2),C2:C10)

で如何でしょうか。

この回答へのお礼

回答ありがとうございます。SUMPRODUCTは便利な機能ですが、
率の欄にはどんなランクと級の組み合わせがきても、それに
合致する価を求める式をもってきたいので、難しいですね。
No.1さんを参考にさせていただこうと思います。

お礼日時：2005/05/25 08:44

No.4 回答者： mu2011 回答日時： 2005/05/24 16:07

配列を使用して、以下の方式は如何でしょうか。

=SUM(IF(A2:An="a",IF(B2:Bn=2,C2:Cn)))
入力の最後にｓｈｉｆｔ＋Ｃｔｒｌ＋Ｅｎｔｅｒとして下さい。

この回答へのお礼

回答ありがとうございます。
このような方法もあるのですね、勉強になりました。

お礼日時：2005/05/25 08:45

No.3 回答者： taocat 回答日時： 2005/05/24 15:51

こんにちは。

Sheet2 （１行目は見出し）

　　質問の変換テーブル（Ａ１－Ｃ５０）


Sheet1　（１行目は見出し）

　　Ａ列に、ランクを入力
　　Ｂ列に、級を入力
　　Ｃ列に、Sheet2の変換テーブルの値を求める


Ｃ列に次の式をセット

=SUMPRODUCT((Sheet2!A2:A50=A2)*(Sheet2!B2:B50=B2)*Sheet2!C2:C50)


以上です。
　

この回答へのお礼

回答ありがとうございます。SUMPRODUCTは便利な機能ですが、
率の欄にはどんなランクと級の組み合わせがきても、それに
合致する価を求める式をもってきたいので、難しいですね。
No.1さんを参考にさせていただこうと思います。

お礼日時：2005/05/25 08:44

No.2 回答者： maruru01 回答日時： 2005/05/24 15:49

こんにちは。

maruru01です。

複数条件の方法にはいろいろありますが、データベース関数を利用した方法を。
表がSheet2にあるとします。
元のシートは、

A1：「ランク」
B1：「級」
A2：「Ａ」
B2：「1」

というようにします。
（つまり1行目が項目名で、2行目に検索値）
こうしたら、

=DGET(Sheet2!A:C,Sheet2!C1,A1:B2)

で率が表示されます。

なお、検索結果が複数になる場合（例えば、ランク"Ａ"の級"1"が複数ある）は、エラーになります。

この回答へのお礼

こんな方法もあるのですね。ただ検索結果が複数に
なるケースも多いので残念です。
勉強になりました、ありがとうございます。

お礼日時：2005/05/25 08:24