値の入っているセルのうち、一番右側の値を取得したい(エクセル)

現在、データを左から右へ順次追加しています。
一番右側が、最新データとなります。
やりたいことは、複数の行にある、最新データを拾って、グラフを作成したいと思ってます。
どうやったら、できるのでしょうか?


＜イメージ?＞
●：最新データ
×：古いデータ
○：空欄
●のみを拾って、グラフを作成したい。

×××××●○
××××●○○
×●○○○○○
××××●○○

No.2 ベストアンサー 回答者： maruru01 回答日時： 2003/09/03 15:11

こんにちは。

maruru01です。

データがB列から、順に右へ入力されていくとして、A列に最新データを表示する場合は、

A1を選択して数式バーに、

=INDIRECT(ADDRESS(ROW(),MAX(IF(LEN($B1:$M1),COLUMN($B1:$M1)))))

と入力し、まだカーソルが数式バーにある状態で[Ctrl]と[Shift]を押しながら[Enter]を押して決定します。
（数式の両端に「{}」が付いて配列数式になります。）
これを下の行へコピーします。
あとは、このA列の値でグラフを作成すればいいと思います。
なお、上記の数式ではデータ入力範囲をB～M列にしましたが、後ろの列は、データを入力する可能性のある最大の列にして下さい。
（何列まで入力するか分からない場合は、エクセルの最終列のIVにしましょう。）

各関数については、ヘルプなどを参照して下さい。
配列数式については、以下のページを参考にして下さい。

http://pc21.nikkeibp.co.jp/pc21/pc_10/hr_top.htm

参考URL：http://pc21.nikkeibp.co.jp/pc21/pc_10/hr_top.htm

No.5 回答者： taisuke555 回答日時： 2003/09/03 22:29

グラフを作成と言うことですので、

●や×は数値ですよね？（違ったら読み飛ばしてください）

A列は項目名
B列に最新データ
C列からデータが入力されるものとします。

B2セルに
=IF(C2="",0,LOOKUP(10^32,C2:IV2))

というのはどうでしょうか？

この回答へのお礼

皆さん、いろいろありがとうございました!
いろんなほうほうがあるんだなぁ！と思ってしまいました。
結局、時間的なこともあり、NO.2さんの方法を使用させていただきました。
また時間があるときに、他の方の教えていただいた方法も、やってみたいと思います!
ありがとうございました!

お礼日時：2003/09/05 12:51

No.4 回答者： imogasi 回答日時： 2003/09/03 22:00

全行で空白セルがデータセルの間にないものと言う条件が満たされるとして

（例データ）Ａ１：Ｄ７に
ac
axc
acdd
ac
acc
a
sc
（関数式）
Ｅ１に=OFFSET(A1,0,4-COUNTBLANK(A1:D1)-1)
といれる。
（結果）
c
c
d
c
cc
a
c
データがＡ－Ｄ列までなので４を式中に使っています。
Ｊ列が最右列なら１０にして、式はＫ列より右列に
設定します。

No.3 回答者： kmb01 回答日時： 2003/09/03 15:32

同じくA列に

=OFFSET(A1,0,COLUMNS(1:1)-COUNTBLANK(1:1)-1)
でもできますね。
空欄のセルより右にデータが入力されないことが前提です。

No.1 回答者： DaddyBear 回答日時： 2003/09/03 15:10

色々な実現方法があると思いますが・・・

たとえば、一番左端の列のセル(A3のセル)に以下のような数式を埋め込みます。
=INDIRECT("R" & CELL("row",B3) & "C" & COUNTA(B3:H3)+1,FALSE)

こうすると、B3からH3までに左から順に入力されたデータの一番右端の値が取れるようになります。

この式は、INDIRECTワークシート関数を用いて、R1C1形式でアドレスを参照し、CUUNTA()で取り出した、今データが入力されているセルの数を指定しています。

ヘルプ等を利用して、解析をされれば、応用は可能であると思います。ご参考になれば幸いです。