ファイル名の一部に年月日が入っているファイルを、指定日以前のもののみ一

ファイル名の一部に年月日が入っているファイルを、指定日以前のもののみ一括削除する方法を教えてください。

上記の目的を果たすためにバッチファイルを作成しようと思っているのですが、当方プログラミング全般に関して全くの素人でして、Web検索で見つけたものを切り貼りして無理やり作ったところ、思うような結果になりませんでした。
（BCPフォルダ直下に当該ファイルを置いた場合削除できたが、サブフォルダのファイルは削除できない）

どうもあと一歩で完成しそうな気がするので、できればこのバッチファイルを元に修正していただけると嬉しいのですが、VBScript等で作成した方が簡単なのであればバッチファイル以外の方法でも構いません。

宜しくお願い致します。


＜予め決められているルール（変更は不可）＞
(1)2010年9月2日21時21分55秒14に作成されたファイルは、「201009」フォルダ配下に「ABC_DEF_GHI_2010090221215514.txt」と「ABC_DEF_GHI_2010090221215514.log」という名前がつけられる。
(2)１日１回バッチファイルを起動し、指定日以前に作成したファイルを全て削除する。


＜作成したバッチファイル（DEL.bat）＞
@echo off

cd ..\BCP

REM －－－－－－－－－－－－－－－
REM 日付のn日前を求める
REM 引数1・・・n（数値）
REM 引数1がないときは1（前日）
REM 引数2・・・YYYY/MM/DD 形式
REM 引数2がないときは本日とする。
REM －－－－－－－－－－－－－－－

if "%1"=="" (
set n=5
) else (
set n=%1
)

if "%2"=="" (
for /F "tokens=1" %%a in ('date /t') do set orgdate=%%a
) else (
set orgdate=%2
)

:年月日の分割
set yy=%orgdate:~0,4%
set mm=%orgdate:~5,2%
set dd=%orgdate:~8,2%
set count=0

:Repeat

:月日の数値化（8進数対策）
set /a mm=1%mm%-100
set /a dd=1%dd%-100

set /a dd=%dd%-1

if %dd% NEQ 0 goto end

:月跨り処理
set /a mm=%mm%-1
if %mm% EQU 0 set mm=12&&set /a yy=%yy%-1

set /a dd=%dd%+31
if "%mm%"=="2" set /a dd=%dd%-3
if "%mm%"=="4" set /a dd=%dd%-1
if "%mm%"=="6" set /a dd=%dd%-1
if "%mm%"=="9" set /a dd=%dd%-1
if "%mm%"=="11" set /a dd=%dd%-1

:閏年処理
:4で割り切れるか？
set /a u=%yy% %% 4
if not %u%==0 goto end
:100で割り切れて、400で割り切れないか？
set /a u=%yy% %% 400
set /a v=%yy% %% 100
if %v%==0 if not %u%==0 goto end
:2月か？
if %mm% EQU 2 set /a dd=%dd%+1

:END
set mm=0%mm%
set mm=%mm:~-2%

set dd=0%dd%
set dd=%dd:~-2%
set /a count=%count%+1
set DT=ABC_DEF_GHI_%yy%%mm%%dd%

IF %count% NEQ %n% goto Repeat

for %%F in (*.txt *.log) do if %%F LSS %DT% del /s %%F

:EXIT


＜フォルダ構造＞
添付画像をご参照下さい。

No.1 ベストアンサー 回答者： kazuma299 回答日時： 2010/09/18 10:54

こんにちは。

>for %%F in (*.txt *.log) do if %%F LSS %DT% del /s %%F
この１行を、以下のように書き換えました。

for /R .\ %%F in (*.txt *.log) do if %%~nF LEQ %DT%99999999 (del /s %%~nxF)


【ご説明】
・for /R .\ %%F in (*.txt *.log)
/R .\と指定すると、カレントフォルダにあるサブフォルダのファイルも検索されます。
カレントフォルダがBCPなので、BCP以下の年月別のサブフォルダにある*.txt *.logが処理対象になります。


・if %%~nF LEQ %DT%99999999 (del /s %%~nxF)
>2)１日１回バッチファイルを起動し、指定日以前に作成したファイルを全て削除する。
この条件があるので、比較方法をLSS（より小さい）からLEQ（以下）に変更しました。

ファイル名の年月部分と比較する年月の桁を合わせるために、%DT%から%DT%99999999に変更しました。

拡張子を除いたファイル名を使うために、%%Fから%%~nFに変更しました。

パスを除いたファイル名を使うために、%%Fから%%~nxFに変更しました。


よろしくお願いします。

この回答へのお礼

大変遅くなりましたが、ご回答有難うございました。

お礼日時：2010/11/07 22:17