【先着1,000名様!】1,000円分をプレゼント!

セルの値を差し引いて、時間を出してるのですが
その時間が「0:00」の時、
そのセルを灰色にしたいのですが、
条件付き書式でうまくできません。

「=$A65536="0:00:00"」
「=$A65536="0:00"」
でも、何も変わりません。

時間は、セルの書式設定で「h:mm」にしています。

このQ&Aに関連する最新のQ&A

A 回答 (4件)

どれでも。



=$A65536=0
=$A65536-"0:00"=0
=$A65536="0:00"+0
=$A65536="0:00"-0
=$A65536="0:00"*1
=$A65536="0:00"/1
=$A65536="0:00"^1
=$A65536=--"0:00"
=$A65536=n("0:00")
=$A65536=value("0:00")
=$A65536=timevalue("0:00")
=$A65536=sum("0:00")
=$A65536=max("0:00")
=$A65536=min("0:00")
=$A65536=average("0:00")
=$A65536=median("0:00")
=$A65536=imreal("0:00")
=text($A65536,"h:mm")="0:00"
=delta($A65536,"0:00")

最もよく使われているのは多分「*1」だと思いますが、「0:00」という時間に限って言えば、いちばん上の式も十分に分かりやすいです。

なお問題になっているのは、セルに記入されている(あるいは算出されている)値が、数値なのか、それとも文字列なのかという点です。セルに数値があって(あるいは空白で)、それを「0:00」という文字列と比較しようとしても、そのままでは当然、一致しません。Excel にデータ型を自動変換させるため、上のような数式が必要になっています。

したがって、セルの書式は何であっても構いません。書式は見かけを設定するだけのことなので、値とは直接の関係がありません。
    • good
    • 0
この回答へのお礼

ありがとうございました。

お礼日時:2013/12/30 21:32

=TEXT($A65536,"h:mm")="0:00"



でどうでしょうか?
    • good
    • 1
この回答へのお礼

ありがとうございました。

お礼日時:2013/12/30 21:32

>その時間が「0:00」の時、



=A1=0

とかで構いません。




#ただし
>セルの値を差し引いて、時間を出してる

その時、「見た目0:00に見えてる」けど実際にはゼロじゃなくて、0.何秒とかの計算結果になってる(=ジャストゼロの結果になっていない)場合が多くあるので、十分に気を付けてください。

まずこちらのご相談の解決として「手で0:00を記入して」条件付き書式が正常に作動する事をしっかり確認してから、次のステップに進んでください。
    • good
    • 0
この回答へのお礼

ありがとうございました。

お礼日時:2013/12/30 21:32

下記のような条件定義でいかがでしょうか



=AND(HOUR($A65536)=0,MINUTE($A65536)=0)
    • good
    • 0
この回答へのお礼

ありがとうございました。

お礼日時:2013/12/30 21:32

このQ&Aに関連する人気のQ&A

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!

このQ&Aを見た人はこんなQ&Aも見ています

このQ&Aを見た人が検索しているワード

このQ&Aと関連する良く見られている質問

QExcelでの時間計算 条件付き書式

Excelを使用して残業時間の算出をしていますが、
入力した時刻を、条件付き書式で、15分以上は青、30分以上は赤と
自動表示させたいのですが、いい数式があればご教授願います。

たとえば、18:00を定時としている場合、
A1に18:00と入力し、B1が18:15だった場合、B1を青
B1が18:30だった場合、B1を赤
といった感じにしたいのです。

よろしくお願いいたします。

Aベストアンサー

一例ですが
条件1「セルの値が」「次の値以上」「=$A1+TIME(0,30,0)」書式で文字色を赤
条件2「セルの値が」「次の値以上」「=$A1+TIME(0,15,0)」書式で文字色を青

Qエクセル 条件付書式で時刻の判定(毎日5-13時)

エクセルの条件付書式の機能を使って、
セルA列に記載されている日時のうち
5時から13時の間に該当するセルを
色付けしたい。

例として、セルA1には
2011/02/24 09:29:16
のいう形式で日時が入っています。

注意;日付の指定ありません。

Aベストアンサー

セル A1 における[条件付き書式]

数式が  =AND(MOD(A1,1)>="5:0"*1,MOD(A1,1)<="13:0"*1)
フォント色  白
パターン色  赤


添付図参照

Q開始時刻から所要時間に応じてセルを塗りつぶすには

現在仕事である部門の管理をしていまして、各人の作業工程の時間を視覚的に把握したいと思い、それをエクセルでやりたいと思っています。
考えているのは、開始時刻と終了時刻を入力すると、その開始時刻から所要時間分のセルを塗りつぶすというものです。
たとえば、Aさんが8:20から8:27までの作業があったら、8:20から右に7セル分
(1分1セル)を塗りつぶすというものです。

これで各人の作業時間の重複を視覚的に把握したいと思っております。
ガントチャートのようなものですが、さほど凝ったものではなく、簡単な関数で実現できればいいと思っていますが、実際できますでしょうか?

Aベストアンサー

例えばA1セルに氏名、B1セルに開始時間、C1セルに終了時間の文字が有り、D1セルから右のセルには8:15,8:16・・・のように1分間隔で時刻が入力されているとします。
その上でB2セルに8:20、C2セルに8:27と入力した場合のようにB列およびC列にデータが入力されたら、該当する時刻のところの列に色が付くようにするためには次のようにします。
D2セルから使用する右側の列で2行目から下方のセルまでを範囲として選択します。
「ホーム」タブの「条件付き書式」をクリックして「新しいルール」を選択します。
「数式を使用して・・・・・」を選択して数式の窓には次の式を入力します。

=AND(D$1>=$B2-"0:00:01",D$1<=$C2+"0:00:01",D$1<>"")

「書式」をクリックして「塗りつぶし」のタブからお望みの色を設定します。
なお、上の式では0.1秒が追加されたり、引かれたりしていますが時刻の比較などではシリアル値での小数点以下の誤差を解消するために使っています。

QEXCELで、入力した時間に合わせてセルに色をつけるにはどのようにした

EXCELで、入力した時間に合わせてセルに色をつけるにはどのようにしたら良いでしょうか?

例えばA1セルに開始時間(9時)、A2セルに終了時間(9時30分)を入力します。
B1セルが9時から9時15分、B2セルが9時15分から9時半、B3セルが9時半から9時45分・・・となっており、A1、A2に入力した時間に合わせて自動的に対応セルに色をつけるようにしたいです(上記の場合、B1とB2に色がつく)。
その際、既にB行にデータがある場合、C行に色をつけるようにしたいと思っています。

使える関数のヒントでも良いので教えていただけると助かります。

よろしくお願いします。

Aベストアンサー

そうですね… 出来ないことと出来そうなことについて,幾つかお話しして見たいと思います。

今はA列の値を元に色を付けたり消したりしているので,今のままでは,A列で指定した範囲から「外れ」たら消えてしまうのは,どうしようもありません。
また既にご覧になったように,「条件付き書式の色が発色している」という事実を「取り出す」方法や残しておく方法は,(マクロを使っても)ありません。

また,ご質問でヤリタイことのご説明の不足としては
>その情報を消さずに(残したまま)、B列の色が既に変わっているのを判定して、C列・・・以降の色が変わるように

この言い方では,「1度色が付いたB列は,たとえば間違いや,意図した変更によってA列を変えても色が残ってしまい,ずっと消せない。」という動作になります。




で,出来る事の範囲で工夫してみると,例えば。
作成例:
 A列に時刻を入れるとB列が発色する
 B列の発色しているセルに何か固定する記号(スペースでもOKだが目で見て判る文字の方がベター)を記入する事で,そのBの色は付きっぱなしになり追加でC列も発色する
 A列を変更すると,B列で記入していない範囲が新しい条件で発色し,記入したB列の色は残り,B列に記入した行のC列も反応を始める
 B列の記入内容を消去すると,記入していないB列の反応に戻る

B1の条件付き書式の数式
=(B1<>"")+($A$1<$A$2)*($A$1<>"")*(TIME(9,15*(ROW(B1)-1),0)<$A$2)*(TIME(9,15*ROW(B1),0)>$A$1)
C1の条件付き書式の数式
=($A$1<$A$2)*($A$1<>"")*(B1<>"")*(C1="")*(TIME(9,15*(ROW(B1)-1),0)<$A$2)*(TIME(9,15*ROW(B1),0)>$A$1)

のような事は出来ます。

そうですね… 出来ないことと出来そうなことについて,幾つかお話しして見たいと思います。

今はA列の値を元に色を付けたり消したりしているので,今のままでは,A列で指定した範囲から「外れ」たら消えてしまうのは,どうしようもありません。
また既にご覧になったように,「条件付き書式の色が発色している」という事実を「取り出す」方法や残しておく方法は,(マクロを使っても)ありません。

また,ご質問でヤリタイことのご説明の不足としては
>その情報を消さずに(残したまま)、B列の色が既に変わ...続きを読む

Qエクセルで表示形式の時刻の「0:00」を表示しないようにするには?

エクセルで残業の計算をしています。
入社時間 退社時間 残業時間
のような感じでしているのですが、
残業時間が、0:00(つまり残業0)の場合は、
何も表示しない場合は、どのような関数を書けばよいでしょうか?

ちなみに残業時間のセルには、残業時間を自動的に表示させるために、
すでに「=IF((A1="")+(B1=""),"",B1-A1-"8:30")」という式が入っています。
この式にどういう式を付け加えればよいのでしょうか?

Aベストアンサー

ただ単に表示形式を変更すればいいです。現状で書式が時刻形式の
h:mmになってると思いますので、ユーザー定義でh:mm;;と後ろにセ
ミコロンを2つ追加して下さい。負の値と0の時は何も表示しないと
いう意味になります。

Q勤務時間に応じて、セルに色をつけるには?

 お詳しい方、よろしくお願いします。
 初歩的な質問ですみません。
 エクセル2007を使っているんですが、表記について、条件付き書式(でよいのでしょうか?)を設定したいと考えています。内容は以下のとおりです。
(1) 実施したい内容
1 A1セルに勤務開始時刻、A2セルに勤務終了時刻を入力(この2つのセルには7:00から20:00までが、30分刻みで、「データの入力規則」を利用して選択できるようになっています。)することとして、
2 A1セルに勤務開始時刻、A2セルに勤務終了時刻を1のとおり入力(選択)すると、
3 7:00から20:00まで1セルを30分としてとらえたA3セルからAC1セルまでのそれぞれのセルに、勤務時間数に応じて、帯グラフのようにセルに色(赤)を付けたいのです。

具体的な例としましては、
まず、A1セルをクリックして、7:00を選択して、
次に、A2セルをクリックして、13:30を選択すると、
A3セルからP1セルまでが赤く表示されるようにしたいのです。

(2) ご教示いただきたい内容
 ついては、((1)1は何とか自分でできそうなので、)A3セルからAC1セルまでのそれぞれのセルに設定すべき「条件付き書式」をご教示いただきたいのです(もっと簡単なやり方があれば、「条件付き書式」でなく、関数でもよいのですが…)。

 ご教示のほど、どうぞよろしくお願いします。

 お詳しい方、よろしくお願いします。
 初歩的な質問ですみません。
 エクセル2007を使っているんですが、表記について、条件付き書式(でよいのでしょうか?)を設定したいと考えています。内容は以下のとおりです。
(1) 実施したい内容
1 A1セルに勤務開始時刻、A2セルに勤務終了時刻を入力(この2つのセルには7:00から20:00までが、30分刻みで、「データの入力規則」を利用して選択できるようになっています。)することとして、
2 A1セルに勤務開始時刻、A2セルに勤務終了時刻を1のとおり入...続きを読む

Aベストアンサー

う~ん、悩む
>7:00から20:00まで1セルを30分としてとらえたA3セルからAC1セルまでのそれぞれのセルに、・・・
A3を7:00とした場合はAA3が20:00になると思います
逆にAC1を20:00とした場合はC1が7:00になりますが???

私が悩んでもしょうがないので、次のように決めます
C1に7:00、D1に7:30、E1に8:00・・・・AC1の20:00まで入力してください
A2に勤務開始時刻、B2に勤務終了時刻を入力することとします
C2からAC2までを選択し、条件付書式を設定します
設定の内容は「数式が」「=AND($A2<=C$1,$B2>=C$1)」として
書式を「パターン赤」設定すれば終わりです

以上、参考まで

Q条件付書式 if関数 を利用する

条件付書式 if関数 を利用する

おはよう御座います。
条件付書式でIF関数を利用したいです。
=if(and(e4>=10,L4>=50),"1","")

e4が10以上で
L4が50以上ならば
そのセルに色をつける場合の公式を教えて頂きたいのですが?
,"1","")
この部分が間違っていると思うのですが???

Aベストアンサー

以下の式で良いと思いますが
=AND(E4>=10,L4>=50)

QエクセルのIF関数で、文字が入力されていたならば~

エクセルのIF関数で文字が入力されていたならば~、という論理式を組み立てたいと思っています。

=IF(A1="『どんな文字でも』","",+B1-C1)

A1セルに『どんな文字でも』入っていたならば、空白に。
文字が入っていなければB1セルからC1セルを引く、という状態です。

この『どんな文字でも』の部分に何を入れればいいのか教えてください。

またIF関数以外でも同様のことができれば構いません。

宜しくお願いします。

Aベストアンサー

=IF(ISTEXT(A1),"",B1-C1)

でどうでしょうか?

Qエクセルで、条件に一致した行を別のセルに抜き出す方法

エクセルで、指定した条件に一致するセルを含む行をすべて抜き出す方法が知りたいです。

たとえば、

<A列> <B列> <C列>
7/1 りんご 100円
7/2 ぶどう 200円
7/2 すいか 300円
7/3 みかん 100円

このような表があって、100円を含む行をそのままの形で、
別のセル(同じシート内)に抜き出したいのですが。

7/1 りんご 100円
7/3 みかん 100円

抽出するだけならオートフィルターでもできますが、
抽出結果を自動的に、別の場所に、常に表示させておきたいのです。

初歩的な質問だと思いますが、検索しても分からなかったので、よろしくお願いします。

Aベストアンサー

同じ質問が結構よく出てますが、そんなに初歩的でもありません
別シートのA1セルに「100円」と入力し、そのシートの任意のセルに以下の式を貼り付けて下さい。後は、下方向、右方向にコピー。
日付のセル書式は「日付」形式に再設定してください

=IF(COUNTIF(Sheet1!$C:$C,$A$1)>=ROW(A1),INDEX(Sheet1!A:A,LARGE(INDEX((Sheet1!$C$1:$C$500=$A$1)*ROW(Sheet1!$C$1:$C$500),),COUNTIF(Sheet1!$C:$C,$A$1)-ROW(A1)+1)),"")

データ範囲は500行までとしていますが、必要に応じて変更して下さい

QExcelでセルに入っている数字を時刻(0:00:00)として表示する方法(※セルの表示形式の変更ではありません。)

   A   B  
1  24  0:00:24
2  76  0:01:16

セルA1に「24」という数字が入っています。
セルA1の数字を秒として、セルB1に「0:00:24」と表示させたいです。

セルA2、B2のようにもできれば理想です。

単純に関数を使って「="0:00:""A1"」とB2に入力しても、正しく表示はできませんでした。
「="0:00:"A1」も同様に、関数ではないのでエラーです。

方法ご教授お願いいたします。

Aベストアンサー

一例です。
B1に=A1/24/60/60で如何でしょうか。(セルの書式設定で表示形式を時分秒に変更して下さい)


このQ&Aを見た人がよく見るQ&A

人気Q&Aランキング