Excelで入力のある最大行数を取得できますか？

こんばんは。
Excelの関数で以下の値を取得できますか？
行は可変です。
行を追加して、行に入力のある時、
その行の行番号を知りたいのです。
やりたいことは
D1の位置にA1からAnまでの合計を
入れたいのですが。
D1=sum(a1:??)
??に関数にて入力のある最大のn番目を取得できれば
できるきがするのです。

A : B:C:D
1:100: : :ここにA1からAnまでのSumをいれたい。
2:150:
3:80
n:100
お分かりの方宜しくお願いします。

No.6 ベストアンサー 回答者： Cupper 回答日時： 2007/02/18 10:09

=SUM(A:A)

これでA列の合計を表示できます。最大行を考える必要はありません。

この回答へのお礼

ご回答どうもありがとうございます。
こんな簡単な方法があったのですね♪
どうもありがとうございました。

お礼日時：2007/03/10 17:28

No.5 回答者： maron--5 回答日時： 2007/02/18 07:29

◆各行に空白が無く入力されていれば

=SUM(OFFSET(A1,,,COUNT(A:A)))
または、
=SUM(A1:INDEX(A:A,COUNT(A:A)))

◆途中に空白行があれば
=SUM(A1:INDEX(A:A,MATCH(10^10,A:A)))

No.4 回答者： zap35 回答日時： 2007/02/18 00:40

最大行数は

=LARGE(INDEX((A1:A1000<>"")*ROW(A1:A1000),),1)
または
=MAX(INDEX((A1:A1000<>"")*ROW(A1:A1000),))
で求められます。

A1から最大行迄の合計は
=SUM(INDIRECT("A1:A"&LARGE(INDEX((A1:A30000<>"")*ROW(A1:A30000),),1)))
または
=SUM(INDIRECT("A1:A"&MAX(INDEX((A1:A30000<>"")*ROW(A1:A30000),))))

No.3 回答者： imogasi 回答日時： 2007/02/17 22:54

A1に

=MAX(IF(A2:A100<>"",ROW(A2:A100)))
SHIFT+CTRL+ENTERの３つのキーを押す（配列数式）
A2：A8に有るとして
q
w
e
r
t

2
の例で　８
合計の場合
A1に　=SUM(IF(A2:A100<>"",A2:A100))
数字の場合A1:A8
17 ーー 和
1
2
3
4
5
空白
2
VBAならd=Range("A65536").End(xlUp).Row
など使います。

No.2 回答者： nishi6 回答日時： 2007/02/17 22:22

Ａ列の合計を求めるという主旨なら

　=SUM(A:A)
でできますが、行数を固定したいなら、登録された最後の行は、

数字が連続して登録してあれば
　=COUNT(A:A)

数字に飛びがあれば（未入力行があれば）
　=MATCH(MAX(A:A)+1,A:A)

それぞれ、この値を使って算式で合計を求めようとすると、

　=SUM(INDIRECT("A1:A"&COUNT(A:A)))

　=SUM(INDIRECT("A1:A"&MATCH(MAX(A:A)+1,A:A)))

のようにINDIRECT関数を使うことになるのでしょう。

No.1 回答者： gon4362 回答日時： 2007/02/17 21:31

関数だけでやりたいのでしょうか？

Excel VBAを使用するということでしょうか？

この回答への補足

関数だけでやれたらやりたいです。
やっぱりマクロ組んだりしないと無理ですかね。
一応多少のマクロは組んだことがありますが
最近いじってないので・・・

補足日時：2007/02/17 21:40