Excelで在庫管理

Excel2007 or 2010　で質問です。
Accessはまったく無理です。

添付した画像の上の表から、下の日付ごとに仕入れた商品や種類仕入数などの在庫を計算したいと思います。
5月10日にりんご　６グラム　種類は2B　箱の大きさ30　仕入を50とします。
これは、出荷もしなければいけないのですが、出荷はその日とは限りません。
５月13日に20個だけ出荷する場合もあります。

例えば5月13日に20個出荷すると残りは30個になりますが、これは「りんご　６グラム　種類は2B　箱の大きさ30」が30個になったとしたいです。
いわゆる、りんごが30個になったというわけではなく、このパターンのものが30個になったと判断したいです。

この表にどんなものを追加し、どのように日付で管理すればいいのか教えてください。

No.1 ベストアンサー 回答者： ryo_ky 回答日時： 2013/05/29 13:40

各々の総量が分かれば良いのであれば、例えば下記の様な一覧表を別のシート用意すれば良いと思うのですが、A列を品名、B列をグラム　C列を種類、D列を箱の大きさ E列を在庫としますと

例（Sheet2に表を作る）
A B C D E
品名　　グラム　種類　箱　在庫
りんご　 6 1A 30
りんご　　 6 2B 30
みかん　　 5 2A 25
・
・
・

Sheet1に質問文に書かれてる表があるとします。
A B 　 C D E F H
日 品名　　グラム　種類　箱　仕入　出荷
5/10 りんご　　6 2B 30 50 10
5/11　バナナ　 10 1A 25 40 0
5/12 りんご　　6 2B 30 30 0
5/12 りんご　　6 1A 30 70 0
・
・
・

まず質問にある様な、場合分けの合計を求める方法についてです。
上に用意したSheet1の表で考えると、
りんご、6、2B、30の合計は仕入が5/10に50と5/12に30なので80ですよね。
この時使用する関数は「SUMIFS」です。
仕入れ量はF列、各々の条件はB～Eの列なので
=SUMIFS(F:F,B:B,"りんご",C:C,6,D:D,"2B",E:E,30)
値は80になります

出荷量はHの列なので
=SUMIFS(H:H,B:B,"りんご",C:C,6,D:D,"2B",E:E,30)
値は10になります

あとは在庫の量は 『仕入総数-出荷総数』 で考えればよいので関数は
=SUMIFS(F:F,B:B,"りんご",C:C,6,D:D,"2B",E:E,30)-SUMIFS(H:H,B:B,"りんご",C:C,6,D:D,"2B",E:E,30)
値は70になります

この関数で値を求めることができますが、一括して色々な条件の在庫を求めるには少々不便なので、
Sheet2の表を利用します。
Eの列が在庫なので関数は
=SUMIFS(Sheet1!F:F,Sheet1!B:B,Sheet2!A2,Sheet1!C:C,Sheet2!B2,Sheet1!E:E,Sheet2!D2,Sheet1!D:D,Sheet2!C2)-SUMIFS(Sheet1!H:H,Sheet1!B:B,Sheet2!A2,Sheet1!C:C,Sheet2!B2,Sheet1!E:E,Sheet2!D2,Sheet1!D:D,Sheet2!C2)

あとはA～Dの列に必要な情報（品名やグラムなど）を入力してE列の関数を下方向にコピーすれば在庫を集計できます。