テキストファイルの各行を配列に格納するには？

お世話になります。vb6でテキストファイルを読み込み、各行を配列に格納するコードを教えて下さい。

No.1 ベストアンサー 回答者： miyuyu 回答日時： 2006/12/19 00:04

Private Sub Command1_Click()

Dim intLoop As Integer
Dim strLines() As String
strLines = Get_TextLines(Text1.Text)
For intLoop = LBound(strLines) To UBound(strLines)
Debug.Print strLines(intLoop)
Next intLoop
End Sub

Private Function Get_TextLines(ByVal strPathFileName As String) As String()
Dim intFileNum As Integer
Dim strLine() As String
Dim intArrayCount As Integer
intFileNum = FreeFile()
intArrayCount = 0
Open strPathFileName For Input As intFileNum
Do Until EOF(intFileNum)
ReDim Preserve strLine(intArrayCount)
Line Input #intFileNum, strLine(intArrayCount)
intArrayCount = intArrayCount + 1
Loop
Close intFileNum
Get_TextLines = strLine
End Function

この回答へのお礼

お返事ありがとうございます。

Open strPathFileName For Input As intFileNum

この行でファイル名または番号が不正ですエラーがでてしまうのですが、どうしてでしょうか？

お礼日時：2006/12/19 01:38

No.2 回答者： temtecomai2 回答日時： 2006/12/19 01:09

Microsoft Scripting Runtime を参照設定すれば事前バインディングでいくなら

Dim lines As Variant
Dim fso As New FileSystemObject
lines = Split(fso.OpenTextFile("D:\test.txt").ReadAll, vbCrLf)
てな感じ。

参照設定せずに遅延バインディングでいくなら
Dim lines As Variant
Dim fso As Object
Set fso = CreateObject("Scripting.FileSystemObject")
lines = Split(fso.OpenTextFile("D:\test.txt").ReadAll, vbCrLf)
てな感じ。

この回答へのお礼

勉強になりました。
ありがとうございます。

お礼日時：2006/12/19 01:41