エクセル関数で600番台の数取得

セル範囲A1:A20に数式で数値が表示されています。
数式で=""が表示されるため、空白に見えるセルもあります。
この範囲から600から699までの数値がいくつあるか取得しようと思います。

=COUNTIF(A1:A20,">=600")-COUNTIF(A1:A20,">=700")

以上の関数でできるとは思いますが、ほかの関数があればご教示ください。
なお、オートフィルターは使用しないものとします。
エクセル2010です。

No.1 ベストアンサー 回答者： yyriceyy 回答日時： 2015/01/15 14:16

=SUMPRODUCT((A1:A20>=600)*(A1:A20<700))

この回答へのお礼

早速ありがとうございます。
この場合でもSUMPRODUCT関数が使えるんですね。
助かりました。

お礼日時：2015/01/16 08:50

No.5 回答者： bunjii 回答日時： 2015/01/15 17:06

=COUNTIF(A1:A20,">=600")-COUNTIF(A1:A20,">=700")

>以上の関数でできるとは思いますが、ほかの関数があればご教示ください。
Excel 2003以前のバージョンではそれで良いと思います。
Excel 2007以降のバージョンではCOUNTIFS関数が利用できますのでこちらが良いでしょう。
=COUNTIFS(A1:A20,">=600",A1:A20,"<700")

「600から699まで」ということはA1からA20の範囲で論理的にAND(A1:A20>=600,A1:A20<700)となるように設定すれば他の関数でも可能です。
=SUMPRODUCT((A1:A20>=600)*(A1:A20<700))
=SUM(INDEX((A1:A20>=600)*(A1:A20<700),0))
=SUM((A1:A20>=600)*(A1:A20<700)) （配列数式なのでCtrl+Shift+Enterキーで確定する）

この回答へのお礼

勉強になりました。
ありがとうございます。

お礼日時：2015/01/16 08:56

No.4 回答者： Chiquilin 回答日時： 2015/01/15 16:37

Excel2010なら COUNTIFS一択です。

> ほかの関数があればご教示ください。
遊びでいいなら

=FREQUENCY(A1:A20,{699,599})

この回答へのお礼

こんな関数があるんですね、ありがとうございます。

お礼日時：2015/01/16 08:55

No.3 回答者： tom04 回答日時： 2015/01/15 14:37

No.2です。

くどいようですが・・・
=SUMPRODUCT((INT(A1:A20/100)=6)*1)
でも大丈夫だと思います。m(_ _)m

この回答へのお礼

ありがとうございます。
たた、これは空白（=""）の表示がある場合、VALUEエラーになってしまいます。

お礼日時：2015/01/16 08:54

No.2 回答者： tom04 回答日時： 2015/01/15 14:27

こんにちは！

=COUNTIFS(A1:A20,">=600",A1:A20,"<=699")
とか
=SUMPRODUCT((A1:A20>=600)*(A1:A20<=699))
といった方法もあります。

※　必ず整数が入るのであれば
<=699
を
<700
としても大丈夫です。m(_ _)m

この回答へのお礼

新しくCOUNTIFSが出来たのを忘れていました。
ありがとうございます。

お礼日時：2015/01/16 08:52