範囲内の列から、一番下の数値又は文字を表示する方法

例　Ａ1～5のみの１行の表があるとします。

　　Ａ
１　1
２　
３　2
４　

５　2

※Ａ1セル表示は「1」、Ａ3には「2」、Ａ2及びＡ4は空白と考えてください。
※Ａ1～Ａ4内の数値は、他の式の計算結果の値が入っていますので実際は関数です。

ここで質問ですが、Ａ5セルにＡ1～Ａ4の範囲内で一番下のセルに入っている数値又は文字（今回はＡ3の「2」）を、Ａ5セル内に表示する方法が知りたいです。空白のセルもあります。

宜しくお願いします。

No.1 ベストアンサー 回答者： masa_019 回答日時： 2009/07/30 19:48

こんにちは。

ちょっと考えてみましたが、こんなのしか思いつかないです。
とりあえず、

=INDIRECT("A" & SUMPRODUCT(MAX(((A1:A4<>"")*ROW(A1:A4)))))

ではいかがでしょう。

この回答への補足

補足：ゼロ値のチェックは外してあります。

ですのでＡ1～Ａ4セル内には関数が入っている為、実際空白でしても値として「0」です。
範囲は違いますが、以下の通り０以上？になるように当て嵌めましたら０以外の最下位列の数値を表示させることが出来ました。

=INDIRECT("m"&SUMPRODUCT(MAX(((M6:N61<>0)*ROW(M6:N61)))))

因みに最後の括弧閉じはもう一つ必要でした。

＃1さんのおかげで無事解決出来ましたので一反締め切ります。
皆様有難うございました。

補足日時：2009/07/31 08:40

No.3 回答者： tom04 回答日時： 2009/07/30 20:51

こんばんは！

すでに回答は出ていますが・・・

他の方法の一例です。

配列数式になってしまいますので
↓の数式をコピー＆ペーストしたあとに
F2キーを押すか、数式バー内で一度クリックして編集可能にした後に
Shift＋Ctrl＋Enterキーを押してください。
数式の前後に　｛　｝　マークが入り、配列数式になります。

A5セルに
=INDEX(A1:A4,LARGE(IF(A1:A4<>"",ROW(A1:A4)),ROW(A1)))

尚、エラー処理はしていませんのですべてのセルが空白の場合はエラーになります。

以上、参考になれば幸いです。m(__)m

この回答への補足

回答有難うございます。

全てのセルが空白の場合も有ります。
ので、エラー処理が含まれた式を希望します。IF関数ですかね？

他の皆さんの式も時間が無いため後で試させていただきます。

補足日時：2009/07/31 07:52

この回答へのお礼

すいません、式を当て嵌めてみましたがエラーになってしまいます＞＜

理解力だ足りなくて申し訳ないです。

お礼日時：2009/07/31 08:51

No.2 回答者： maron--5 回答日時： 2009/07/30 19:55

◆一番下の数値

=LOOKUP(10^10,A:A)

◆一番下の文字列
=LOOKUP("ーー",A:A)

◆一番下の数値
=LOOKUP(1,0/(A1:A100<>""),A1:A100)

この回答へのお礼

以下のとおり、無事解決することが出来ました。

回答有難うございました。

お礼日時：2009/07/31 08:52