ウィンドウズXPで１６進のダンプリストを作成したい

ウィンドウズXPで１６進のダンプリストを作成する方法があれば教えてください。
詳しくは言えませんが、用途はサーバへの簡易なチェックです。

No.2 ベストアンサー 回答者： yambejp 回答日時： 2007/01/23 18:06

ダンパーとしてはstirlingが有名ですね。

参考URL：http://www.vector.co.jp/soft/win95/util/se079072 …

No.5 回答者： noname#25383 回答日時： 2007/01/24 17:39

debugコマンドはどうですかね。

http://www.atmarkit.co.jp/fwin2k/win2ktips/775he …

No.4 回答者： sakusaker7 回答日時： 2007/01/24 15:56

wsh を使ってよいのなら、スクリプトで簡単なダンプコマンドを作れます。

wshも禁止されていたらちょっと手が出ないですね。

Option Explicit

Dim objADOST
Dim sFile
Dim oArgs

Set oArgs = WScript.Arguments

If oArgs.Count = 0 Then
___WScript.Echo "ファイルを指定してください"
___WScript.Quit
Else
___sFile = oArgs(0)
End If

Set objADOST = CreateObject("ADODB.Stream")

objADOST.Type = 1 'adTypeBinary
objADOST.Open
objADOST.LoadFromFile sFile
objADOST.Position = 0

Dim byData
Dim i
Dim sLine

i = 0
Do Until objADOST.EOS = True

___byData = objADOST.Read(1)
___sLine = sLine & " " & Right("0" & Hex(AscB(byData)), 2)

___If (i Mod 16) = 15 Then
______Call PutLine(LTrim(sLine), Int(i/16))
______sLine = ""
___End If

___i = i + 1

Loop

If sLine <> "" Then
______Call PutLine(LTrim(sLine), Int(i/16))
End If

objADOST.Close

Set objADOST = Nothing

Sub PutLine(sLine, iOffset)
______WScript.StdOut.Write Right("0000000" & Hex(iOffset*16), 8) & " "
______WScript.StdOut.WriteLine sLine
End Sub

行頭の_をスペースで置き換えてから適当な名前でファイルにセーブして、
コマンドプロンプトで

cscript //nologo スクリプト名 ダンプしたいファイルの名前

で、
00000000 47 49 46 38 39 61 14 00 23 00 B3 00 00 FF 9A 00
00000010 31 9A 63 FF 30 00 BF BF 00 00 00 BF BF 00 BF 00
00000020 BF BF C0 C0 C0 80 80 80 FF 00 00 00 FF 00 FF FF
00000030 00 00 00 FF FF 00 FF 00 FF FF FF FF FF 2C 00 00
00000040 00 00 14 00 23 00 40 04 37 F0 C9 49 AB BD 98 86
00000050 CD BB F7 59 28 8E 64 05 9C 68 AA AA 65 EB BE 70
00000060 2C 3F 5F 5D 0B 78 AE EF FB EC FF C0 A0 30 B6 2A
00000070 16 65 B6 A4 72 C9 54 CA 78 50 E8 70 4A 75 45 00
00000080 00 3B

こんな感じの出力になります。
フォーマットが気に入らないなどあったら好きにいじってください。

No.3 回答者： sakusaker7 回答日時： 2007/01/24 01:22

何か条件はないのでしょうか?

たとえばフリーウェアの類は持ち込み厳禁で、あらかじめxpにある
コマンドでどうにかしないといけないとか。

この回答へのお礼

お答えありがとうございます。
仰るとおり、持ち込みはできればしたくないです。
先の方があげていただいたプログラムも
安全が確認できれば使用したいとおもいますが…

お礼日時：2007/01/24 11:58

No.1 回答者： Oh-Orange 回答日時： 2007/01/23 17:07

★上から２つ目の『簡単ダンプ』というソフトはどう？

・http://www5a.biglobe.ne.jp/~NCPRO/soft3.htm→『簡単ダンプ』
・以上。おわり。

参考URL：http://www5a.biglobe.ne.jp/~NCPRO/soft3.htm