エクセルで商品棚卸の照合表を作ろうとしているのですが上手くいきません。
VLOOKUP関数を使って、在庫帳と棚卸票の照合をしようしたのですが、棚卸票にあるのに在庫帳にない商品が相当数ある為、在庫帳を基準にした照合表ではデータの拾い漏れが発生してしまいます。
2つの表のデータ(商品名)をダブらせずに一つの表に転記したいのですが・・・。
どうかアドバイスをお願い致します。

「エクセル 商品棚卸の照合表を作りたいので」の質問画像

A 回答 (3件)

データメニューの統合を使い,2つのリストの寄せ集めを簡単に行えます。



手順:
まとめの集め表を配置したいセル(添付図:B10)を選ぶ(必須)
データメニューの統合を開始する
それぞれのリストのセル範囲を追加する
左端列,上端行にチェックを入れてOKする

必要に応じて差し引きの単純な引き算の式を追加する。




#別の考え方
>棚卸票にあるのに在庫帳にない商品が相当数ある為、
>在庫帳を基準にした照合表ではデータの拾い漏れが発生してしまいます。

データが足りないのが判っている在庫帳を基準にしてもしかたありません。
敢えて言えばモノが「ある」のが判っている棚卸票を基準にして,在庫帳をVLOOKUPしてくるのが適正と言えます。
また実際には棚卸票と在庫帳の商品一覧を単純に縦に続けてコピーして並べ,データメニューのフィルタから「フィルタオプションの設定」を使って(オートフィルタのオプションではないので間違えないこと)「重複を無視する」で漏れもダブりも無い商品一覧リストを作成します。

あとはVLOOKUP関数でそれぞれの商品を各リストから調べてくれば,必要な突き合わせ表を作成できます。
「エクセル 商品棚卸の照合表を作りたいので」の回答画像1
    • good
    • 1
この回答へのお礼

ありがとうございます。
「フィルターオプションの設定」で商品一覧を作って、在庫差異リストを作成することができました。

お礼日時:2011/04/18 10:21

初心者でもデータを入力していくだけで結果が表示されるようにしておくことが便利ですし、分かり易い方法で処理をすることが計算に負担を掛けない方法として適当でしょう。

そのためには作業列を使って処理をすることです。作業列が目障りでしたらその列を選択して右クリックし「非表示」を選択しましょう。
シート1には在庫表が、シート2には棚卸表があるとしてシート3にお望みの表を作るとします。
シート1ではA2セルに商品名、B2セルに数量の文字があり、各データはそれぞれの下行に入力されるとします。
C3セルには次の式を入力して下行にオートフィルドラッグします。

=IF(COUNTIF(A$3:A3,A3)=1,MAX(C$2:C2)+1,IF(COUNTIF(A$3:A3,A3)>1,"重複記載",""))

この式では在庫表に同じ商品名がダブって入力された場合には2つ目の商品名には重複記載が表示されるようにしています。しかし、ダブって記載されていても在庫の数量は問題なくカウントされるようにします。
シート2でもシートと同じようにしますが、C2セルには次の式を入力します。

=MAX(Sheet1!C:C)

C3セルには次の式を入力して下方にオートフィルドラッグします。

=IF(COUNTIF(Sheet1!A:A,A3)>0,"",IF(COUNTIF(A$3:A3,A3)=1,MAX(C$2:C2)+1,IF(COUNTIF(A$3:A3,A3)>1,"重複記載","")))

この式ではシート1に無い商品名についてシート1の番号に続いて番号が付けられます。
次にまとめのためのシート3については次のようにします。
A2セルに商品名、B2セルに帳簿数量、C2セルに棚卸数量、D2セルに棚卸差異と入力します。
A3セルには次の式を入力してC3セルまでオートフィルドラッグしたのちに下方にもオートフィルドラッグします。

=IF(ROW(A1)>MAX(Sheet2!$C:$C),"",IF(ROW(A1)<=MAX(Sheet1!$C:$C),IF(COLUMN(A1)=1,INDEX(Sheet1!$A:$A,MATCH(ROW(A1),Sheet1!$C:$C,0)),IF(COLUMN(A1)=2,SUMIF(Sheet1!$A:$A,$A3,Sheet1!$B:$B),IF(COLUMN(A1)=3,SUMIF(Sheet2!$A:$A,$A3,Sheet2!$B:$B),""))),IF(ROW(A1)<=MAX(Sheet2!$C:$C),IF(COLUMN(A1)=1,INDEX(Sheet2!$A:$A,MATCH(ROW(A1),Sheet2!$C:$C,0)),IF(COLUMN(A1)=2,0,IF(COLUMN(A1)=3,SUMIF(Sheet2!$A:$A,$A3,Sheet2!$B:$B),""))))))

最後にD3セルには次の式を入力して下方にオートフィルドラッグします。

=IF(A3="","",C3-B3)
    • good
    • 1
この回答へのお礼

ありがとうございます。
求めているものが出来ました。

お礼日時:2011/04/19 18:21

こんばんは!


色々方法はあるかと思いますが・・・
一例です。

↓の画像で「在庫帳」・「棚卸表」・「棚卸照合表」それぞれを別Sheetにしています。
(Sheet名は上記の通りにしています)

棚卸表に作業用の列を1列設けます。
棚卸Sheetの作業列C2セルに
=IF(OR(A2="",COUNTIF(在庫帳!A:A,A2)),"",ROW())
という数式を入れオートフィルでずぃ~~~!っと下へコピーしておきます。

そして、棚卸照合表のA2セルに
=IF(COUNTA(在庫帳!A:A)-1+COUNT(棚卸表!C:C)<ROW(A1),"",IF(COUNTA(在庫帳!A:A)-1>=ROW(A1),在庫帳!A2,INDEX(棚卸表!A:A,SMALL(棚卸表!C:C,ROW(A1)-(COUNTA(在庫帳!A:A)-1)))))
B2セルに
=IF(A2="","",IF(COUNTIF(在庫帳!A:A,A2),VLOOKUP(A2,在庫帳!A:B,2,0),0))
C2セルに
=IF(A2="","",IF(COUNTIF(棚卸表!A:A,A2),VLOOKUP(A2,棚卸表!A:B,2,0),0))
D2セルに
=IF(A2="","",C2-B2)
という数式をそれぞれ入力し、A2~D2セルを範囲指定しD2セルのフィルハンドルで下へコピーすると画像のような感じになります。

他に良い方法があればごめんなさいね。m(__)m
「エクセル 商品棚卸の照合表を作りたいので」の回答画像2
    • good
    • 0
この回答へのお礼

ありがとうございます。
いろいろと応用してみたいと思います。

お礼日時:2011/04/19 18:20

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!

このQ&Aを見た人はこんなQ&Aも見ています

このQ&Aを見た人が検索しているワード

このQ&Aと関連する良く見られている質問

Qエクセルで打ち込んだ数字を自動で別シートに表示したい

エクセルでセルに打ち込んだ数字を自動で別シートに表示できる方法があれば、教えてください。

例えば、シート1のC1に5を打ち込んだら、シート2のD2にシート1で打ち込んだ5が自動で表示される。

また1列すべてを自動で表示させる場合、一つのセルの時と違いがありましたら教えてください。よろしくお願いします。

Aベストアンサー

こんばんは。
入力したセルの値を合計とかでなくて、
純粋に別のシートに自動的に表示したいのであれば、
以下の方法があります。

1.1つのセルだけの場合
例)シート1のC1に5を打ち込んだら、
  シート2のD2にシート1で打ち込んだ5が自動で表示される

⇒シート2のD2のセルをアクティブにして「=」を入力
 した後、シート1のC1をクリックする。
 そうするとD2のセルに「=Sheet1!C1」と表示され、値が自動的に
 表示されるようになります。

2.1列全てコピーしたい場合。
  コピー&リンク貼り付けを使うと便利です。

例)例)シート1のC1~C5に何かを入力したら、
  シート2のD2~D7にシート1で打ち込んだものが自動で表示される

  シート1にあるコピー元のセルを範囲選択して、
  シート2のD2の上で「右クリック」⇒「形式を選択して貼り付け」
  をクリックします。

  そして出てきた小さな画面の左下にある「リンク貼り付け」という
  ボタンをクリックすると完成です。
  試してみてください。。

  念のためにリンク貼り付けを図解しているURLを載せておきます。
  参考にしてみてくださいね。。
  http://www.geocities.jp/office_inoue/excel/eq21.htm

こんばんは。
入力したセルの値を合計とかでなくて、
純粋に別のシートに自動的に表示したいのであれば、
以下の方法があります。

1.1つのセルだけの場合
例)シート1のC1に5を打ち込んだら、
  シート2のD2にシート1で打ち込んだ5が自動で表示される

⇒シート2のD2のセルをアクティブにして「=」を入力
 した後、シート1のC1をクリックする。
 そうするとD2のセルに「=Sheet1!C1」と表示され、値が自動的に
 表示されるようになります。

2.1列全てコピーしたい場合。
  コ...続きを読む

Qエクセルで2つのデータを照合したい

会社のPCなのでソフトをダウンロードしたりすることができません。できるだけシンプルで簡単なやり方があれば教えてください。

会員番号と個人名が入ったエクセルファイルが2つあります。
<ファイル1(先輩が担当している顧客)>
101 青木さやか
104 友近
105 山田花子
106 中川翔子
125 真鍋かをり
132 ジャガー横田
144 ともさかりえ
155 小西真奈美
164 篠原涼子
177 山口智子
189 稲森いずみ
211 蒼井優

<ファイル2(私が担当する顧客)>
102 蛯原友里
104 友近
135 山田優
141 押切もえ
144 ともさかりえ
167 堀北真希

<ファイル1>と<ファイル2>には共通して104 友近と144ともさかりえがいるのですが、瞬時にわかるようにするにはどうすればいいでしょうか?

Aベストアンサー

Vlookup関数をファイル1か2のどちらかのC列に入れて同じ値があるかどうかを確認する。
あれば数字が返ってくるし、なければエラー値になるのでそれで判別。

例えばファイル1のC列に1行目に以下を入れてオートフィルターでコピーする
=VLOOKUP(A1,[ファイル2.xls]Sheet1!$A$1:$A$100,1,FALSE)
ファイル名とシート名や範囲は状況に合わせて。

Qエクセルを使用しての実地棚卸

バーコードリーダーとエクセルを使用して、棚卸しを行いたいのですが、教えてください。
物件は2,000件あります。1品ごとに番号をつけて、ラベルにしてバーコード+番号を記載して貼り付けています。

現在は、紙の台帳で1件ずつ確認してレ点チェックをしてるのですが、探すのに時間がかかり台帳も何回もめくってボロボロになってしまいます。
そこで、バーコードリーダーとノートPCを使って確認したいのですが、
エクセルをどのようにすればできるのかわかりません。

棚卸のやり方は下記にしたいです。
対象の物件を発見⇒ラベルを確認⇒バーコドリーダーにて読み取り⇒リストの対象物件に確認済みフラグもしくは色塗りつぶし、数字フラグにて確認済にする
⇒続けて次の物件を発見したら、ラベル確認⇒バーコード読み取り・・・繰り返し

パソコンのOSは、Win7Pro
エクセルは、2007です。
バーコードは、CODE128

よろしくお願いします。

Aベストアンサー

No2です。
別途、現物確認 という名前でシートを準備
ノートパソコンとバーコードリーダーを準備
現物に張ってあるバーコードを片っ端から読み込む
仮に、A列にバーコードの番号が並ぶ
 A
読み込みバーコード

添付のシートのチェックのセルに
=IF(COUNTIF(現物確認!A:A,C12)=1,"レ","")
とでも入れて下へコピー
式の意味は、現物確認のシートのA列に
このシートのC12と同じ番号が一個あれば
チェックマーク
無ければ(或いは2個以上入っていたら)空白
と云う意味です。

同様の関数を、現物確認のシートのB列にも入れておけば
現物があるのに、台帳に記載されていな現物の発見も出来ると思います。

Qエクセルで、列内が同じ名前を集計する方法は?

エクセルで以下のような表を作成したとします。

      A列   B    C    D
 1行   名前   項目   金額
 2    すずき  あいう  100
 3    すずき  かきく  200
 4    すずき  さしす  450
 5    さとう  あいう  150
 6    さとう  さしす  200
 7    はやし  あいう  250 
 8    はやし  かきく  170
 9    はやし  たちつ  980

B列の名前が同じ者の、金額の合計をD列に出したいのです。
D4に すずきの合計 750、D6にさとうの合計 350、
D9にはやしの合計 1150  というふうに。
全部で100人分位、データ行数は15000ほどあるのですが
これをさっとできるようにはどのようにしたら良いのでしょうか?

Aベストアンサー

次の方法は如何でしょうか。
D2に=IF(COUNTIF(A:A,A2)=COUNTIF($A$2:A2,A2),SUMIF(A:A,A2,C:C),"")を入力→D2を選択→フィルハンドル(D2セル枠右下の■)をダブルクリック
但し、C列途中に空白がある場合、その直前までしかコピーされませんので、空白セル前のセルを下方向にコピー後、同様にフィルハンドルをダブルクリックし下さい。

QExcelで[表1]にあって、[表2]にないものを抽出する関数

Excelで[表1]にあって、[表2]にないものを抽出する関数

例)[表1]   [表2]
   A社     A社
   D社     D社
   R社     P社
   P社     R社
   D社
   F社
   F社

上記は簡単に書きましたが、表1に重複するものも含め、300社程度あるなかで
表2にリストアップされていない会社を見つける関数やその他方法論があれば
ぜひ教えてください!
(例でいえば、F社を見つける方法です。)

抽出するのは別シートでも、同じシートでも構いません。

Excel2003でも対応できるものであれば、なお嬉しいです。

よろしくお願いします。

Aベストアンサー

Countif関数で同じものがいくつあるか数えさせます。
   A   B        C
  [表1]表2にある数   [表2]
   A社          A社
   D社          D社
   R社          P社
   P社          R社
   D社
   F社
   F社
だとして
B列に =Countif(C:C,A2)
と入れて下までコピィすれば 表2に同じものがいくつあるか出ますので
0 がないものです。

Q(Excel)あるセルに文字を入力しただけで、同じブック内のほかのワークシートにも、同じ文字が自動的に入るようにするには?

こんにちは。
質問内容はタイトルのとおりです。

あるワークシートのあるセルに文字を入力すると、ほかのワークシートのセルにも同じ文字が自動的に書き込まれる方法を知りたいです(ブックは同じ)。複数のワークシートを制御するには、やはりマクロを使うのでしょうか?

よろしくお願いします。

Aベストアンサー

clam_chowderさん、こんにちは。

Sheet1のA1にたとえば「100」と入力しますね。
Sheet2のA1に、これと同じ数値を表示するには、
 =Sheet1!A1
でOKです。

数式をいれるのが苦手なら、
Sheet2のA1セルで「=」を入力すると、数式入力状態に入りますから、
ここでSheet1のシートタブをクリックし、
リンクしたいA1セルをクリックしてEnterすると、
自動的にさきほどと同じ式が入ります。

Qエクセルを使った、在庫管理と発注。

エクセルを使った、在庫管理と発注。


私は、エクセルが得意ではないのですが、今日、用事で退社する上司に「手が空いているので何かやっておくことがあったら言ってください」といったところ、思わぬ無茶振りをされてしまい、とても困っています。在庫管理などに関する知識がまったく無い人間なので、説明が長くなってしまうことと、わかりにくい点があるかもしれないですが、なるべくわかりやすく書こうと思うのでご協力お願いいたします。


現在当社の商品在庫は、エクセルで管理されております。
発注は目視で足りないと思ったら適性分だけ頼むかたちです。

今度上司のしたいことはエクセルの在庫データを使って「発注リスト」が自動的に作成されることです。

例えば、商品Aの適正在庫が5だとして、それを切ったら自動でリストの中に適正在庫になるような個数と商品名が載る。あとはそれをプリントアウト(パソコンからも送れるのでそれで自動発注できればなお良いです)してFAXで発注。というかたちです。

それは、エクセル上で全部済めばそれでも良いですが、そのやり方が複雑な場合、こんな方法、こんな簡単なソフトがあるよ、という意見がありましたらよろしくお願いしたいです!!

当社POSシステムはございません。導入もいたしませんのでどうかパソコンでの方法でご回答お願いいたします。

アクセスは、当社で使える者がいないため、なるべくエクセルを使う形にしたいみたいです。

何か説明が足りないようでしたらご指摘ください。

よろしくお願いいたします!

エクセルを使った、在庫管理と発注。


私は、エクセルが得意ではないのですが、今日、用事で退社する上司に「手が空いているので何かやっておくことがあったら言ってください」といったところ、思わぬ無茶振りをされてしまい、とても困っています。在庫管理などに関する知識がまったく無い人間なので、説明が長くなってしまうことと、わかりにくい点があるかもしれないですが、なるべくわかりやすく書こうと思うのでご協力お願いいたします。


現在当社の商品在庫は、エクセルで管理されております。
発注は目視...続きを読む

Aベストアンサー

No.1です!
何度もごめんなさい。
前回は単に適正在庫数に足らないものだけを表示するだけです。
ご希望としてはそのリストを印刷できる表にしたい!ということだと思いますので、
もう一度画像をアップしてみます。

商品補充リストをSheet2に表示するようにしてみました。
Sheet1は前回そのままで、

Sheet2のA2セルに
=IF(COUNT(Sheet1!$C$2:$C$1000)<ROW(A1),"",INDEX(Sheet1!A$2:A$1000,SMALL(IF(Sheet1!$C$2:$D$1000<>"",ROW($A$1:$A$999)),ROW(A1))))

これは配列数式になってしまいますので、データ量が多い場合はコンピュータにかなりの負担を与えます。
という訳で、Sheet1の1000行目まで対応できる数式にしていました。

Sheet2のA2セルにこの画面からコピー&ペーストしただけではエラーになると思います。
貼り付け後、F2キーを押す、または貼り付けセルをダブルクリック、または数式バー内で一度クリックします。
編集可能になりますので、Shift+Ctrlキーを押しながらEnterキーで確定します。
数式の前後に{ }マークが入り配列数式になります。

そして、B2セルに
=IF(A2="","",VLOOKUP(A2,Sheet1!A:C,3,0))
(これは配列数式ではありません)

最後にZ2・B2セルを範囲指定し、B2セルのフィルハンドルで下へコピーすると
画像のような感じになります。

以上、参考になればよいのですが・・・
何度も失礼しました。m(__)m

No.1です!
何度もごめんなさい。
前回は単に適正在庫数に足らないものだけを表示するだけです。
ご希望としてはそのリストを印刷できる表にしたい!ということだと思いますので、
もう一度画像をアップしてみます。

商品補充リストをSheet2に表示するようにしてみました。
Sheet1は前回そのままで、

Sheet2のA2セルに
=IF(COUNT(Sheet1!$C$2:$C$1000)<ROW(A1),"",INDEX(Sheet1!A$2:A$1000,SMALL(IF(Sheet1!$C$2:$D$1000<>"",ROW($A$1:$A$999)),ROW(A1))))

これは配列数式になってしまいますので、データ量が多...続きを読む

Qバーコードを使って在庫管理をaccesかexcelで行いたいのですが。

こんにちは。
バーコードを使って自社倉庫内の在庫管理をaccesかexcelで行いたいと考えております。
ACCES,excelのマクロやVBA、をほんの少々かじったレベルです。
バーコードで自社倉庫内の商品を管理したいと考えております。
必要な機能としまして、商品の入庫、出庫、リアルタイム在庫の表示、月末棚卸し、csv出力等一般的な倉庫の在庫管理を作成できればと考えております。(入出庫履歴等の表示はほしいですが、販売管理は必要なく在庫の管理のみ必要です)
そして、それをラベル発行機とハンディーを使ってバーコードで管理できればと思っております。
正直全く何もないところから作成できる自信がありません。
そこで何か、参考になる書籍か安くて(1万円まで位)自分で改良できVBAのソースコード何かもコピペできるような都合のよいソフト等はありませんでしょうか?
それとも、その他方法はありませんか?
素人が手を出すなと言われそうですが、がんばってみたいなと思っております。
どうぞ、質問内容もわかりにくいところが多々あるとは思いますがどうぞご指導お願いいたします。

こんにちは。
バーコードを使って自社倉庫内の在庫管理をaccesかexcelで行いたいと考えております。
ACCES,excelのマクロやVBA、をほんの少々かじったレベルです。
バーコードで自社倉庫内の商品を管理したいと考えております。
必要な機能としまして、商品の入庫、出庫、リアルタイム在庫の表示、月末棚卸し、csv出力等一般的な倉庫の在庫管理を作成できればと考えております。(入出庫履歴等の表示はほしいですが、販売管理は必要なく在庫の管理のみ必要です)
そして、それをラベル発行機とハンディーを使...続きを読む

Aベストアンサー

だいぶ前ですが、ショップの生産指示や完成実績管理のため、バーコードを使ったシステムを自製したことがあります。
バーコードは社内利用なのでCODE39を使いましたが、バーコードの入出力自体は結構簡単にできました。(初めてだったんですが、2日間位で)
扱うデータが膨大だったので、DBはサーバーのORACLEを使い、管理部分や表示、帳票出力などの個別ソフトはVB、C、JAVA(Webベースでもできるようにしたため)などを使い、こちらのほうは多少時間を要しました。
在庫管理ソフト機能とDB構造をどうするかのほうが、いろいろな面で大変と思われます。

在庫管理の規模によると思いますが、質問の内容からは
リアルタイムに対応できるデータベースと専用の開発ソフトが必要なのか、扱うデータ量、運用する環境、期待するレスポンスなどが不明なので、Access/ExcelとMDBを使う程度で済むレベルなのか、VBAのみで構築は若干難しい気もしますが、Windows API等と組み合わせると何とかなりそうなレベルなのか、ちょっと判断ができません。
まずは、必要な機能と仕組みをきちんと整理してから、着手されたほうが良いと思われますが、簡単な仕組み(プロトタイプ)を作って実用性の確認をしてみる方法もあります。

実務に役立つ在庫管理・・・左側の目次から選択できます。
http://www.sk-zaiko.com/unyou/un04_barcode.html

ソフトに関しては自前で作成ばかりだったので、どういったものが出回っているかあまり知りません。
「在庫管理」、「在庫管理 ソフト」などをキーに検索してみてください。
 

だいぶ前ですが、ショップの生産指示や完成実績管理のため、バーコードを使ったシステムを自製したことがあります。
バーコードは社内利用なのでCODE39を使いましたが、バーコードの入出力自体は結構簡単にできました。(初めてだったんですが、2日間位で)
扱うデータが膨大だったので、DBはサーバーのORACLEを使い、管理部分や表示、帳票出力などの個別ソフトはVB、C、JAVA(Webベースでもできるようにしたため)などを使い、こちらのほうは多少時間を要しました。
在庫管理ソフト機能とDB構造をどうするかの...続きを読む

QWord 文字を打つと直後の文字が消えていく

いつもお世話になっています。
Word2000を使っているものです。
ある文書を修正しているのですが,文章中に字を打ち込むと後ろの字が消えてしまいます。
分かりにくいですが,
「これを修正します。」
という文章の「これを」と「修正します。」の間に「これから」という単語を入れたときに,その場所にカーソルを合わせて「これから」と打つと,
「これをこれからす。」
となってしまいます。
他の文書では平気です。
何か解決する方法があれば教えて下さい。

Aベストアンサー

入力モードが「挿入」(普通の入力)から、「上書き」になってしまっているのだと思われます。
キーボードに[Insert]というキーがあると思いますので、1度押してみてください。

Qエクセルで、条件に一致した行を別のセルに抜き出す方法

エクセルで、指定した条件に一致するセルを含む行をすべて抜き出す方法が知りたいです。

たとえば、

<A列> <B列> <C列>
7/1 りんご 100円
7/2 ぶどう 200円
7/2 すいか 300円
7/3 みかん 100円

このような表があって、100円を含む行をそのままの形で、
別のセル(同じシート内)に抜き出したいのですが。

7/1 りんご 100円
7/3 みかん 100円

抽出するだけならオートフィルターでもできますが、
抽出結果を自動的に、別の場所に、常に表示させておきたいのです。

初歩的な質問だと思いますが、検索しても分からなかったので、よろしくお願いします。

Aベストアンサー

同じ質問が結構よく出てますが、そんなに初歩的でもありません
別シートのA1セルに「100円」と入力し、そのシートの任意のセルに以下の式を貼り付けて下さい。後は、下方向、右方向にコピー。
日付のセル書式は「日付」形式に再設定してください

=IF(COUNTIF(Sheet1!$C:$C,$A$1)>=ROW(A1),INDEX(Sheet1!A:A,LARGE(INDEX((Sheet1!$C$1:$C$500=$A$1)*ROW(Sheet1!$C$1:$C$500),),COUNTIF(Sheet1!$C:$C,$A$1)-ROW(A1)+1)),"")

データ範囲は500行までとしていますが、必要に応じて変更して下さい


このQ&Aを見た人がよく見るQ&A

人気Q&Aランキング

おすすめ情報