エクセルで文字列から数字を抽出する書式

エクセルで文字列から数字を書式を使って抽出したいと考えています。

元となる文字列は　２パターンです。
パターンA　16 results　➔16
パターンB　1-24 of 17,565 results　➔ 17565

パターンA
・数字　＋半角スペース ＋ 「results」
・数字部分は１桁〜最大５桁


パターンB
・「１-24 of」＋半角スペース ＋　数字（抽出したい部分）＋半角スペース＋「results」
・１桁〜最大５桁

なるべく、シンプルで短い書式にしたいのですが、よい方法はないでしょうか。

質問者からの補足コメント

• 

  以下は自力で、組んだ書式です。
  もっとシンプルにスマートにできる方法はないか、案があれば教えてください。
  
  =IF(COUNTIF(A1,"*of*")>0,
  MID(LEFT(A1,FIND("r",A1)-1),FIND("f",A1)+1,LEN(A1)),
  LEFT(A1, FIND(" ", A1)-1))

    補足日時：2017/06/07 23:46

No.5 回答者： runix2007 回答日時： 2017/06/08 22:42

形式が決まってるなら、置換だけでもいいかぁ

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A1," results",""),"1-24 of ",""),",","")

No.4 回答者： d-q-t-p 回答日時： 2017/06/08 10:00

=-LOOKUP(,-LEFT(RIGHT(A1,8+{1;2;3;4;5;6}),{1;2;3;4;5;6}))

とか。 Excelのバージョンは書いて欲しいものです。

No.3 回答者： enunokokoro 回答日時： 2017/06/07 23:37

パターンが決まっているのなら、抽出しない文字数は一定ですよね。

それを前提にするなら、以下のものでも可能だと思う。
　=IF(ISBLANK(A1),"",VALUE(MID(A1,IF(LEFT(A1,2)="1-",8,1),FIND("results",A1)-IF(LEFT(A1,2)="1-",8,1))))

大雑把な式なので、もっと簡略できると思います。

No.2 回答者： runix2007 回答日時： 2017/06/07 23:03

提示例だとB1に以下の数式を入力し、フィルハンドルで下に引っ張っていくと、抽出できます

=IF(ISNUMBER(FIND("results",A1)),SUBSTITUTE(IF(ISNUMBER(FIND("of",A1)),MID(A1,LEN("1-24 of ")+1,FIND(" ",A1,LEN("1-24 of ")+1)-LEN("1-24 of ")),MID(A1,1,FIND(" ",A1)-1)),",",""),"該当なし")


パターンA、パターンB一括判定なので、かなり複雑です

簡単に説明しておくと、
１）対象セルに result という文字列が含まれているか判定→ある場合は２）へ進み、ない場合は”該当なし"を返す
２）次に対象セルに of という文字列が含まれているかを判定→ある場合は３）へ、ない場合は４）へ進む、また３）、４）で返される結果のカンマ記号をカンマなしに置換
３）of以降の２つの半角スペースの位置を調べ、その間の文字列を取り出す
４）先頭から、最初の半角スペースまでの文字列を取り出す

No.1 回答者： angkor_h 回答日時： 2017/06/07 22:25

パターンA

FIND関数で半角スペースの位置を得て、LEFT関数で、一つ前まで取り出せばよいです。

パターンB
同様に、「f」と「r」の位置を得て、MID関数で取り出せばよいです。
なお、このままではカンマを含んだ文字列なので、VALUE関数で数値変換が必要です。

ご参考まで。