エクセルで日付＋時間帯別にカウントしたいと思っています。

エクセルで日付＋時間帯別にカウントしたいと思っています。

2010/3/28 19:47:12
2010/2/12 18:52:25
2010/3/22 17:12:11
2010/3/20 15:34:53

このように分類が日付になっているデータがランダムに並んでいます。
書式設定で言うと
分類：日付
種類：2010/3/20 15:34:53

これを日付＋時間帯別にカウントしたい場合どうすれば良いでしょうか？
例えば(上の例だと)
「2010/3/20 15時台」は　1個
「2010/3/20 16時台」は　0個
「2010/3/20 17時台」は　0個
「2010/3/22 17時台」は　1個

どうかよろしくお願いします。

No.1 回答者： keithin 回答日時： 2010/03/28 19:33

3/20の15:00以降の数 と 3/20の16:00以降の数 との差し引き

などのように計算します。

判りやすくたとえばC1にある日付，D1に15:00と記入しておくと
=COUNTIF(A:A,">="&(C1+D1)) - COUNTIF(A:A, ">="&(C1+D1+"1:0"))

この回答へのお礼

目的達成する事ができました！
大変分かりやすいやり方でした。
ありがとうございました。

お礼日時：2010/03/29 18:47

No.2 回答者： mshr1962 回答日時： 2010/03/28 19:33

「2010/3/20 15時台」は=SUMPRODUCT((TEXT(A1:A1000,"YYYYMMDDHH")="2010032015")*1)

「2010/3/20 16時台」は=SUMPRODUCT((TEXT(A1:A1000,"YYYYMMDDHH")="2010032016")*1)
「2010/3/20 17時台」は=SUMPRODUCT((TEXT(A1:A1000,"YYYYMMDDHH")="2010032017")*1)
「2010/3/22 17時台」は=SUMPRODUCT((TEXT(A1:A1000,"YYYYMMDDHH")="2010032217")*1)

この回答へのお礼

目的達成できました！
アレンジを加え参考にさせていただきます。
ありがとうございました！

お礼日時：2010/03/29 18:49

No.3 ベストアンサー 回答者： tom04 回答日時： 2010/03/28 20:14

こんばんは！

一例です。
↓の画像のように各時刻台（1時間台）のデータをつくり
隣のセルに個数を表示させるようにしています。

D2セルに
=IF(C2="","",SUMPRODUCT(($A$2:$A$100>=C2)*($A$2:$A$100<C2+"1:00")))
という数式を入れ、オートフィルで下へコピーしています。
数式はA列の100行目まで対応できるようにしていますが、
データ量によって範囲指定の領域はアレンジしてみてください。

以上、参考になれば良いのですが
他に良い方法があれば読み流してくださいね。m(__)m

この回答へのお礼

わざわざ画像まで付けていただき大変分かりやすかったです。
本当にありがとうございました。

お礼日時：2010/03/29 18:52

No.4 回答者： mike_g 回答日時： 2010/03/28 21:02

　　　　　A　　　　　　B　　　C　　　　D　　　 E　　　 F

1　2010/3/28 19:47:12　　　　　　　　15時台　16時台　17時台
2　2010/2/12 18:52:25　　 2010/3/20　　　 1　　　 0　　　 0
3　2010/3/22 17:12:11　　 2010/3/22　　　 0　　　 0　　　 1
4　2010/3/20 15:34:53
5

１．セル D1 に 15:0 と入力して、“ユーザー定義”で h"時台" に書式設定
２．セル D1 を右方にドラッグ＆ペースト
３．セル D2 に次式を入力して、此れを右下にドラッグ＆ペースト
　　　　=SUMPRODUCT(($A$1:$A$10>=$C2+D$1)*($A$1:$A$10<$C2+D$1+"1:0"))

この回答へのお礼

目的達成できました！
コピーの仕方まで教えていただいて助かりました。
参考にさせていただきます。
ありがとうございました！

お礼日時：2010/03/29 18:51