ドロップダウンリストの行を増やしたいです。VBA。

エクセル2000。VBAでコンボボックスを作成したのですが、ドロップダウンリストの表示する行の増やし方が分かりません。” 担当者”は20セル（人）指定しています。

プロパティからならListRowsを8から変更すればいいだけなので分かります。ですがVBAで実施したいです。ドロップダウンリスト表示を20に増やすにはどうしたらいいでしょうか？かなり困っていますのでどうぞ宜しくお願いします。

Selection.ListRows = 20
を足したところ、実行時エラー438「オブジェクトは、このプロパティまたはメソッドをサポートしていません。」となりました。

Sub test()

Dim sh As Worksheet
Set sh = Worksheets("Sheet1")
For i = 1 To 100
l = sh.Cells(i, "H").Left
t = sh.Cells(i, "H").Top
w = sh.Cells(i, "H").Width
h = sh.Cells(i, "H").Height
sh.OLEObjects.Add(ClassType:="Forms.ComboBox.1", _
Left:=l, Top:=t, Width:=w, Height:=h _
).Select
Selection.ListFillRange = "担当者"
Selection.LinkedCell = "H" & i
Selection.PrintObject = False
Next i
End Sub

No.1 ベストアンサー 回答者： watabe007 回答日時： 2013/11/10 09:29

.Object.ListRows = 20

では、如何でしょうか

For i = 1 To 100
　　l = sh.Cells(i, "H").Left
　　t = sh.Cells(i, "H").Top
　　w = sh.Cells(i, "H").Width
　　h = sh.Cells(i, "H").Height
　　With sh.OLEObjects.Add(ClassType:="Forms.ComboBox.1")
　　　　.Left = l
　　　　.Top = t
　　　　.Width = w
　　　　.Height = h
　　　　.ListFillRange = "担当者"
　　　　.Object.ListRows = 20
　　　　.LinkedCell = "H" & i
　　　　.PrintObject = False
　　End With
Next i

この回答へのお礼

早急な回答本ありがとうございました。

問題なく20行表示することができました！！

かなり急ぎでどうしようかと思っていました。

お時間とって頂き感謝しております。

本当にありがとうございした。

お礼日時：2013/11/10 12:39