エクセルの複数せるの内容の一致を確認したい

エクセルでa1b1c1d1の4セルの値が同じなら●、１つでも異なっていたらXとセルE1に表示させたいのです。
セルが2つだったら=IF(A1=B1,"●","×")とできるのですが多数だとわかりません
教えてください！！

No.6 回答者： imogasi 回答日時： 2004/06/04 19:43

既出回答と似たり寄ったりですが、

私は
=IF(AND(COUNTBLANK(A1:D1)=0,AND(A1=B1,B1=C1,C1=D1)),"○","×")
で小数例テストで旨く行きました。

この回答への補足

回答ありがとうございます
A1には5、B1、C1、D1は空欄、D1には5　と入力した場合のの表示は●とはいきませんか？

つまり空白以外のみを判定対象として、その入力されている値のみを判定したいのですが。無理でしょうか？
なんだか　面倒ですね？

補足日時：2004/06/07 12:17

No.5 回答者： inte-nori 回答日時： 2004/06/04 17:11

#1&#4です。

たびたびすみません。

#4の例ですと、B1,C1,D1に数値が入っていて、A1が空白である場合にうまく機能しないので、下記のようにして下さい。

=IF(A1&B1&C1&D1="","",IF((A1=B1)*(B1=C1)*(C1=D1),"●","X"))

No.4 回答者： inte-nori 回答日時： 2004/06/04 17:05

#1です。

=IF(A1="","",IF((A1=B1)*(B1=C1)*(C1=D1),"●","X"))

でどうでしょうか？

No.3 回答者： mshr1962 回答日時： 2004/06/04 12:42

いくつか方法があります。

=IF(COUNTIF(A1:D1,A1)=4,"●","×")
=IF(AND(A1=B1,A1=C1,A1=D1),"●","×")
=CHOOSE(COUNTIF(A1:D1,A1),"×","×","×","●")

=COUNTIF(A1:D1,A1) で表示形式をユーザー定義で　[=4]"●";"×"

この回答への補足

空白セルは無視するってことって可能でしょうか？

補足日時：2004/06/04 14:23

No.2 回答者： SAKURAMYLOVE 回答日時： 2004/06/04 12:41

以下のようにします。

=IF(AND(EXACT(A1,B1),EXACT(C1,D1),EXACT(A1,C1)),"●","×")

この回答への補足

空白セルは無視するってことって可能でしょうか？
セル内に値があるセルのみを対象としてその値のみが同じかどうかの判定？

補足日時：2004/06/04 14:24

No.1 回答者： inte-nori 回答日時： 2004/06/04 12:39

=IF((A1=B1)*(B1=C1)*(C1=D1),"●","X")

のように、条件式を( )でくくって「*」でつなぐと、ANDの意味になります。

同様に「+」でつなぐとORの意味になります。
ご参考までに。