エクセル関数 【 から 】 までの文字を抜き出す関数

こんにちは、以下のセルの文字から
【　オレンジジュース　】の部分だけ抜き出す関数を教えて下さい
ちなみにレモンジュース、ブドウジュースなど【内の文字が変わるので、使えるのは　【　と　】　のみです。

とっても美味しい【　オレンジジュース　】　果汁100％　

よろしくお願いします。

No.4 ベストアンサー 回答者： goomania 回答日時： 2023/06/05 13:05

「気は長く、数式は短く」を理想としたい私としては、No.2さんの

=MID(A1,FIND("【",A1),FIND("】",A1)-FIND("【",A1)+1)･･･①

という数式を

=MID(LEFT(A1,FIND("】",A1)),FIND("【",A1),300)･･･②

としたらよいのではないかと思います。

なお、No.3さんのご指摘のように【】がみつからなかったなど、エラーなら「空白」という場合は

=IFERROR(MID(LEFT(A1,FIND("】",A1)),FIND("【",A1),300),"")･･･③

とする方法もあります。

なお、今迄の回答は【】を含めた文字列を抽出するものですが、【】の中身だけを抽出したいという場合は

=TRIM(MID(LEFT(A1,FIND("】",A1)-1),FIND("【",A1)+1,300))･･･④

また、エラーなら「空白」という場合は

=IFERROR(TRIM(MID(LEFT(A1,FIND("】",A1)-1),FIND("【",A1)+1,300)),"")･･･⑤

とすることになります。

この回答へのお礼

こんにちは、気は長く、数式は短く
正解です！笑

ありがとうございます

お礼日時：2023/06/08 16:57

No.3 回答者： fujillin 回答日時： 2023/06/04 22:45

こんばんは

どこまで入力値が規格に沿っているかによりますが。。

一応、いろいろなケースに対応するなら少々長くなりますが、A1に元の文字列があるとして、
=IF(IFERROR(FIND("】",A1)-FIND("【",A1),0)<1,"",MID(A1,FIND("【",A1),FIND("】",A1)-FIND("【",A1)+1))

この回答へのお礼

ありがとうございます！
汎用性の高い方法なんですね、助かります！

お礼日時：2023/06/05 00:06

No.2 回答者： tatsumaru77 回答日時： 2023/06/04 22:42

A1セルに

とっても美味しい【　オレンジジュース　】　果汁100％
と記入してある場合、

表示したいセルに
=MID(A1,FIND("【",A1),FIND("】",A1)-FIND("【",A1)+1)
と入力してください。

【と】が両方そろってないとエラーなります。

この回答へのお礼

ありがとうございます！
出来ました

お礼日時：2023/06/05 00:05

No.1 回答者： taglet 回答日時： 2023/06/04 22:35

SEARCH関数で探して、MID関数で抜き出すと良いですね。

https://support.microsoft.com/ja-jp/office/searc …

この回答へのお礼

ありがとうございます！

お礼日時：2023/06/05 00:05