weekday関数で月曜、水曜、金曜のみ閉店時間を変えて表示したい

こんばんは
weekday関数を使い、月曜、水曜、金曜の終了時間を21時とし、これ以外の曜日を22時終了と表示させたいのですが、私の頭では以下の関数しか思い浮かびません
=IF(WEEKDAY($A3,2)=1,"21時終了","22時終了")

一つの関数で月曜、水曜、金曜のみ閉店時間を変えて表示するにはどの様にすればよろしでしょうか？

使っているのはエクセル2000です

よろしくお願いいたします

No.1 ベストアンサー 回答者： mshr1962 回答日時： 2006/07/03 19:00

=IF(OR(WEEKDAY($A3)=2,WEEKDAY($A3)=4,WEEKDAY($A3)=6),"21時終了","22時終了")

または
=IF(MOD(WEEKDAY($A3),2)=0,"21時終了","22時終了")
または
=IF(FIND(TEXT($A3,"aaa"),"月水金日火木土日")<4,"21時終了","22時終了")
または
=CHOOSE(WEEKDAY($A3),22,21,22,21,22,21,22)&"時終了"

この回答への補足

mshr1962さん
回答ありがとうございます
再度、質問させてください
weekday関数で出たシリアル値を「２」で割り算すると言うことですが、「＝0」の意味はなんでしょうか?

回答者Ｎｏ．2の方は「＝0」無しでも同じ結果になります

よろしくお願いします

=IF(MOD(WEEKDAY($A3),2)=0,"21時終了","22時終了")にあります

補足日時：2006/07/03 23:19

この回答へのお礼

mshr1962様
一番速い回答にもかかわらず
4つも回答していただき
誠にありがとうございました

おかげで問題も解決しました
本当にありがとうございました。

お礼日時：2006/07/04 09:04

No.2 回答者： mike_g 回答日時： 2006/07/03 20:56

=IF(MOD(WEEKDAY(A3),2),"22時終了","21時終了")

No.3 回答者： imogasi 回答日時： 2006/07/03 21:07

2006/7/1722時

2006/7/2122時
2006/7/3221時
2006/7/4322時
2006/7/5421時
2006/7/6522時
2006/7/7621時
B列は　=WEEKDAY(A1)
C1は　=IF((B1=2)+(B1=4)+(B1=6),"21時","22時")
という表現方法もあります。B,C列は１つにできますが、分けてます。
ーーー
G1:H7に
122時
221時
322時
421時
522時
621時
722時
E1に　=VLOOKUP(WEEKDAY(A1),$G$1:$H$7,2,FALSE)
なんていうのもあります。どうにも設定できる、自由度が増します。

No.4 回答者： NCU 回答日時： 2006/07/03 23:08

=21+MOD(WEEKDAY(A1),2)&"時終了"

汎用性度外視。

No.5 回答者： BLUEPIXY 回答日時： 2006/07/04 03:48

=IF(OR(WEEKDAY($A3,2)={1,3,5}),"21時終了","22時終了")