エクセル 関数 下から一番最初の行番号

図のように下から数えて一番最初にヒットする空白でない行番号を取得したいのですが、
いい関数はありますか？
VBAは避けたいです。
ご教授よろしくお願い致します。

No.1 ベストアンサー 回答者： CoalTar 回答日時： 2009/08/30 17:21

例題通りなら

=MATCH("ー",A:A)
でどうでしょう？

この回答への補足

すいません。
興味本位で知りたいのですが、"ー"はどういう意味なのでしょうか？
なぜ"ー"で最終行がわかるのか不思議です。
再度ご解答いただけたら幸いです。

補足日時：2009/08/30 18:01

この回答へのお礼

思った通りにできました！ありがとうございます。

お礼日時：2009/08/30 17:59

No.6 回答者： CoalTar 回答日時： 2009/08/31 12:21

#1です

>興味本位で知りたいのですが、"ー"はどういう意味なのでしょうか？
文字列の中では大きな値ということです。
数値の場合は =MATCH(8^3^8,A:A) でもいいです

>なぜ"ー"で最終行がわかるのか不思議です。
MATCH関数の照合の型を1(または-1)にすると二分探索を使った検索を行います。検索対象が昇順(降順)に並んでいるとされているので、最終行を見て判断し、終わりのほうの値がある場所を示すんだと思います
正確なアルゴリズムはわかりませんが、その性質を逆手に取った方法だと考えられます。

参考URL：http://oshiete1.goo.ne.jp/qa5186020.html

この回答へのお礼

再度ありがとうございます。理由がわかってすっきりしました。

お礼日時：2009/08/31 23:12

No.5 回答者： maron--5 回答日時： 2009/08/30 20:09

【数値の場合】

=MATCH(10^10,A:A)
【文字列の場合】
=MATCH("ー",A:A)
【数値・文字列の場合】
=MATCH(1,INDEX(0/(A:A<>""),0))
【「あ」の場合】
=MATCH("あ",A:A)

この回答へのお礼

いろいろは方法を教えてくださってありがとうございます。
大変参考になりました。

お礼日時：2009/08/31 23:11

No.4 回答者： tom04 回答日時： 2009/08/30 19:28

こんばんは！

すでに回答は出ていますが・・・

文字・数値どちらにも対応できる数式です。

尚、配列数式になりますので、↓の数式をコピー＆ペーストした後に
F2キーを押すか、数式バー内を一度クリックして
Shift＋Ctrl＋Enterキーを押してみてください。
数式の前後に｛　｝マークが入り、配列数式になります。

=MAX(IF(A1:A10000<>"",ROW(A1:A10000)))

尚、とりあえず10000行まで対応できる数式です。

以上、参考になれば幸いです。m(__)m

この回答へのお礼

こんな裏技初めて知りました！
２番目のmike_gさんもこのことを言ってるのですね！
ご回答ありがとうございます。参考になりました。

お礼日時：2009/08/31 23:11

No.3 回答者： dodemoii 回答日時： 2009/08/30 18:51

こんにちは

参照過去log
http://detail.chiebukuro.yahoo.co.jp/qa/question …

では。

この回答へのお礼

ご回答ありがとうございます。よく読んでみます。

お礼日時：2009/08/31 23:08

No.2 回答者： mike_g 回答日時： 2009/08/30 17:31

{=MAX((A1:A100<>"")*ROW(A1:A100))} ←配列数式

この回答へのお礼

ちょっと使い方がわからないので調べてみます。

お礼日時：2009/08/30 17:59