「形式を選択して貼り付け」 のマクロ

セルを貼り付けする時に値だけを取り出したいので
以下のものを書いてみました。

Ctrl + c > Ctrl + v　「コピー　貼り付け」　は動くのですが、
Ctrl + x > Ctrl + v　「切り取り　貼り付け」　は run time error が出てしまいます。
理由ご存知でしょうか？


Sub Auto_Open()
　Call setKey
End Sub


Sub setKey()
　Application.OnKey "^{v}", "pasteValue"
End Sub


Sub pasteValue()
　ActiveCell.PasteSpecial xlPasteValues
　Application.CutCopyMode = False
End Sub

No.2 ベストアンサー 回答者： KenKen_SP 回答日時： 2008/03/27 02:55

こんばんは。

半分寝ぼけて書いたので、おかしな部分がありそうですが...

複数セルやシェープなどのオブジェクトに対応してみました。余談ですが、
このようにマクロで貼り付けたものは Undo が効かないのでご注意を。

では。

Option Explicit
Option Private Module

Private moSrc As Object　' // コピー・切り取りのソース
Private mfCut As Boolean ' // 切り取りフラグ

Sub Auto_Open()
　　Call SetKeys
End Sub
Sub Auto_Close()
　　Call RestoreKeys
End Sub

' // 独自ショートカットキー設定
Sub SetKeys()
　　Application.OnKey "^c", "'CustomCopy 0'"
　　Application.OnKey "^x", "'CustomCopy 1'"
　　Application.OnKey "^v", "CustomPaste"
End Sub
' // 独自ショートカットキー解除
Sub RestoreKeys()
　　Application.OnKey "^c"
　　Application.OnKey "^x"
　　Application.OnKey "^v"
End Sub

Public Sub CustomCopy(ByVal lMode As Long)
　　
　　On Error Resume Next
　　
　　Set moSrc = Selection
　　Select Case lMode
　　　　Case 0: mfCut = False
　　　　Case 1: mfCut = True
　　End Select
　　moSrc.Copy

End Sub

Public Sub CustomPaste()
　　
　　On Error GoTo Err_
　　
　　Application.ScreenUpdating = False
　　If moSrc Is Nothing Then
　　　　ActiveSheet.Paste
　　ElseIf TypeOf moSrc Is Range Then
　　　　' // Case range
　　　　ActiveCell.PasteSpecial Paste:=xlPasteValues
　　　　If mfCut Then moSrc.Clear ' // or ClearContents
　　Else
　　　　' // Case other object
　　　　ActiveSheet.Paste
　　　　If mfCut Then moSrc.Delete
　　End If
　　Set moSrc = Nothing
　　Exit Sub
　　
Err_:
　　MsgBox Err.Description, vbCritical, "貼り付けに失敗"
End Sub

この回答へのお礼

回答ほんとに感謝です
まさに改善したい通りにして頂けました
書いていただいたコード、今の自分にはまだ読めませんが
時間ある時に解読するのを楽しみに取っておきます

ありがとうございました^^

お礼日時：2008/03/28 15:11

No.1 回答者： hana-hana3 回答日時： 2008/03/26 13:54

通常の動作でも、Ctrl + X の場合は「形式を選択して貼付け」が無効になっているはずですよ。

なので、ＶＢＡでも同様です。
出来ない動作を実行させようとしたのですからエラーになります。

この回答へのお礼

回答ありがとうございました　おっしゃる通りですね
一応以下のコードで希望通り動くようになったのですが、
cutValue() の時にデフォルトのように点線で囲むにはどうするのでしょうか？？
あるいはもっと効率の良い書き方などあればアドバイスよろしくお願いします。

Dim cellValue As String

Sub Auto_Open()
Call setKey
End Sub


Sub setKey()
Application.OnKey "^{x}", "cutValue"
Application.OnKey "^{v}", "pasteValue"
End Sub


Sub cutValue()
cellValue = ActiveCell.Value
ActiveCell.Value = ""
Application.CutCopyMode = True
End Sub


Sub pasteValue()
ActiveCell.Value = cellValue
Application.CutCopyMode = False
End Sub

お礼日時：2008/03/26 14:24