ＩＦ関数か他の関数で、5つの複数条件を設定したい

ＩＦ関数をつかって、下記の条件で設定したいと思っています。

Ｃ５セルに　「=A5-B5」　という式を入れ、その際、Ｃ５セルに下記条件にあるような回答が出た場合、Ｄ５セルに、「ランクＡ」～「ランクＥ」のような表示が出るようにしたいのです。
初歩的かもしれませんが、どうかよろしくお願い致します。

（条件）
＋５以上　⇒　「ランクA」を表示させる　
＋２以上～＋５未満　⇒　「ランクＢ」を表示させる　
－２以上～＋２未満　⇒　「ランクＣ」を表示させる　
－５以上～－２未満　⇒　「ランクＤ」を表示させる　
－５以下　　　　　　　　⇒　「ランクＥ」を表示させる　

No.1 回答者： THut111 回答日時： 2011/09/19 16:16

IF関数の組み合わせですと、下記のような式になります。

=IF(C1>=5,"ランクA",IF(C1>=2,"ランクB",IF(C1>=-2,"ランクC",IF(C1>=-5,"ランクD","ランクE"))))

この回答へのお礼

ありがとうございました！！

お礼日時：2011/09/19 18:41

No.2 回答者： keithin 回答日時： 2011/09/19 16:27

まず，Ｃ５セルには

=IF(COUNT(A5:B5)=2,A5-B5,"")
という具合にして，ちゃんと数字が入っているときだけ評価点を表示するように丁寧に作成します。

Ｄ５セルは，まぁ他の関数を使う方法もありますが，
=IF(C5="","","ランク"&IF(C5<-5,"Ｅ",IF(C5<-2,"Ｄ",IF(C5<2,"Ｃ",IF(C5<5,"Ｂ","Ａ")))))
などのようで十分です。


＃参考
他の関数の例
=IF(C5="","","ランク"&LOOKUP(C5,{-999,-5,-2,2,5},{"Ｅ","Ｄ","Ｃ","Ｂ","Ａ"}))

この回答へのお礼

ご丁寧にありがとうございます！！！
皆さん、素晴らしすぎます。

お礼日時：2011/09/19 18:41

No.3 回答者： mu2011 回答日時： 2011/09/19 16:33

一例です。

=IF(COUNT(セル),LOOKUP(セル,{-99,-5,-2,2,5},{"E","D","C","B","A"}),"")

この回答へのお礼

こんなやり方があるとは。。。
すばらしいです。
ありがとうございました！！

お礼日時：2011/09/19 18:40

No.4 回答者： THut111 回答日時： 2011/09/19 16:42

No1の者です。

「C5」を「C1」と打ち間違えてしまいました。下記のように訂正します。

=IF(C5>=5,"ランクA",IF(C5>=2,"ランクB",IF(C5>=-2,"ランクC",IF(C5>=-5,"ランクD","ランクE"))))

原始的なやり方ですが、今後式をメンテナンスする際の手間を考えると、式の内容がわかりやすいほうがいいと思います。

この回答へのお礼

ありがとうございました！！IF関数では、3つまでしかネスト出来ないと思っていたのですが、頭使えば出来るんですね！

お礼日時：2011/09/19 18:40

No.5 回答者： esupuresso 回答日時： 2011/09/19 17:55

別の方法で別表を作っての式になりますが、表はいらないし～、と言うのでしたら無視してください＾＾；

F5セルに「=IF(ISBLANK(C5),"",IF(C5<-5,"E",VLOOKUP(C5,$F$6:$G$9,2,1)))」の式を入れて必要な行まで式をコピーして下さい

画像を添付しておきます

この回答へのお礼

ありがとうございます！

お礼日時：2011/09/19 18:39

No.6 回答者： esupuresso 回答日時： 2011/09/19 17:58

No5です

式はF5セルじゃなくてF6のセルに
「=IF(ISBLANK(C5),"",IF(C5<-5,"E",VLOOKUP(C5,$F$6:$G$9,2,1)))」を入れます

間違いました　失礼　<(_ _)>

この回答へのお礼

ご丁寧にありがとうございます！感謝！！

お礼日時：2011/09/19 18:39

No.7 ベストアンサー 回答者： tom04 回答日時： 2011/09/19 18:01

こんばんは！

すでに回答は出ていますので、参考程度で・・・
↓の画像のような方法もあります。

Sheet2に画像のように表を作成しておきます。
（実際はA・C列だけでOKですが、判りやすくするために敢えて、「未満」のB列も表示しています）

Sheet1のD5セルに
=IF(C5="","",VLOOKUP(C5,Sheet2!A2:C6,3,1))
という数式を入れると希望に近い形になると思います。

※　Sheet2のA2セルにはこれ以下はない！というくらいの数値を入れておきます。m（_ _）m

この回答へのお礼

ありがとうございました！これで採用させて頂きました！！スッキリ！！

お礼日時：2011/09/19 18:38