Excel オートコンプリート機能を応用したい

Question

Excelで見積書のフォーマットを作成しています。
顧客数が非常に多く、正しい顧客名が入力できるように、そして選択しやすいように
データの入力規則のリストを活用しておりましたが、
顧客数が多いのでリストが小さく、選びづらくなってしまい、違い方法を探しています。

Excelの関数またはVBAなどで、オートコンプリート機能のように、いくつか文字を入力すると、
指定のリスト一覧の中から候補がいくつか出てきて、いずれかを選択すると、そのセルに入力できる。
というようなことができないでしょうか。
ご教示願います。

ママチャリ · Accepted Answer

こんなのはどうでしょう。
添付画像のように、A列に顧客名を並べます。
下記のマクロをSheetモジュールに張り付けます。
B1セルに、顧客名の一部を入力します。
すると・・・。
入力した情報で顧客名が一意になる場合は、その顧客名で決定されます。
一意にならない場合は、顧客名のリストが表示され、選択することができるようになります。

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Address <> "$B$1" Then Exit Sub
    If Target.Value = "" Then Exit Sub
    Dim i As Long
    Dim a As String
    Dim s As String
    Dim h As Long
    For i = 1 To Cells(Rows.Count, "A").End(xlUp).Row
        If Cells(i, "A").Value Like "*" & Target.Value & "*" Then
            h = h + 1
            a = a & s & Cells(i, "A").Value
            s = ","
        End If
    Next i
    If h = 1 Then
        Application.EnableEvents = False
        Target.Value = a
        Application.EnableEvents = True
        Exit Sub
    End If
    If h = 0 Then a = "該当する顧客名が存在しません！！"
    With Target.Validation
        .Delete
        .Add Type:=xlValidateList, AlertStyle:=xlValidAlertInformation, _
        Operator:=xlBetween, Formula1:=a
        .IgnoreBlank = True
        .InCellDropdown = True
        .InputTitle = ""
        .ErrorTitle = ""
        .InputMessage = ""
        .ErrorMessage = ""
        .IMEMode = xlIMEModeNoControl
        .ShowInput = True
        .ShowError = False
    End With
    Target.Select
    SendKeys "%{DOWN}"
End Sub

yotawmonpt · Answer

それよりも、テンプレートを作成したらいかが。それとオートフィル機能も。

WindFaller · Answer

このご質問をしばらく考えて昔も挑戦したことがあったことですが、失敗しましたが、技術が上がった今もうまく行きませんでした。
入力規則の出て来るものをコントロールすることは可能だと言えば可能なのですが、タイミングが悪いのです。

逆に、オートコンプリートを人為的に出てくるものを替えるということと考えました。次に何を出すかは、ユーザーの文字入力に依存しています。ユーザーに何秒でも待たせればもう失敗です。

ある程度までは可能なのですが、入力してすぐに素早い対応を示せないと思うのです。Excelが本体でやっているオートコンプリートを、ユーザーアドインやマクロで出すワザというのは、やったことはあります。でも、それ以降挑戦したことがありません。

そこで、便宜的ですが、IME のユーザー辞書を利用したらどうでしょうか。
今でも変わらないのなら、ユーザー辞書そのものは、Text で管理出来たと思います。

https://121ware.com/qasearch/1007/app/servlet/relatedqa?QID=013008

Excel オートコンプリート機能を応用したい

それよりも、テンプレートを作成したらいかが。

このご質問をしばらく考えて昔も挑戦したことがあったことですが、失敗しましたが、技術が上がった今もうまく行きませんでした。

こんなのはどうでしょう。

似たような質問が見つかりました

このQ&Aを見た人はこんなQ&Aも見ています

関連するカテゴリからQ&Aを探す

このQ&Aを見た人がよく見るQ&A

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング