NTT-X Store d払いご利用でdポイントが貯まる使える!

エクセルのVBAで開いているパワーポイントのファイルを印刷することは可能でしょうか?
色々とHP等で調べましたが、わかりません
教えてください

このQ&Aに関連する最新のQ&A

A 回答 (4件)

お、まだあきらめないんですね。


難しいでしょうが、がんばってください。

Sub pp_Print4()
Dim objPPT As Object '参照設定していればPowerPoint.Application
Dim myPre As Object 'PowerPoint.Presentation
Dim myName As String
Dim n As Long
myName = "E:\office\powerpoint\0.ppt" 'ファイル名
Set objPPT = CreateObject("PowerPoint.Application")
With objPPT
 .Visible = True
 On Error GoTo Err_Hnd
 'ファイル開いているとき
 Set myPre = .Presentations(myName)
 GoTo tugi
Err_Hnd:
 'ファイル開いていないとき
 Set myPre = .Presentations.Open(myName)
tugi:
 On Error GoTo 0
End With
With myPre
 '用紙に合わせる
 .PrintOptions.FitToPage = msoTrue
 .PrintOut '印刷
 DoEvents
 .Close 'ファイル閉じる
End With
'PowerPoint終了
objPPT.Quit
Set myPre = Nothing
Set objPPT = Nothing
End Sub
    • good
    • 0

pp_Print3で.Closeを忘れました。


↓こっちでお願いします。

Sub pp_Print3()
Dim myPre As Object 'powerpoint.Presentation
Dim n As Long
'ファイル名指定する場合
On Error GoTo Err_Hnd
Set myPre = GetObject("E:\office\powerpoint\0.ppt")
On Error GoTo 0
With myPre
.Application.Visible = True
 With .PrintOptions
  '用紙に合わせる
  .FitToPage = msoTrue
 End With
 .PrintOut '印刷
 DoEvents
 .Close
End With
Err_Hnd:
Set myPre = Nothing
End Sub

この回答への補足

ありがとうございます。
パワーポイントの「閉じる」ですが、開いている特定のファイルは閉じますが、パワーポイントのソフト自体が残ってしまいます。
パワーポイント自体を閉じるにはどうすればいいのでしょうか?

補足日時:2009/01/24 16:57
    • good
    • 0

Sub pp_Print2()


Dim objPPT As Object '参照設定していればpowerpoint.Application
Dim n As Long
'起動しているPowerPoint取得
On Error GoTo Err_Hnd
Set objPPT = GetObject(, "PowerPoint.Application")
On Error GoTo 0
With objPPT.Presentations(1) 'ひとつ目のファイルだけ
 With .PrintOptions
  '用紙に合わせる
  .FitToPage = msoTrue
 End With
 .PrintOut '印刷
 DoEvents
End With
Err_Hnd:
Set objPPT = Nothing
End Sub

Sub pp_Print3()
Dim myPre As Object 'powerpoint.Presentation
Dim n As Long
'ファイル名指定する場合
On Error GoTo Err_Hnd
Set myPre = GetObject("E:\office\powerpoint\0.ppt")
On Error GoTo 0
With myPre
 With .PrintOptions
  '用紙に合わせる
  .FitToPage = msoTrue
 End With
 .PrintOut '印刷
 DoEvents
End With
Err_Hnd:
Set myPre = Nothing
End Sub
    • good
    • 0

開いているファイルをすべて印刷するなら..



Sub pp_Print()
Const ppPrintOutputSixSlideHandouts = 4
Dim objPPT As Object 'パワポに参照設定ならPowerPoint.Application
Dim myPre As Object 'PowerPoint.Presentation
Dim n As Long
'起動しているPowerPoint取得
On Error GoTo Err_Hnd
Set objPPT = GetObject(, "PowerPoint.Application")
On Error GoTo 0
With objPPT.Presentations
 For n = 1 To .Count '開いているプレゼンループ
  With .Item(n)
   With .PrintOptions
    '1枚に6スライド(例です)
    .OutputType = ppPrintOutputSixSlideHandouts
    '用紙に合わせる
    .FitToPage = msoTrue
   End With
   .PrintOut '印刷
   DoEvents
  End With
 Next n
End With
Err_Hnd:
Set objPPT = Nothing
End Sub

新しく開くならCreateObjectを使うことも。

この回答への補足

ありがとうございます。
特定のパワーポイントファイル1つを印刷するにはどうすればいいでしょうか?
また、1ページに1スライドのみ印刷したいのですが、どうすればいいでしょうか?

補足日時:2009/01/22 20:12
    • good
    • 0

このQ&Aに関連する人気のQ&A

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!

このQ&Aを見た人はこんなQ&Aも見ています

このQ&Aを見た人が検索しているワード

このQ&Aと関連する良く見られている質問

QVBAで既存のパワポのファイルを開くには?

アクセスやエクセルからVBAで既存のパワポのファイルを開くには?

参照設定をして、
Sub test()
Dim App As PowerPoint.Application
Dim MyFileName As String

Set App = CreateObject("PowerPoint.Application")

MyFileName = CurrentProject.Path & "サンプル.ppt"
App.Visible = True

Set App = Nothing
End Sub

を実行すると、パワポの空のアプリケーション開きますが肝心のファイルが開きません。

開く方法を教えてください。

Aベストアンサー

ExcelファイルやAccessファイルと
パワーポイントのファイルが同じフォルダにあるとして
Accessなら、CurrentProject.Path
Excelなら、ThisWorkbook.Path
でフォルダ名までが得られますので、それに \ を付け足して
CurrentProject.Path & "\" & "サンプル.ppt"

パワーポイントに参照設定を行っているのですから
CreateObjectせずに
Sub PPTopen()
Dim pp As New PowerPoint.Application
pp.Presentations.Open ThisWorkbook.path & "\" & "サンプル.ppt"
以下省略
で。
開くだけで、その後はVBAでパワーポイントを操作しないのであれば
Shell ("explorer.exe" & Chr(32) & ThisWorkbook.path & "\" & "サンプル.ppt"
↑読み取り専用で開かれました。当方 Office2010 の場合
↓PPTファイルをダブルクリックで開いた状態
CreateObject("shell.application").shellexecute ThisWorkbook.path & "\" & "サンプル.ppt"
とかでも。

ちなみにパワーポイントは数年来使ったことはありませんので
これ以上のことはご勘弁ください。

ExcelファイルやAccessファイルと
パワーポイントのファイルが同じフォルダにあるとして
Accessなら、CurrentProject.Path
Excelなら、ThisWorkbook.Path
でフォルダ名までが得られますので、それに \ を付け足して
CurrentProject.Path & "\" & "サンプル.ppt"

パワーポイントに参照設定を行っているのですから
CreateObjectせずに
Sub PPTopen()
Dim pp As New PowerPoint.Application
pp.Presentations.Open ThisWorkbook.path & "\" & "サンプル.ppt"
以下省略
で。
開くだけで、その後はVBAでパワーポイント...続きを読む

QPDFファイルを開き、印刷し、閉じるマクロ

Excel 2003 VBAにて、
PDFファイルを開き、印刷し、閉じるマクロを作りたいと思っています。

Dim AA, AAA

AA = "C:\Program Files\Adobe\Reader 11.0\Reader\AcroRd32.exe C:\Scan\20131101160734050_001.pdf"
AAA = Shell(AA, vbNormalFocus)

にて、PDFファイルを開くことは出来ました。
このPDFファイルを、「印刷し、閉じる」ためには、
このPDFファイルを指定する必要があると思いますが、
その構文が判りません。
知っている方、教えて下さい。

Aベストアンサー

#3です。
WShell.Execを使うと閉じる事ができる様ですが、色々と気難しくて苦労しました。
まず、なぜかAdobe Reader/Acrobatのフルパスを与えないと、ファイルがみつからないとゴネます。

Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

Sub test()
printPdf2 GetDesktopPath & "\test.pdf", "DocuWorks Printer", "DocuWorks Printer Driver"
' printPdf2 GetDesktopPath & "\test.pdf"
End Sub

Sub printPdf2(pdfDocument As String, Optional printerName As Variant, Optional printerDriver As Variant)
Dim cmdLine As String
Dim WShell As Object
Dim oExec As Object
'ここは調整の必要がありそう
Const waitTime As Long = 1000
'Windows7 Home 64bitの場合です
Const pgmFullPath As String = "C:\Program Files (x86)\Adobe\Reader 11.0\Reader\AcroRd32.exe"

Set WShell = CreateObject("WScript.Shell")
If IsMissing(printerName) Or IsMissing(printerDriver) Then
cmdLine = "pgmFullPath /n /s /o /h /t ""pdfFullPath"""
cmdLine = Replace(cmdLine, "pgmFullPath", pgmFullPath)
cmdLine = Replace(cmdLine, "pdfFullPath", pdfDocument)
Else
cmdLine = "pgmFullPath /n /s /o /h /t ""pdfFullPath"" ""printerName"" ""printerDriver"""
cmdLine = Replace(cmdLine, "pgmFullPath", pgmFullPath)
cmdLine = Replace(cmdLine, "pdfFullPath", pdfDocument)
cmdLine = Replace(cmdLine, "printerName", printerName)
cmdLine = Replace(cmdLine, "printeDriver", printerDriver)
End If
Debug.Print cmdLine
Set oExec = WShell.exec(cmdLine)
Sleep waitTime
'Windows7Home/64bit環境ではここで実行時エラーが出るので無理矢理先に進めていますが
'Adobe Readerは閉じられる様です
On Error Resume Next
oExec.Terminate
Set WShell = Nothing
End Sub

Private Function GetDesktopPath() As String
Dim wScriptHost As Object, strInitDir As String
Set wScriptHost = CreateObject("Wscript.Shell")
GetDesktopPath = wScriptHost.SpecialFolders("Desktop")
Set wScriptHost = Nothing
End Function

Terminateで原因不明のエラーが出るのでWebを漁っいて下記をみつけました。64bit環境でエラーが出るのはこれも関係しているのでしょうか?少々無理をしている様なので、ご使用時はご注意下さい。
Terminate メソッドは最後の手段としてのみ使用します。これは、アプリケーションによっては適切にクリーンアップできない場合があるためです。通常は、プロセスを途中で中断せず、プロセス自身で実行を終了させるようにします。Terminate メソッドは WM_CLOSE メッセージを使ってプロセスを終了しようとします。これで終了できない場合は、通常のシャットダウン手順を実行せずに、プロセスを強制終了します。
http://msdn.microsoft.com/ja-jp/library/cc364387.aspx

#3です。
WShell.Execを使うと閉じる事ができる様ですが、色々と気難しくて苦労しました。
まず、なぜかAdobe Reader/Acrobatのフルパスを与えないと、ファイルがみつからないとゴネます。

Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

Sub test()
printPdf2 GetDesktopPath & "\test.pdf", "DocuWorks Printer", "DocuWorks Printer Driver"
' printPdf2 GetDesktopPath & "\test.pdf"
End Sub

Sub printPdf2(pdfDocument As String, Optional printerName As Variant, Optional prin...続きを読む

QEXCEL VBA で現在開いているブックのファイル名を取得する方法

EXCEL2003 VBAで業務を簡素化するために、現在開いているブックのファイル名を取得する方法が分かりません。
作業手順をマクロを使って処理していますが、オリジナルのワークブックをファイル名を変えて保存し、以後、このワークブックを読み込んで使用しています。
このときのVBAは、オリジナルのファイル名を使っているため、ファイル名を変更するとエラーになり、以後の業務に使用できません。
常にファイル名を取得出来るVBAをどなたか、教えて下さい。

Aベストアンサー

>現在開いているブックのファイル名
 ちょっと曖昧な表現かなぁという気もいたしますが、VBAが書いてあるブックのブック名は
ThisWorkbook.Name
で、現在 "アクティブにして" 操作対象になっているブックの名前は
ActiveWorkbook.Name
ですね。

 しかし、
>VBAは、オリジナルのファイル名を使っているため、ファイル名を変更するとエラーになり
というような文脈からすると、
ThisWorkbook.Name
の方ですかね。

QVBAでアクティブなファイルを切り替える

PowerPointVBAの件です。

複数のファイルを開いていて、作業の流れでアクティブなファイルを切り替えたいと考えています。

ExcelVBAですと、

Workbooks(1).Activate

で、可能なので、

Presentations(1).Activate

で、よいのかと思ったのですが、

"コンパイル エラー:メソッドまたはデータ メンバが見つかりません。"と
表示されてしまいます。

パワーポイントでアクティブなファイルを切り替えるにはどのようにすれば良いのでしょうか?

Aベストアンサー

直接的な答えとしては
  Presentations(1).Windows(1).Activate
  Presentations(2).Windows(1).Activate
のようになります。
また、Excel同様
  Windows(1).Activate
  Windows(2).Activate
のようにも書けます。

Q印刷マクロ【エクセル】エクセルからワードを印刷する

タイトルの件、質問します。

下記の条件で、エクセルを開き、下記の3つの書面を
印刷する、マクロはできますか??

●エクセルブック【Sheet1】【Sheet2】
●ワード【文書1】
※ワードは開いていません。閉じたまま。
※ワードとエクセルブックは同じフォルダ内にあります。

ご存知の方、いらっしゃいましたら、宜しくお願いいたします!!

Aベストアンサー

マクロはエクセル側に書くんですね?
エクセルから開いていないワードを開き、印刷してワードは終了させればいいのですね?
エクセルのSheet1、Sheet2もPrintするんですね?

一例です。

Sub Word_Print()
  Dim wd As Object
  Set wd = CreateObject("Word.application")
  wd.Visible = True
  wd.documents.Open Filename:=ThisWorkbook.Path & "\文書1.doc"
  wd.ActiveDocument.PrintOut Background:=False
  wd.Quit
  Set wd = Nothing
  Sheets(Array("Sheet1", "Sheet2")).PrintOut
End Sub

Qエクセルから表をパワーポイントへ貼り付けたときの、位置調整がうまくいきません

エクセルから表をパワーポイントへ貼り付けたときの、位置調整がうまくいきません。宜しくお願いします。

--------------------
sub test1()

Dim pptApp As Object
Dim pptPre As Object
Dim tempFileName As String

Dim macrofile As String 'エクセルの貼り付け元のファイル名
Dim sht As String 'エクセルの貼り付け元のシート名


Dim page As Integer 'パワーポイントへの貼り付けたいページ
Dim picPos_yoko As Long 'パワーポイントへの貼り付け横位置
Dim picPos_tate As Long 'パワーポイントへの貼り付け縦位置

macrofile = "sample001.xls"
sht = "sheet1"


tempFileName = ThisWorkbook.Path & Application.PathSeparator _
& macrofile


Set pptApp = CreateObject("powerPoint.Application")

With pptApp
.Visible = True
Set pptPre = .Presentations.Open(tempFileName)
End With



Workbooks(macrofile).Worksheets(sht).Activate
Range("A1").CurrentRegion.Copy '表のコピー


With pptPre.Slides(page)
.Shapes.Paste.Name = "hyou1"
With .Shapes("hyou1")
.Top = picPos_yoko
.Left = picPos_tate
End With
End With


End Sub
------------------------

.Shapes.Paste.Name = "pic1"
↑この行で名前をつけたかったがうまく名前がついていない。
 貼り付けた表の名前をパワーポイントのマクロの記録で確認したところ "Group 288"と名前がついていた

With .Shapes("hyou1")
↑当然この行で"hyou1"は見つからないというエラーが出てしまう。


表をエクセルからコピーして、パワーポイントへ位置を指定して張り付けるかもしくは貼り付けた後に移動ができるかを実現したい。
何かいい方法はありませんか?パワーポイントへエクセルからグラフを貼り付けた場合はうまくいきました。
また。パワーポイントの表の名前のつけ方には規則性があるのでしょうか。規則性があれば、それに則ってコードをかけるのですが・・・。

エクセルから表をパワーポイントへ貼り付けたときの、位置調整がうまくいきません。宜しくお願いします。

--------------------
sub test1()

Dim pptApp As Object
Dim pptPre As Object
Dim tempFileName As String

Dim macrofile As String 'エクセルの貼り付け元のファイル名
Dim sht As String 'エクセルの貼り付け元のシート名


Dim page As Integer 'パワーポイントへの貼り付けたいページ
Dim picPos_yoko As Long 'パワーポイントへの貼り付け横位置
Dim picPos_tate As Long ...続きを読む

Aベストアンサー

書き忘れました。
下のコードにして、名前が変更されていることも確認してください。
オブジェクト名: hyou1 になると思います。

 With pptPre.Slides(page).Shapes
  .Paste
  With .Item(.Count)
   .Name = "hyou1"
   .Top = picPos_tate
   .Left = picPos_yoko
   MsgBox "オブジェクト名: " & .Name
  End With
 End With

Q【VB.NET】 パワポ操作を非表示で

 質問させていただきます.
どうぞよろしくお願いいたします.

 PowerPointの操作をするコードを作成して使っております.
毎回立ち上がるパワポのウィンドウを非表示にしたいのですが,
myAPP.Visible = True状態でないと,presentations.Openでエラーが出てしまいます.

Dim myAPP As Object
myAPP = CreateObject("PowerPoint.Application")
Dim myAPPpre = myAPP.presentations
Dim Mypath As String = TextBoxパス.Text
Dim FName As String

myAPP.Visible = True

FName = Dir(Mypath & "test.ppt", vbNormal)
With myAPPpre.Open(Mypath & FName) '←上のmyAPP.Visible = Trueを消すとエラー
                    '「Presentations.Open : 無効な要求です。PowerPoint のフレーム ウィンドウは存在しません。」となります.

 どうにか見えない状態で実行できないものでしょうか.
調べておりますと,同じ現象がよくあるようでした.
(http://www.kotaete-net.net/Default.aspx?pgid=14&qid=80254136041
http://www.microsoft.com/japan/technet/scriptcenter/resources/qanda/sept07/hey0921.mspx のページ中間あたり「さいわい、Visible プロパティを True に設定することによって~」のところ.)

 もし何か方法が分かるかたがいらっしゃいましたら,
アドバイスいただければと思います.
 どうぞよろしくお願いいたします.

 質問させていただきます.
どうぞよろしくお願いいたします.

 PowerPointの操作をするコードを作成して使っております.
毎回立ち上がるパワポのウィンドウを非表示にしたいのですが,
myAPP.Visible = True状態でないと,presentations.Openでエラーが出てしまいます.

Dim myAPP As Object
myAPP = CreateObject("PowerPoint.Application")
Dim myAPPpre = myAPP.presentations
Dim Mypath As String = TextBoxパス.Text
Dim FName As String

...続きを読む

Aベストアンサー

Openの引数WithWindowの既定値はmsoTrueですから,そうなるでしょう。
WithWindowにMsoTriState.msoFalseを渡してやればよいです。

Q【EXCEL-VBA】PDFファイルを開いて印刷したい

お世話になります。
以前、以下のリンク先の質問でA1セルに入力されたファイル名(フルパスの)を取得し
PDFを開くマクロを頂きました。
※ご解答頂いたWindFallerさん、maiko0333さん、ありがとうございました。
このマクロはすごくシンプルで使いやすいので今でも仕事で使っております。

で、、、今回、これをカスタマイズして「印刷もしたい」と思ったのですが、
印刷するためのコードの追加方法がわかりませんでした。

このコードに固執してないので、別の方法でもかまいません。
ですが、ネットで調べたところ複雑なコードばかりでした。
リンク先のようなシンプルなコードでPDFファイルを開いて
印刷することって出来ないのでしょうか?

すいませんが詳しい方、説明の上手な方、
直接、コードで説明できる方、マクロでPDFファイルを開いて印刷するための
コードを教えて下さい。よろしくお願いします。


リンク先:PDFファイルを開くマクロ
「PowerShellを使って関連付けられたアプリケーションでファイルを開く時のエラー」
https://oshiete.goo.ne.jp/qa/9338065.html

追記
1)開いたPDFファイルを閉じる必要はありません。
開けっ放しでOKです

2)前述していますし、リンク先を見て頂ければわかると思いますが、
A1セルに入力するファイル名はフルパスです。
※詳細はリンク先の説明、画像をご覧ください

3)PDFファイルはどれも1枚だけです。
※複数ページのPDFはありません。

以上です。すいませんがよろしくお願いします。

お世話になります。
以前、以下のリンク先の質問でA1セルに入力されたファイル名(フルパスの)を取得し
PDFを開くマクロを頂きました。
※ご解答頂いたWindFallerさん、maiko0333さん、ありがとうございました。
このマクロはすごくシンプルで使いやすいので今でも仕事で使っております。

で、、、今回、これをカスタマイズして「印刷もしたい」と思ったのですが、
印刷するためのコードの追加方法がわかりませんでした。

このコードに固執してないので、別の方法でもかまいません。
ですが、ネットで調...続きを読む

Aベストアンサー

こちらを参考にして
https://www.moug.net/tech/acvba/0130005.html
こんな感じで動きました。(Windows7 64ビット , Excel2010 32ビット)

Option Explicit

Declare Function ShellExecute Lib "SHELL32" Alias "ShellExecuteA" (ByVal hwnd&, ByVal lpOperation$, ByVal lpFile$, ByVal lpParameters$, ByVal lpDirectory$, ByVal nShowCmd&) As Long

Public Sub PrintPDF()
 Dim strPath As String

 strPath = Range("A1").Value
 ' 現在の位置とサイズで表示 5(SW_SHOW)
 Call ShellExecute(Application.hwnd, "open", strPath, vbNullString, vbNullString, 5)
 ' 印刷
 Call ShellExecute(Application.hwnd, "print", strPath, vbNullString, vbNullString, 5)
End Sub

こちらを参考にして
https://www.moug.net/tech/acvba/0130005.html
こんな感じで動きました。(Windows7 64ビット , Excel2010 32ビット)

Option Explicit

Declare Function ShellExecute Lib "SHELL32" Alias "ShellExecuteA" (ByVal hwnd&, ByVal lpOperation$, ByVal lpFile$, ByVal lpParameters$, ByVal lpDirectory$, ByVal nShowCmd&) As Long

Public Sub PrintPDF()
 Dim strPath As String

 strPath = Range("A1").Value
 ' 現在の位置とサイズで表示 5(SW_SHOW)
 Call ShellExecute(Applica...続きを読む

QExcelとPowerPointをVBAで連携させる方法

おけましておめでとうございます。
本年もよろしくお願いします。
で、本題ですが、
(Win95でExcel2000とPowerPoint2000を使用)
EXCELのデータベースの表を順々にPowerPointのテキストボックスへ
コピーして印刷するためにVBAを作成したいと思ってます。
(印刷形式がPowerPointのため)
ここには作成できるんですが、両者のVBAをどのように
連携させるかわかりません。
よろしくご教授ください。

また、PowerPointのVBAでマクロの記録を使わず、オブジェクト名
(("Text Box 1")とか)を知る方法もあわせてよろしくご教授ください。

Aベストアンサー

>オブジェクト名はVBAを使わずにパワーポイント上だけでは確認しようが無いと言うことでしょうか。

絶対できないとまでは断言できる自信はないのですが、少なくともその方法は知りません。

オブジェクト名はVBAを使えば変更することはできます。
Application.ActiveWindow.Selection.SlideRange.Shapes.Item(1).Name = "New Name 1"

だだ、この設定した名称が勝手に変更されることはないのかどうか自信がありません。少なくとも自動的に生成した「オブジェクト名」は勝手に変更されてしまいます。

Qなぜマクロの記録がなくなってしまったのでしょうか?

なぜオフィス2007のパワポは、マクロの記録がなくなってしまったのでしょうか?

2003のパワポを使っていた時は、
とても重宝していたのですが、なくなってしまって残念です。

あまり需要がなかったのでしょうか?

Aベストアンサー

 ソフトそのものやOSそのものの機能などに関することは
質問しても無駄です。それを開発した会社が何らかの理由でそうしているわけで
一般の人に対して理由を公開することはないでしょう。
 
 おっしゃる通りで、VBAで何かやろうと思ってもそのたびに調べなおさなければいけないので時間がかかりますね。以前に作成しておいたものを見てそこから再利用すると少し楽になります。
 ですが、プレゼンテーションに必要なことはもうほとんどなんでも一般機能でできてしまいます。私なんかがVBAでやっていた機能も2010版ではいくつか取り込まれてしまっています。
 最初に書いた通り理由はわかりませんが、マクロ記録機能をつけるよりもパフォーマンス改善に力を入れたのではないかと思います。2010版でも搭載されていません。

 需要とはあまり関係なく作成者が増えているだけなのかもしれませんが、
私がpowerpoint VBAをはじめてたくさんのサンプルコードを無償公開していた頃に比べると、今では、ネット検索のヒット数は40倍ほど増えています。


このQ&Aを見た人がよく見るQ&A

人気Q&Aランキング