ＶＢＡにて商品と月別ごとにの集計するには

Question

商品名	年月日	売り上げ								
りんご	7月7日	123,000					　　　4	　5	　　6	　7
みかん	5月2日	123,000				りんご				
みかん	5月3日	123,000				みかん				
りんご	5月4日	123,000				バナナ				
バナナ	6月5日	123,000								
バナナ	7月5日	123,000								
りんご	5月7日	123,000								
りんご	4月5日	123,000								

上の表に商品ごと売り上げ年月日ごとに売り上げ金額があります。
これをもとに右表に集計したいと思います。	
Sub t()
Dim g As Double
Dim i As Long
For i = 15 To 22
If Cells(i, 6).Value >= DateSerial(2017, 5, 1) And Cells(i, 6).Value <= DateSerial(2017, 5, 31) Then
g = g + Cells(i, 7).Value
End If
Next i
Cells(16, 12).Value = g
End Sub	
ここまでやれましたが　りんごをどうやって処理したらよいか
また、うまく一度に処理できないのか考えています。
よい方法があれば教えてくれませんでしょぅか

GooUserラック · Accepted Answer

こちらでも作ってみました。
-----------------------------------------------------------------------------------------
Sub test()
Const 元 As String = "E14"
Const 先 As String = "J15"
Dim 元列 As Long
Dim 元行 As Long
Dim 先列 As Long
Dim 先行 As Long
Dim 元始 As Long
Dim 元終 As Long
Dim 先始 As Long
Dim 月 As Date
Dim 位置 As Long
  Application.ScreenUpdating = False
  Application.Calculation = xlCalculationManual
  元始 = Range(元).Row + 1
  元列 = Range(元).Column
  元終 = Cells(Rows.Count, 元列).End(xlUp).Row
  先始 = Range(先).Row
  先列 = Range(先).Column
  Range(Cells(先始, 先列 + 1), Cells(Rows.Count, 先列 + 13)).ClearContents
  Range(Cells(先始, 先列 + 1), Cells(先始, 先列 + 13)).NumberFormatLocal = "m""月"""
  Range(Cells(先始 + 1, 先列), Cells(Rows.Count, 先列)).ClearContents
  Range(Cells(先始 + 1, 先列 + 1), Cells(Rows.Count, 先列 + 13)).NumberFormatLocal = "#,##0"
  月 = Application.Min(Range(Cells(元始, 元列 + 1), Cells(元終, 元列 + 1)))
  月 = CDate(Format(月, "yyyy/mm") & "/01")
  For 位置 = 先列 To 先列 + 11
    Cells(先始, 位置 + 1).Value = 月
    月 = DateAdd("m", 1, 月)
  Next
  For 元行 = 元始 To 元終
    For 先行 = 先始 + 1 To Rows.Count
      位置 = DateDiff("m", Cells(先始, 先列 + 1).Value, Cells(元行, 元列 + 1).Value) + 先列 + 1
      If Cells(先行, 先列).Value = "" Then
        Cells(先行, 先列).Value = Cells(元行, 元列).Value
        Cells(先行, 位置).Value = Cells(元行, 元列 + 2).Value
        Exit For
      Else
        If Cells(先行, 先列).Value = Cells(元行, 元列).Value Then
          Cells(先行, 位置).Value = Cells(先行, 位置).Value + Cells(元行, 元列 + 2).Value
          Exit For
        End If
      End If
    Next
  Next
  Application.Calculation = xlCalculationAutomatic
  Application.ScreenUpdating = True
End Sub
-----------------------------------------------------------------------------------------
位置など決まっていないというので、簡単に変更出来るようにしたので少し見にくいコードになってしまったかもしれません。
「Const 元 As String = "E14"」と「Const 先 As String = "J15"」だけ変更すれば後は自動で処理します。
もちろん商品が増えれば、勝手に処理します。
一番古いデータの月から１年間分を処理するように作成しています。

GooUserラック · Answer

一応念の為の注意です。

年月日の欄ですが、例えば「2017/12/30」のデータを年をまたいで１月に「12/30」とか入力してしまうと「2018/12/30」になってしまうので、年をまたいだ時は、年の入力を忘れないで行ってください。（書式設定の関係上、年が違っていても同じに見えるので、集計されない時などは年が合っているか最初に確認してください）
実はこの辺も、セルの書式設定を「@（文字列）」にして「yyyy/m/d」や「m/d」形式で入力し、マクロ（ＶＢＡ）を使えば回避出来たりしますけど必要でしょうか？（なぜ書式設定を文字列にするかというと、文字列にしていないと意識的に年を入れているかの判断が出来ない為です。判断後は自動で書式設定を「m"月"d"日"」に変更する事ももちろん可能です）

GooUserラック · Answer

No.3 の訂正

すみません。添付した図はテストでデータなどを動かしたものを載せてしまいました。
No.3 の場合は下図のようなデータの時の物です。

ちなみに No.3 の図の場合は、もちろん「Const 元 As String = "B5"」「Const 先 As String = "I3"」になります。

GooUserラック · Answer

それでしたら、もういくつか質問させていただきます。
① 年月日の列は表示形式が「m"月"d"日"」になっているだけで、実は年も持っていますか？（数式バーには「2017/7/7」のように表示されている）
② 行の最後は２２行目と固定するよりも１５行目以降最後までの方が良いでしょうか？
③ Ｋ列以降の１５行目は「4」などの数字単独ではなく「４月」のようにした方が良いでしょうか？
④ 売り上げの無い欄は空欄で良いですか？
⑤ 集計は最大１２ヶ月でで良いでしょうか？それともデータが有る限り集計した方が良いでしょうか？その場合は「年」表示も必要だと思いますがどうしたらいいでしょうか？
⑥ 念の為の確認ですが、位置などのレイアウトは先ほどの図で間違いないでしょうか？

GooUserラック · Answer

何をやりたいのかよく判らないし、レイアウトもよく判りません。
もしかして下図のような月ごとの商品別の集計を行いたいのでしょうか？
なお売り上げの数値は検証しやすいように変えてあります。

ＶＢＡにて 商品と月別ごとにの集計するには

こちらでも作ってみました。

一応念の為の注意です。

No.3 の訂正

それでしたら、もういくつか質問させていただきます。

何をやりたいのかよく判らないし、レイアウトもよく判りません。

似たような質問が見つかりました

このQ&Aを見た人はこんなQ&Aも見ています

関連するカテゴリからQ&Aを探す

このQ&Aを見た人がよく見るQ&A

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング

ＶＢＡにて商品と月別ごとにの集計するには