エクセルでの段階式料金の計算式を教えてください。

エクセルでの段階式料金の計算式を教えてください。

条件
１．対象金額が２００万円まではその５％を計算
２．２００万超～４００万までは４％を計算
３．４００万超～は３％を計算

エクセルの様式
対象金額
２００万円までの金額：計算式１
２００万超～４００万までの金額：計算式2
４００万超～の金額：計算式3
合計：

例
３００万円だとすると条件１と条件２による計算がされ条件３は働きません。
条件１の結果：１０万
条件２の結果：　４万
条件３の結果：　０万

計算式１～３を教えてください。よろしくお願いします。

No.5 ベストアンサー 回答者： sige1701 回答日時： 2010/02/02 13:25

金額を「○万円」単位とした場合で回答します

算式１
=MIN(A1,200)*0.05
算式２
=MAX(0,MIN(A1-200,200))*0.04
算式３
=MAX(0,A1-400)*0.03

全体で
=A1*0.05-MAX(0,A1-200)*0.01-MAX(0,A1-400)*0.01

この回答へのお礼

式が一番美しく見えたのでコチラを選ばせていただきます。

ありがとうございました。

お礼日時：2010/02/02 13:41

No.6 回答者： MackyNo1 回答日時： 2010/02/02 13:30

そのまま数式にするなら以下のようになります。

数式１=MIN(A1,2000000)*0.05

数式２=MIN(A1-2000000,4000000-2000000)*0.04

数式3=MAX(A1-4000000,0)*0.03

まとめると以下の数式になります。

=MIN(A1,2000000)*0.05+MIN(A1-2000000,2000000)*0.04+MAX(A1-4000000,0)*0.03

この回答へのお礼

ありがとうございました。

お礼日時：2010/02/02 22:31

No.4 回答者： KURUMITO 回答日時： 2010/02/02 13:08

Ａ１セルに3000000の数値があるとして条件1の式は次のようです。

=IF(A1="","",MIN(A1,2000000)*0.05)
条件2の式は
=IF(A1="","",IF(A1<=2000000,0,MIN(A1-2000000,4000000)*0.04))
条件3の式は
=IF(A1="","",IF(A1<=4000000,0,(A1-4000000)*0.03))

この回答へのお礼

ありがとうございました。

お礼日時：2010/02/02 22:31

No.3 回答者： watabe007 回答日時： 2010/02/02 11:38

算式１

=IF(A1>=2000000,2000000*0.05,A1*0.05)
算式２
=IF(A1>=4000000,2000000*0.04,IF(A1>2000000,(4000000-A1)*0.04,0))
算式３
=IF(A1>4000000,(A1-4000000)*0.03,0)

この回答へのお礼

ありがとうございました。

お礼日時：2010/02/02 22:32

No.2 回答者： FEX2053 回答日時： 2010/02/02 11:10

本来はVLOOKUPを使うんですが、たった３つならIF文で出来ちゃいますね。

金額を「○万円」単位とした場合は

=IF(A1<200,A1*0.05,IF(A1<400,A1*0.04+2,A1*0.03+6))

金額が「○円」単位の場合、200,400,2,6をそれぞれ1万倍して下さい。
要は全部を「条件３」で計算した場合、条件１、２で増額になる部分は
一定金額になる、ということです。図を書けば分かりやすいんですが。

この回答へのお礼

説明がうまくいっていないのか、回答が求めるものではありません。

ありがとうございました。

お礼日時：2010/02/02 22:33

No.1 回答者： A88No8 回答日時： 2010/02/02 11:09

こんにちは

>１．対象金額が２００万円まではその５％を計算
>２．２００万超～４００万までは４％を計算
>３．４００万超～は３％を計算
　エクセルに限らずコンピュータの場合、こんな風に考えます。

もし対象金額が２００万円までなら対象金額×0.05、それ以外でもし対象金額が４００万円までなら対象金額×0.04、それ以外なら対象金額×0.03

=IF(対象金額<=2000000,対象金額*0.05,IF(対象金額<=4000000,対象金額*0.04,対象金額*0.03))

この回答へのお礼

説明がうまくいっていないのか、回答が求めるものではありません。

対象金額が１０００万の場合

計算１：１０万　←ここの式
計算２：　８万　←ここの式
計算３：１８万　←ここの式
合　計：３６万

※合計額が「対象金額＊３％＋６万」となることはわかっています

よろしくお願いします。

お礼日時：2010/02/02 13:32