エクセル２００７で既に開かれているCSVファイル

Question

のセルA1に特定の文字が入力されているファイルに対してマクロを実行したいのです。

会社のイントラネットから各種データを開くと（ダウンロードではありません。）以下のファイル名になります。
list.csv , list(1).csv , list(2).csv , list(4).csv , … , list(n).csv ←list(3).csvは不要だったので閉じられている例です。

マクロ実行前に、例えば list.csv と list(4) のセルA1に特定の文字が入力されている場合は、どちらかを選択するか、処理を中止する。（希望は前者ですが。。。）

対象のCSVファイルが無ければ（CSVファイルが開かれていない、または、A1が不一致）メッセージを出力する。

Sub Sample()
Dim myChkBook As Workbook
Dim i As Integer
    On Error GoTo Err0
    Set myChkBook = Workbooks("List.csv")　'この時にセルA1の文字を比較したいです。
    Call 処理
    Exit Sub

Err0:
For i = 1 To 5　'←５は少なくとも list(n).csv のｎまで処理したい。
    On Error Resume Next
    Set myChkBook = Workbooks("List(" & i & ").csv")　'←現状では、開かれていないファイルが
    On Error GoTo 0　　　　　　　　　　　　　　　　　　　　　　'あるとエラーになってしまいます。
    Call 処理
    Exit Sub
Next i
    Exit Sub
Err1:
    MsgBox "対象のＣＳＶファイルが見つかりませんでした。"
End Sub

出だしで躓いてしまい、悩んでおります。
良い方法をご教示いただければと思い、質問致します。
宜しくお願い致します。

end-u · Accepted Answer

提示コードはあくまでサンプルなので「もったいない」事もなく、
あまり気にされなくても良いかと。
文章で説明するよりコードを動かしたほうが理解し易い場合もあります。
それより
同名ファイルを同時に開く事はできないのでよく確認したほうが良いですよ。

Sub try_2()
　　Dim wb As Workbook
　　Dim s　As String
　　Dim i　As Long
　　ReDim v(1 To 10) As String
　　
　　For Each wb In Workbooks
　　　　s = LCase(wb.Name)
　　　　If s = "list.csv" Or s Like "list(#).csv" Then
　　　　　　If wb.Sheets(1).Range("A1").Value = "特定文字" Then
　　　　　　　　i = i + 1
　　　　　　　　v(i) = wb.Name
　　　　　　　　Debug.Print i, v(i) '確認用
　　　　　　End If
　　　　End If
　　Next
　　Select Case i
　　Case 0
　　　　MsgBox "no file"
　　Case 1
　　　　MsgBox v(1) & "処理" 'Call 処理
　　Case Is > 1
　　　　MsgBox i & "個から選択"
　　　　ReDim Preserve v(1 To i)
　　　　s = Join(v, vbLf) & vbLf & vbLf
　　　　For i = 1 To i
　　　　　　Application.Goto Workbooks(v(i)).Sheets(1).Range("A1")
　　　　　　If MsgBox(s & "の" & vbLf & vbLf & v(i) & " ?", vbYesNo) = vbYes Then
　　　　　　　　MsgBox v(i) & "処理" 'Call 処理
　　　　　　　　Exit For
　　　　　　End If
　　　　Next
　　End Select
End Sub

仕様的にはLoopで選択させるよりも対象外ファイルを閉じてもらったほうが良いような気もしますね。
Case Is > 1 の内容を以下に変えるとか。

ReDim Preserve v(1 To i)
MsgBox Join(v, vbLf) & vbLf & vbLf & i & " ファイルあり。" _
　　　　　& vbLf & vbLf & "対象外ファイルを閉じて再実行。"

end-u · Answer

今ひとつ納得いかない感もありますが
取り敢えず..
名前に頼らずCollectionに格納したものを使う方式です。

Sub try_3()
　　Dim col As Collection
　　Dim wb　As Workbook
　　Dim s　 As String
　　Dim i　 As Long

ReDim v(1 To Workbooks.Count) As String
　　Set col = New Collection
　　For Each wb In Workbooks
　　　　s = LCase(wb.Name)
　　　　If s = "list.csv" Or s Like "list(#).csv" Then
　　　　　　If wb.Sheets(1).Range("A1").Value = "特定文字" Then
　　　　　　　　i = i + 1
　　　　　　　　v(i) = wb.Name
　　　　　　　　col.Add wb
　　　　　　End If
　　　　End If
　　Next

Select Case i
　　Case 0
　　　　MsgBox "no file"
　　Case 1
　　　　MsgBox v(1) & "処理" 'Call 処理
　　Case Is > 1
　　　　MsgBox i & "個から選択"
　　　　ReDim Preserve v(1 To i)
　　　　s = Join(v, vbLf) & vbLf & vbLf
　　　　For Each wb In col
　　　　　　Application.Goto wb.Sheets(1).Range("A1")
　　　　　　If MsgBox(s & "の" & vbLf & vbLf & wb.Name & " ?", vbYesNo) = vbYes Then
　　　　　　　　MsgBox wb.Name & "処理" 'Call 処理
　　　　　　　　Exit For
　　　　　　End If
　　　　Next
　　End Select

Set wb = Nothing
　　Set col = Nothing
End Sub

end-u · Answer

>Set myChkBook = Workbooks("List(" & i & ").csv")　'←現状では、開かれていないファイルが
>On Error GoTo 0 　　　　　　　　　　　　　　　　　'あるとエラーになってしまいます。
On Error制御の後に 変数 Is Nothing 判定すれば良いです。
If Not myChkBook Is Nothing Then
　　Call 処理
End If

>マクロ実行前に、例えば list.csv と list(4) のセルA1に特定の文字が入力されている場合は、どちらかを選択するか、処理を中止する。（希望は前者ですが。。。）
ユーザーに選択させるという意味でしょうか？
例えば
Sub try()
　　Dim wb As Workbook
　　Dim v(1 To 10) As String
　　Dim s As String
　　Dim i As Long

For Each wb In Workbooks
　　　　s = LCase(wb.Name)
　　　　If s = "list.csv" Or s Like "list(#).csv" Then
　　　　　　If wb.Sheets(1).Range("A1").Value = "特定文字" Then
　　　　　　　　i = i + 1
　　　　　　　　v(i) = wb.Name
　　　　　　End If
　　　　End If
　　Next
　　Select Case i
　　Case 0
　　　　MsgBox "no file"
　　Case 1
　　　　MsgBox v(i) & "処理" 'Call 処理
　　Case Is > 1
　　　　MsgBox i & "個から選択"
　　　　For i = 1 To i
　　　　　　If MsgBox(v(i) & "?", vbYesNo) = vbYes Then
　　　　　　　　MsgBox v(i) & "処理" 'Call 処理
　　　　　　　　Exit For
　　　　　　End If
　　　　Next
　　End Select
End Sub

選択させるなら、対象ファイルがいくつあるか、全調査しないといけないですよね。
選択方法については、MsgBoxのLoopではなくて
Application.InputBoxを使って処理したいファイルをアクティブにさせるという方法もありかもしれません。

エクセル２００７で既に開かれているCSVファイル

提示コードはあくまでサンプルなので「もったいない」事もなく、

この回答への補足

今ひとつ納得いかない感もありますが

>Set myChkBook = Workbooks("List(" & i & ").csv") '←現状では、開かれていないファイルが

この回答への補足

似たような質問が見つかりました

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング

>Set myChkBook = Workbooks("List(" & i & ").csv")　'←現状では、開かれていないファイルが