役員の退任慰労金を計算するためのエクセルの作成について

お世話になります。
エクセルを、自由に使いこなせないので、皆さんからご指導いただきたく、質問させていただきました。

作成（質問）したい内容

質問その１

役員名　　役職名　就任月日　退任月日　就任期間
東京太郎　理事　　H12.2.1 H15.3.31 3.1

エクセルに上記項目を作成して、
退任年月日－就任年月日＝就任期間　（年・月）
H15.3.31 - H12.2.1 3 . 1
と求めれる関数（計算式）が分かりません。

質問その２
また、このような支給率表があります。
１年　１００％
２年　２００％
３年　３００％
４年　４００％
５年　５００％
求めた年数から、指定される％を見に行くための関数
をお願いします。

質問その３
基本となる、基本給がありまして、
14年４月１日以降は６３０，０００円
　　　　　　以前は７００，０００円を見に行くため
　　　　　　の計算式です。

以上の質問を、文章で表現しますと、
Ａ役員の役員就任期間が３年１ヶ月、但し、規程上には、
１年に満たない場合は、６ヶ月以上は１年とし、未満は
切り捨てます。従って、本例では、３年となります。
上手く質問できませんが、よろしくお願いします。

No.2 ベストアンサー 回答者： maruru01 回答日時： 2003/05/14 14:35

こんにちは。

maruru01です。

質問その1について
E2に、

=DATEDIF(C2,D2,"Y") & "." & DATEDIF(C2,D2,"YM")

で出来ます。

質問その2について
支給率表の年数は"年"という字を付けずに、半角英数で1～5が入力されているとします。
支給率を表示するセルに、

=VLOOKUP(ROUND(DATEDIF(C2,D2,"M")/12,0),支給率表,2,FALSE)

で出来ます。

質問その3について
基準となる日付（14年4月1日）が就任年月日と退任年月日の間にある場合は、基準日以前が630,000で、基準日以後が700,000ということでしょうか。
それとも単に就任年月日との比較でしょうか。

この回答への補足

ありがとうございます。
支給金額の基礎となる数値が、
１４年４月１日を境にして、変わったと
言う意味です。
７０万→（平成１４．３．３１）
　　　　（平成１４．４．　１）→６３万
となるため、７０万と６３万がまたがる場合に、
期間計算などが必要となるのです。
引き続きよろしくお願いします。

補足日時：2003/05/14 21:38

この回答へのお礼

実際にエクセルで作成して見ました。
質問どおりの、１、２について疑問が解けました．
ありがとうございます。

お礼日時：2003/05/15 16:19

No.1 回答者： arukamun 回答日時： 2003/05/14 13:43

その１

就任月日のセルをC2
退任月日のセルをD2
就任期間のセルをE1
として、
D2-C2を行うと、シリアル値の差分になるので、1900/1/1を1としたものになってしまいます。
ですので、

=IF(MONTH(D2)-MONTH(C2)<0,YEAR(D2)-YEAR(C2)-1&"年"&MONTH(D2)+12-MONTH(C2)&"ヶ月",YEAR(D2)-YEAR(C2)&"年"&MONTH(D2)-MONTH(C2)&"ヶ月")

と計算させても良いでしょう。

その２
１年がA3セルなら

=VLOOKUP(JIS(IF(MONTH(D2)-MONTH(C2)<0,YEAR(D2)-YEAR(C2)-1,YEAR(D2)-YEAR(C2)))&"年",A3:B52,2)

といった感じでしょうか。もし1年の様に半角ならJIS関数は要りません。

その３
＞基本となる、基本給がありまして、
＞14年４月１日以降は６３０，０００円
＞　　　　　　以前は７００，０００円を見に行くため
＞　　　　　　の計算式です。

１４年４月１日は就任月日の話しでしょうか？
それであれば、

=IF(C2<DATEVALUE("2002/4/1"),700000,630000)

で良いと思います。

＞以上の質問を、文章で表現しますと、Ａ役員の役員就任期間が３年１ヶ月、但し、規程上には、１年に満たない場合は、６ヶ月以上は１年とし、未満は切り捨てます。従って、本例では、３年となります。

この文章はどこにかかっているのでしょうか？

その２にかかっているとすれば、

=VLOOKUP(JIS(IF(MONTH(D2)-MONTH(C2)<0,IF(MONTH(D2)+12-MONTH(C2)<6,YEAR(D2)-YEAR(C2)-1,YEAR(D2)-YEAR(C2)),IF(MONTH(D2)-MONTH(C2)<6,YEAR(D2)-YEAR(C2),YEAR(D2)-YEAR(C2)+1)))&"年",A3:B52,2)

の様に変更しなくてはなりません。

動作がおかしい、不明な点がありましたら、補足して下さい。

この回答へのお礼

取り急ぎお礼まで。
追って、また、コメントいたします。

お礼日時：2003/05/14 21:37