SelectとActivateの違いは？

Sub Macro1()
Sheets("Sheet1").Activate
Sheets("Sheet2").Select
End Sub
は、同じ動きをします。

マクロの記録でシートを選択すると、Selectの方が取得されます。
SelectとActivateの違いを説明できる方お願いします。

No.1 ベストアンサー 回答者： keithin 回答日時： 2012/10/13 16:05

selectは二つ以上のモノを同時にセレクトできます。

たまたまその時に１つのモノをセレクトすると、activateと同じになります。

この回答へのお礼

ご回答ありがとうございます。

お礼日時：2012/10/21 22:57

No.2 回答者： cj_mover 回答日時： 2012/10/13 17:40

こんにちは。

お邪魔します。

理解の助けになれば嬉しいのですけれど。

' ' Sheet1, Sheet2, Sheet3 について.Selectと.Activateの挙動の違いを示します
Sub お試し用()
　　Sheets(Array("Sheet1", "Sheet2")).Select
　　MsgBox "Sheets(Array(""Sheet1"", ""Sheet2"")).Select" & vbLf & vbLf _
　　　　& "Sheet1 と Sheet2 を同時に選択しました" & vbLf _
　　　　& "選択中のシート数は　" & ActiveWindow.SelectedSheets.Count & vbLf _
　　　　& "アクティブシートは　" & ActiveSheet.Name

　　Sheets("Sheet2").Activate
　　MsgBox "Sheets(""Sheet2"").Activate" & vbLf & vbLf _
　　　　& "選択中の Sheet1,Sheet2 の中から Sheet2 をアクティブにしました" & vbLf _
　　　　& "選択中のシート数は　" & ActiveWindow.SelectedSheets.Count & vbLf _
　　　　& "アクティブシートは　" & ActiveSheet.Name

　　Sheets("Sheet3").Activate
　　MsgBox "Sheets(""Sheet3"").Activate" & vbLf & vbLf _
　　　　& "Sheet3 をアクティブにしようとしましtが" & vbLf _
　　　　& "直前に選択中だったシ－ト に含まれてない為" & vbLf _
　　　　& "Sheet3 を (.Activate する代わりに) .Select しました" & vbLf _
　　　　& "選択中のシート数は　" & ActiveWindow.SelectedSheets.Count & vbLf _
　　　　& "アクティブシートは　" & ActiveSheet.Name

　　Sheets("Sheet1").Select
　　MsgBox "Sheets(""Sheet1"").Select" & vbLf & vbLf _
　　　　& "Sheet1 を選択しました" & vbLf _
　　　　& "選択中のシート数は　" & ActiveWindow.SelectedSheets.Count & vbLf _
　　　　& "アクティブシートは　" & ActiveSheet.Name
End Sub

この回答へのお礼

ご回答ありがとうございます。

お礼日時：2012/10/21 22:57

No.3 回答者： kiyomac#1 回答日時： 2012/10/13 20:24

Selectは複数のデータから指定データを選択し、開く。

Activateは指定した単一のデータを開く。

Select　a
データ1
データ2

この回答へのお礼

ご回答ありがとうございます。

お礼日時：2012/10/21 22:58