シートAとシートBのあるセルの合計をシートCに出したい

Office2003のVBAを勉強中です。

2つのエクセルファイル(ファイルA、ファイルB)があります。
ファイルA、Bにはシートが一つづつあり、そこには同じフォーマットで表が書かれています。

ファイルA、Bのシートに書かれている表の合計を新規に作成したエクセルファイルCに書き込みたい場合、皆さんならどのようにされるでしょうか？

僕は下記のように考えました。
１．ファイルCを作成
２．ファイルAの対象シートをファイルCのシート1へコピー
３．ファイルBの対象シートをファイルCのシート2へコピー
４．ファイルCのシート３にシート１とシート２の合計を計算表示

「そんな手間な事をせずとももっと・・・」だとかあるようでしたら、
皆さんのご意見をお聞かせください。

それともう一つ、シート１の指定セルとシート２の指定セルの合計をシート３の指定セルに計算表示するのはどのようなロジックを書けばよいのでしょうか？

No.1 回答者： hana-hana3 回答日時： 2007/04/17 16:31

合計だけ必要なら・・・

コピーして貼付けをする時に「形式を選択して貼付け」という機能があります。

ひな形を作成しておいて
1．ファイルAの表をファイルCのシート1へ[値]コピー
2．ファイルBの表をファイルCのシート1へ[加算]コピー

No.2 回答者： chie65536 回答日時： 2007/04/17 16:31

１．ファイルＣを作成

２．式に「=SUM('C:\My Documents\excel\[ファイルA.xls]Sheet1'!A1:E20,'C:\My Documents\excel\[ファイルB.xls]Sheet1'!B2:F50)」と入力

以上。

No.3 回答者： zap35 回答日時： 2007/04/17 16:38

ブックＡ、ブックＢを開いた状態でブックＡをアクティブにする。

1)ブックＡに新規シート追加
2)新規シートにブックＡのSheet1とブックＢのSheet1のデータを統合
3)新規シート（ActiveSheet）を新規ブックに移動
4)新規ブックをブックＣとして保存
の操作をマクロ記録すると以下のようなマクロができあがります。（少し余分な行を削除してあります）

この方法だけが正しいわけではありませんので、あくまで「ご参考」です。
マクロはブックＡ、もしくはブックＢの標準モジュールシートに貼り付けてください。

Sub Macro1()
　Worksheets.Add
　Range("B2").Select
　Selection.Consolidate Sources:=Array("[BookA.xls]Sheet1!R2C2:R3C3", _
　　　"[BookB.xls]Sheet1!R2C2:R3C3"), Function:=xlSum, 　　TopRow:=False, LeftColumn:= _
　　　　False, CreateLinks:=False
　ActiveSheet.Move
　ActiveWorkbook.SaveAs Filename:="Z:\BookC.xls", FileFormat:=xlNormal, _
　　　Password:="", WriteResPassword:="", ReadOnlyRecommended:=False, _
　　　CreateBackup:=False
End Sub

No.4 ベストアンサー 回答者： Wendy02 回答日時： 2007/04/17 20:36

こんばんは。

>Office2003のVBAを勉強中です。

私のいつもの持論なのですが、VBA勉強中は、なるべく、ワークシートのごちゃごちゃしたものには、手を出さないほうがよいですね。1年掛かるものが、2年になってしまいます。ワークシートを扱うと、結構つまらないことで振り回されるので、「ロジック」とは関係のないところに行ってしまいます。

とはいえ、実務上の問題は避けては通れないのですから、軽く流す程度にしたほうがよいと思います。

>僕は下記のように考えました。
1～4
それで良いとは思うけれど、それを現実化させるというのは、実は、意外とつまらない部分でつまづくことが多いかもしれません。

まったく、同じ造りのシートだとしたら、#3の[統合=Consolidation] が最も便利かなって思います。

ただ、元のデータのブックが開けてある状態なら、意外に単純な方式で出来ます。C列だけを計算すればよいのですね。

1～3行目まであるデータで、A列,B列が項目と明細が入っていて、C列が計算行です。

ひとつのSheet1は、
　A　　　B　　　 C
日時　　名前　　金額
20061201　　Aさん　　100
20061202　　Cさん　　200
20061203　　Bさん　　100

同じようなシートで、金額だけ違うような場合は、

マクロは、以下のようになります。

Sub TestSample1()
Dim wb1 As Workbook
Dim wb2 As Workbook
Dim newWb As Workbook
Set wb1 = Workbooks("TEST061.XLS")
Set wb2 = Workbooks("TEST062.XLS")

Set newWb = Workbooks.Add
With wb1.Worksheets("Sheet1")
'項目のコピー
　.Range("A1", .Range("A65536").End(xlUp).Offset(, 2)).Copy _
　 newWb.Worksheets(1).Range("A1")
End With

With newWb.Worksheets(1)
　 'C列に数式を作る
　 .Range("A2", .Range("A65536").End(xlUp)).Offset(, 2).FormulaLocal _
　　 = "=[" & wb1.Name & "]Sheet1!RC +[" & wb2.Name & "]Sheet1!RC"
　　'値貼り付け
　 .Range("A2", .Range("A65536").End(xlUp)).Offset(, 2).Value = _
　 .Range("A2", .Range("A65536").End(xlUp)).Offset(, 2).Value
　　'合計を出す
　 .Range("A65536").End(xlUp).Offset(1, 2).FormulaLocal = _
　 "=SUM(" & .Range("A2", .Range("A65536").End(xlUp)).Offset(, 2).Address(0, 0) & ")"
　
End With
End Sub

なお、保存は手動でしてください。