エクセルＶＢＡ

エクセルＶＢＡでセルに塗りつぶしなしの丸をつけたい。
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

Dim trg As Range
If TypeName(Selection) = "Range" Then
Set trg = Selection
ActiveSheet.Shapes.AddShape(msoShapeOval, trg.Left, _
trg.Top, trg.Width, trg.Height).Select
Selection.ShapeRange.Fill.Visible = msoFalse
trg.Select
End If
End Sub
を張り付けました。
家のＰＣでは、表示しますが、会社のＰＣでは、図形のマークが出るだけで、丸が表示されません。
設定があるのでしょうか？
よろしくお願いします。

No.3 回答者： WindFaller 回答日時： 2017/10/29 12:13

割り込み失礼します。

このご質問は、オプションの設定の問題だと思ったのですが、
fujillinさんご指摘の、デフォルトには気が付きませんでした。
その上で、てんこ盛りで、いろいろ加えてみました。

Sheet モジュールでは、インテリセンスが働きますから、プロパティの種類は自動で教えてくれます。図形線種？.以下の　.Style = の=を取って再度=を入れれば、インテリセンスが出てきます。
後は、HLEPボタン(F1)ではないかな？

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
　Cancel = True　'←ダブルクリックの時は、これは忘れないで!
　With Target
　　With Me.Shapes.AddShape(msoShapeOval, _
　　　　.Left, .Top, .Height, .Height) '楕円でなく丸
　　　　.Fill.Visible = msoFalse
　　　With .Line
　　　　.Visible = msoTrue
　　　　.ForeColor.SchemeColor = 1 - 1　'SchemeColor は、ColorIndex から1を引く
　　　　.Weight = 2#
　　　　.Style = msoLineSingle
　　　　.DashStyle = msoLineSolid
　　　　.Transparency = 0#
　　　End With
　　End With
　End With
End Sub
'ColorIndex
'黒(1),白(2),赤(3),黄緑(4),青(5),黄色(6),ピンク(7),'水色 (8), 茶(9), 緑(10), 藍(11)

No.2 回答者： fujillin 回答日時： 2017/10/26 18:56

#1です。

＞図形線種を指定するマクロを教えていただけますでしょうか。
マクロの記録を作成してみればわかるのではないかと・・・

念のため太さや線種の指定もしていますが、不要なら削除してください。

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
　Dim trg As Range

　If TypeName(Selection) = "Range" Then
　　Set trg = Selection
　　ActiveSheet.Shapes.AddShape(msoShapeOval, trg.Left, _
　　　trg.Top, trg.Width, trg.Height).Select

　　Selection.ShapeRange.Fill.Visible = msoFalse
　　With Selection.ShapeRange.Line
　　　.Visible = msoTrue
　　　.ForeColor.RGB = RGB(0, 0, 0)
　　　.Transparency = 0
　　　.Weight = 1.5
　　　.Style = msoLineSingle
　　End With
　End If
End Sub

No.1 回答者： fujillin 回答日時： 2017/10/24 18:06

こんにちは

確認していないので、推測ですが・・・
塗り色をなしに指定していますが、線は何も指定していないので、デフォルトの書式設定で描かれているものと想像します。
デフォルトが「線なし」とか透明とかになっていませんか？
あるいは、マクロで明示的に線を指定してあげるとか。

※ はずしていたらスルーしてください。

この回答へのお礼

ご回答ありがとうございます。
デフォルトは確認しましたが、表示する設定でした。
図形線種を指定するマクロを教えていただけますでしょうか。
よろしくお願いします。

お礼日時：2017/10/26 18:34