条件に合った最初の行番号を表示したい。

ｅｘｃｅｌで、Sheet1に、Aに丁目、Ｂに番地、Ｃに号を割り振りました。
　 A　 B 　C
1 　1 　1 　15
2 　1 　1 　18
3 　1 　1 　21
4 　1 　2 　7
5 　1 　2 　14
6 　2 　1 　33
7 　2 　1 　36
8 　2 　1 　37
9 　3 　1 　 15
そこで、条件に合った最初の行番号を表示したいのです。
例えば、２丁目１番地の最初は、６行目なので、F1などに６と表示する方法を知りたいのです。
１丁目２番地だったら、F1は４になるようにしたいのです。
よろしくお願いします。

No.1 ベストアンサー 回答者： tom04 回答日時： 2014/02/01 22:12

こんばんは！

＞例えば、２丁目１番地

D1sるに○丁目　の○の数値、E1セルに△番地　の△数値を入力するとします。

F1セルに
=MIN(IF((A1:A1000=D1)*(B1:B1000=E1),ROW(A1:A1000)))

これは排列数式になりますので、Shift＋Ctrl＋Enterで確定してください。

この画面からコピー＆ペーストする場合は
上記数式をドラッグ＆コピー　→　F1セルを選択　→　数式バー内に貼り付け　→　そのまま（編集可能なまま）
Shift＋Ctrlキーを押しながらEnterキーで確定！
数式の前後に{ }マークが入り配列数式になります。m(_ _)m

No.2 回答者： tom04 回答日時： 2014/02/01 22:23

No.1です。

たびたびごめんなさい。
前回タイピングミスが2ヶ所ありました。
（数式はそのままでOKです）
お判りだと思いますが、

＞D1sるに○丁目　の○の数値
は
＞D1セルに○丁目　の○の数値

＞これは排列数式
は
＞これは配列数式

の間違いです。
どうも失礼しました。m(_ _)m

この回答へのお礼

助かりました。ばっちりです。配列数式などは頑張って勉強します。ありがとうございました。

お礼日時：2014/02/02 09:41

No.3 回答者： keithin 回答日時： 2014/02/01 22:28

えっと、イミフメイのムズカシイ関数がお好みでしたっけ。

Ｄ１に丁目の数字、Ｅ１に番地の数字を記入し、Ｆ１に
=MATCH(D1&"-"&E1,INDEX(A1:A10&"-"&B1:B10,),0)
と計算します。


当然ですが、該当が無ければエラーにします。

この回答へのお礼

ありがとうございました。このような方法もあるのですね。

お礼日時：2014/02/02 09:43

No.4 回答者： kagakusuki 回答日時： 2014/02/02 00:05

>例えば、２丁目１番地の最初は、６行目なので、F1などに６と表示する

>１丁目２番地だったら、F1は４になるようにしたい

　F1セルに表示させる行番号が「何丁目の何番地のデータがある行なのか」という事をどの様にして決めるのかという事が不明ですので、取り敢えずの話として、例えば、２丁目１番地の場合はE列に「2#1」と入力し、１丁目２番地の場合はE列に「1#2」と入力しておくものとします。
　その場合、F2セルに次の関数を入力してから、F2セルをコピーして、F3以下に貼り付けて下さい。

=IF(ISERROR(1/LEFT($E2,FIND("#",$E2)-1)/REPLACE($E2,1,FIND("#",$E2),)),"",IF(COUNTIFS($A:$A,LEFT($E2,FIND("#",$E2)-1),$B:$B,REPLACE($E2,1,FIND("#",$E2),)),IF(ISERROR(1/(INDEX($A:$A,MATCH(REPLACE($E2,1,FIND("#",$E2),)+0,INDEX($B:$B,MATCH(LEFT($E2,FIND("#",$E2)-1)+0,$A:$A,0)):INDEX($B:$B,ROWS($B:$B)),0)+MATCH(LEFT($E2,FIND("#",$E2)-1)+0,$A:$A,0)-1)=LEFT($E2,FIND("#",$E2)-1)+0)),"住所の並び順が不適当です",MATCH(REPLACE($E2,1,FIND("#",$E2),)+0,INDEX($B:$B,MATCH(LEFT($E2,FIND("#",$E2)-1)+0,$A:$A,0)):INDEX($B:$B,ROWS($B:$B)),0)+MATCH(LEFT($E2,FIND("#",$E2)-1)+0,$A:$A,0)-1-ROW($A$1)),"該当無し"))

この回答へのお礼

ちょっと自分には難しすぎるようです。わざわざありがとうございます。

お礼日時：2014/02/02 09:44