エクセルVBA 他のファイルからデータをコピー

エクセルVBAについて質問があります。お詳しい方、ご教授頂ければ幸いです。
Ａ，Ｂ２つのエクセルのファイルがあります。例えばファイルＡのセル「Ａ１０」から下を、（ファイルＢを開かずに）ファイルＢのセル「Ａ１０」から下のデータに置き換えたいのですが、どのようにすれば良いでしょうか。
また、ファイルＡから「ファイルを開く」ダイアローグを表示させてファイルＢを指定したいのですが、この場合の方法もよろしければ教えて頂けませんでしょうか。
よろしくお願いいたします。

No.3 ベストアンサー 回答者： merlionXX 回答日時： 2008/03/11 21:49

#2です。

少し修正します。

Sub test02()
Dim fn As String
Dim wb As Workbook
fn = Application.GetOpenFilename("エクセル ファイル (*.xls), *.xls")
With ThisWorkbook.Sheets("Sheet1")
.Range(Range("A10"), Range("A10").End(xlDown)).ClearContents
End With
If fn = "False" Then
MsgBox "キャンセルしました。"
Exit Sub
End If
Application.ScreenUpdating = False
Set wb = Workbooks.Open(Filename:=fn)
With wb.Sheets("Sheet1")
.Range(Range("A10"), Range("A10").End(xlDown)).Copy
ThisWorkbook.Sheets("Sheet1").Range("A10").PasteSpecial
Application.CutCopyMode = False
End With
wb.Close (False)
Set wb = Nothing
Application.ScreenUpdating = True
End Sub

No.4 回答者： merlionXX 回答日時： 2008/03/12 09:39

#3です。

昨日は眠かったのか、今見直すと不備な点が散見されました。
書き直します。

Sub test03()
Dim fn As String
Dim wb As Workbook
fn = Application.GetOpenFilename("エクセル ファイル (*.xls), *.xls")
With ThisWorkbook.Sheets("Sheet1") 'このBOOKのSheet1において
.Range(.Range("A10"), .Range("A10").End(xlDown)).ClearContents 'A10以下の連続したデータを消去
End With
If fn = "False" Then
MsgBox "キャンセルしました。"
Exit Sub
End If
Application.ScreenUpdating = False '画面更新を止める
Application.EnableEvents = False '自動マクロを止める
Set wb = Workbooks.Open(Filename:=fn, UpdateLinks:=1) '警告を出さずリンクを更新して開きwbとする
'（UpdateLinks:=0 にすると、リンクを更新せずに開きます。）
With wb.Sheets("Sheet1") 'wbのSheet1において
.Range(.Range("A10"), .Range("A10").End(xlDown)).Copy 'A10以下の連続したデータをCopy
ThisWorkbook.Sheets("Sheet1").Range("A10").PasteSpecial 'このBOOKのA10以下に貼り付け
Application.CutCopyMode = False 'コピーモード終了
End With
wb.Close (False) '警告を出さず保存しないでwbを終了
Application.EnableEvents = True '自動マクロを有効へ
Set wb = Nothing
Application.ScreenUpdating = True '画面更新
End Sub

この回答へのお礼

大変お礼が遅くなり申し訳ありません。
皆様のおかげで、大変勉強になりました。本当にありがとうございます。

お礼日時：2008/05/01 22:22

No.2 回答者： merlionXX 回答日時： 2008/03/11 21:38

ファイルＡから「ファイルを開く」ダイアローグを表示させてファイルＢを指定し、ファイルＡのセル「Ａ１０」から下をファイルＢのセル「Ａ１０」から下のデータに置き換えるサンプルです。

ファイルＢを開かずとのリクエストですが、開いているところを見せないようにはしています。
Sheet名に言及がなかったのでＡＢともにSheet1としています。

Sub test01()
Dim fn As String
Dim wb As Workbook
fn = Application.GetOpenFilename("エクセル ファイル (*.xls), *.xls")
With ThisWorkbook.Sheets("Sheet1")
.Range(Range("A10"), Range("A10").End(xlDown)).ClearContents
End With
If fn = "False" Then
MsgBox "キャンセルしました。"
Exit Sub
End If
Application.ScreenUpdating = False
Set wb = Workbooks.Open(Filename:=fn)
With wb.Sheets("Sheet1")
.Range(Range("A10"), Range("A10").End(xlDown)).Copy
ThisWorkbook.Sheets("Sheet1").Range("A10").PasteSpecial
End With
wb.Close
Set wb = Nothing
Application.CutCopyMode = False
Application.ScreenUpdating = True
End Sub

No.1 回答者： toshi_2000 回答日時： 2008/03/11 16:07

後者の回答です。

FileFoOpen = Application.GetOpenFilename("エクセル ファイル (*.xls), *.xls")