Excel2007互換モードでの右クリックロジック

Question

１００件程度の実績のあるソフトですが、あるお客様のみ不思議な現象が発生しています。
そのお客様はWindowsXP & Excel2007の組み合わせで、ソフトは互換モードで動作しています。

Option Compare Text
Option Explicit

Sub migi_del()
    Dim icbc
    Application.CommandBars("cell").Reset
    For Each icbc In Application.CommandBars("cell").Controls
        icbc.Delete
    Next icbc
End Sub

Sub migi_add()
    Dim icbc
    Application.CommandBars("cell").Reset
    For Each icbc In Application.CommandBars("cell").Controls
        icbc.Delete
    Next icbc
        
    With Application.CommandBars("cell").Controls _
        .Add(Type:=msoControlButton, Temporary:=True)
        .Caption = "Message!"
        .OnAction = "aaa"
    End With
End Sub

Sub migi_addTag()
    Dim icbc
    Application.CommandBars("cell").Reset
    For Each icbc In Application.CommandBars("cell").Controls
        icbc.Delete
    Next icbc
        
    With Application.CommandBars("cell").Controls _
        .Add(Type:=msoControlButton, Temporary:=True)
        .Caption = "Message!"
        .OnAction = "aaa"
        .Tag = "aaa"
    End With
End Sub

Sub migi_Rest()
    Dim icbc
    Application.CommandBars("cell").Reset
End Sub

Sub aaa()
    MsgBox "OK"
End Sub

Sub Sample()
    Application.CommandBars("Row").Reset
    Application.CommandBars("Column").Reset
End Sub

の何れの操作を行っても、右クリックは標準のものが表示されてしまいます。
WindowsXP & Excel2007の組み合わせの他のお客様ではこのような現象は出ていません。
何方か理由をご存知の方はいらっしゃいませんか？

end-u · Accepted Answer

>リセットしますと、今度は右クリックで何も表示されなくなりました。
Sub migi_Rest()
　　Dim cb As CommandBar
　　For Each cb In Application.CommandBars
　　　　If cb.Name = "Cell" Then
　　　　　　cb.Reset
　　　　End If
　　Next
End Sub
リセットもLoop処理してください。

おそらく、Index 12 のCommandBarが標準のもので
Index 11 は改ページプレビュー用の"Cell"なのでしょう。

end-u · Answer

>ｉｄ：11
ですか。
2007のデフォルトではid11はCommandBars("Formatting")ですよね。
どうも標準シート右クリックメニューのCommandBars("cell")とは別物のようです。
Sub test()
　　Dim cnt As Long
　　Dim i　 As Long

With Application.CommandBars
　　　　cnt = .Count
　　　　ReDim v(0 To cnt, 1 To 4)
　　　　v(0, 1) = "index"
　　　　v(0, 2) = "name"
　　　　v(0, 3) = "namelocal"
　　　　v(0, 4) = "type"
　　　　For i = 1 To cnt
　　　　　　With .Item(i)
　　　　　　　　v(i, 1) = .Index
　　　　　　　　v(i, 2) = .Name
　　　　　　　　v(i, 3) = .NameLocal
　　　　　　　　v(i, 4) = .Type
　　　　　　End With
　　　　Next
　　End With
　　Workbooks.Add(xlWBATWorksheet).Sheets(1).Range("A1:D1").Resize(cnt + 1).Value = v
End Sub
..こんな感じのでCommandBars列挙して確認したい気持ちもありますけど、
確実な対処方法として、#1で書いたようにLoop＆名前判定で処理すれば良いと思います。

Sub migi_addTag()
　　Dim cb　 As CommandBar
　　Dim icbc As CommandBarControl

For Each cb In Application.CommandBars
　　　　With cb
　　　　　　Select Case .Name
　　　　　　Case "Cell"
　　　　　　　　.Reset
　　　　　　　　For Each icbc In .Controls
　　　　　　　　　　icbc.Delete
　　　　　　　　Next
　　　　　　　　With .Controls.Add(Type:=msoControlButton, Temporary:=True)
　　　　　　　　　　.Caption = "Message!"
　　　　　　　　　　.OnAction = "aaa"
　　　　　　　　　　.Tag = "aaa"
　　　　　　　　End With
　　　　　　End Select
　　　　End With
　　Next
End Sub

end-u · Answer

>でも、今回の問題は標準の表示で発生しています。
ぅーん..そうですか。
別にエラーが出てるわけではないのですよね。
そういった事態には遭遇した事ないですし、あまり聞いた事もありません..
#ご存知の方のレスを待って頂いたほうが良いかも。

手探り状態で原因を探るとすれば、
その現象が出るお客様側で、簡略化したコードのテストをしてもらったほうが良いです。
例えば
Sub cbTest()
　　Dim icbc As CommandBarControl

With Application.CommandBars("cell")
　　　　MsgBox "id： " & .Index & vbLf & "protection： " & .Protection
　　　　.Reset
　　　　For Each icbc In .Controls
　　　　　　icbc.Delete
　　　　Next icbc
　　　　.Controls.Add(Type:=msoControlButton, Temporary:=True).Caption = "test"
　　　　.ShowPopup
　　End With
End Sub
これでどんなメッセージが出るか、
一連の流れで ShowPopup まで実行しますから、どんな結果が表示されるか、
など対話方式でチェックしていくしかないような。
#まずは質問者様側の2007の環境でテストしてみたほうが良いです。

テスト後には元に戻す処理も必要です。
Sub cbReset()
　　Application.CommandBars("cell").Reset
End Sub

end-u · Answer

2007に限らず、ある作業環境化ではそのマクロは機能しません。
「改ページプレビュー」で作業している時です。

Sub test()
　　Dim cb As CommandBar

For Each cb In Application.CommandBars
　　　　Select Case cb.Name
　　　　Case "Cell"
　　　　　　MsgBox cb.Index & "::" & cb.Name
　　　　End Select
　　Next
End Sub

"Cell"、"Column"、"Row"のCommandBarは
それぞれ２個ずつあります。
「標準」ウィンドウ用と「改ページプレビュー」用です。
制御するのであれば、上記のようにLoop＆名前判定などで
両方のCommandBarに対して処理する必要があります。

#その画像って..？
#たんなる添付ミス..です..よね？

Excel2007互換モードでの右クリックロジック

>リセットしますと、今度は右クリックで何も表示されなくなりました。

>ｉｄ：11

この回答への補足

>でも、今回の問題は標準の表示で発生しています。

この回答への補足

2007に限らず、ある作業環境化ではそのマクロは機能しません。

似たような質問が見つかりました

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング