エクセルVBAで次の様にデーターをテンプレートに反映したいのですが、よろしくお願い致します。

先程のとよく似ていますが、複雑です。
バラシシートと短冊シートがあり、（バラシシートのデーターは増減します）バラシシートのS列データーを短冊シートに記入していくようにしたいのですが、（短冊シートは罫線のテンプレートがつくってあります）1番から2，3，4とデーターを入れていきたいのですが、1つのボックスは４列６行の２４個入るようになってますが、赤の矢印のように左上から下に入れて行きます。ただし、記号が変われば次の行（下）に入るというようにしていきたいのです、そしてバラシシートのS列データーが空欄になれば1つのロットが終了となります。そこで、７のマスの様に飛ばしてまた、次のロットを８から始めるというようにしたいのですが、詳しい方よろしくお願い致します。　

https://gyazo.com/1d54c5cbe862e7cc29cbec48711afcea

質問者からの補足コメント

• 短冊シートに色も反映したいです。

    補足日時：2022/04/17 20:17

No.1 ベストアンサー 回答者： tatsumaru77 回答日時： 2022/04/19 11:03

>記号が変われば次の行（下）に入るというようにしていきたいのです、

記号が変わった時に、次の行になっていた場合は、1行空白を開けないで書き込むようにしています。
添付図の例では、C3,D3,E3がFAシボになっていた場合です。その場合は、１行開けずに、B4からFBブラックを書き込むようにしています。
以下のマクロを標準モジュールに登録してください。

Option Explicit

Dim sh1 As Worksheet 'バラシシート
Dim sh2 As Worksheet '短冊シート
Public Sub 短冊シート設定3()
Dim maxrow1 As Long
Dim maxrow2 As Long
Dim max_box As Long
Dim i As Long
Dim wrow As Long
Dim boxNo As Long
Dim seqNo As Long
Dim box_row As Long
Dim box_col As Long
Dim pv As String
Dim y As Long
Set sh1 = Worksheets("バラシ")
Set sh2 = Worksheets("短冊")
maxrow1 = sh1.Cells(Rows.count, "S").End(xlUp).row 'S列の最大行取得
If maxrow1 < 2 Then Exit Sub
maxrow2 = sh2.Cells(Rows.count, "A").End(xlUp).row 'A列の最大行取得
If (maxrow2 + 1) Mod 7 <> 0 Then
MsgBox ("マス番号の行が不正")
Exit Sub
End If
max_box = ((maxrow2 + 1) \ 7) * 3
'短冊シートのマスをクリア
For i = 1 To max_box
Call clear_box(i)
Next
'バラシシートを処理
boxNo = 1
seqNo = 0
pv = ""
For wrow = 2 To maxrow1
If sh1.Cells(wrow, "S").Value = "" Then
If seqNo > 0 Then
boxNo = boxNo + 2
seqNo = 0
pv = ""
End If
Else
seqNo = seqNo + 1
If (seqNo Mod 4) <> 1 And pv <> sh1.Cells(wrow, "S").Value Then
y = (seqNo - 1) \ 4
seqNo = (y + 1) * 4 + 1
End If
If seqNo > 24 Then
boxNo = boxNo + 1
seqNo = 1
End If
'マス番号とマス内番号に対応する位置を取得
Call get_pos_in_box(boxNo, seqNo, box_row, box_col)
'該当位置へS列データを設定
sh2.Cells(box_row, box_col).Value = sh1.Cells(wrow, "S").Value
sh2.Cells(box_row, box_col).Interior.Color = sh1.Cells(wrow, "S").Interior.Color
pv = sh1.Cells(wrow, "S").Value
End If
Next
MsgBox ("完了")
End Sub

'指定マスクリア
Private Sub clear_box(ByVal box_no As Long)
Dim box_row As Long
Dim box_col As Long
Dim i As Long
For i = 1 To 24
Call get_pos_in_box(box_no, i, box_row, box_col)
sh2.Cells(box_row, box_col).ClearContents
sh2.Cells(box_row, box_col).Interior.Pattern = xlNone
Next
End Sub
'指定マス内の指定位置取得
Private Sub get_pos_in_box(ByVal box_no As Long, ByVal seq_no As Long, ByRef box_row As Long, ByRef box_col As Long)
Dim x1 As Long
Dim x2 As Long
Dim y1 As Long
Dim y2 As Long
y1 = (box_no - 1) \ 3
y2 = (seq_no - 1) \ 4
box_row = y1 * 7 + 1 + y2
x1 = (box_no - 1) Mod 3
x2 = (seq_no - 1) Mod 4
box_col = x1 * 5 + 2 + x2
End Sub

この回答へのお礼

ありがとうございました。
助かりました。

お礼日時：2022/04/20 19:14