XSLTのselectの指定

解決済

質問者：noname#20378
質問日時：2005/06/05 21:58
回答数：2件

以下のようなXMLファイルを作成した(XML宣言省略)

<purchase-order>
<book>
<title>古い算数</title> 
<price>1500</price> 
<count>6</count> 
</book>
<book>
<title>楽しくない国語</title>
<price>1000</price>
<count>4</count>
</book>
<book>
<title>詳解リカバリ</title>
<price>4000</price>
<count>5</count>
</book>
</purchase-order>

データ中の本のタイトルは気にしないでください(^^;;;
この注文全体について一冊あたりの平均価格(つまり(1500*6+1000*4+4000*5)/(6+4+5))を求めたいのですが、
どうやって求めたらいいのでしょうか？
6+4+5の部分だけなら

前略
<xsl:template match="purchase-order">
<xsl:value-of select="sum(count)">
<xsl:template>
後略

でうまくいくんですが(別なデータでは上手くいった。関数名との競合は起きないと思うんですが..)
分子を出すにあたって、selectに指定する内容が解らないんです。

通報する

この質問への回答は締め切られました。

質問の本文を隠す

回答 (2件)

ベストアンサー優先
最新から表示
回答順に表示

No.1ベストアンサー

回答者： dellko
回答日時：2005/06/22 11:16

初書き込みです。

時間がったているので解決したかと思いますが、レスしますね。
以下のテンプレートを使用すれば、出来るのかなと思います。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/">
<html>
<body>
<xsl:apply-templates select="purchase-order" />
</body>
</html>
</xsl:template>

<xsl:template match="purchase-order">
<xsl:variable name="total_sum">
<xsl:call-template name="culc_sum">
<xsl:with-param name="tanka" select="book/price" />
<xsl:with-param name="suryou" select="book/count" />
</xsl:call-template>
</xsl:variable>
<xsl:text>合計</xsl:text>
<xsl:value-of select="format-number( $total_sum div sum(book/count),'#,###')" />
</xsl:template>

<xsl:template name="culc_sum">
<xsl:param name="tanka" />
<xsl:param name="suryou" />
<xsl:choose>
<xsl:when test="not($tanka) or not($suryou)">
<xsl:value-of select="0" />
</xsl:when>
<xsl:otherwise>
<xsl:variable name="sum_data">
<xsl:call-template name="culc_sum">
<xsl:with-param name="tanka" select="$tanka[position()>1]" />
<xsl:with-param name="suryou" select="$suryou[position()>1]" />
</xsl:call-template>
</xsl:variable>
<xsl:value-of select="number($tanka[1]) * number($suryou[1]) + $sum_data" />
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>