複数のチェックボックス

Question

困ってます。
前回ボタンクリックでチェックボックス768個を全部ONにしたりOFFにしたりするプログラムを教えてもらい何とかできたのですが、768個のチェックボックスを1個1個押したときのプログラムを一つにまとめたい場合は、どうすればよかったのでしょうか。
前回教えてもらった物をヒントに作ったのですが思った動きをしません。

初心者にわかりやすく教えてもらえますか。
ボタンクリックと同じ場所に飛ばしているせいか
　Select Case DirectCast(sender, Button).Name
のbuttonでエラーが出ることが分かっています。
ただいろいろやりましたがSelectCase文で行っても1個のチェックボックスには反応しますがほかのチェックボックスは無視します。

よろしくお願いします。

Wizard_Zero · Accepted Answer

CheckBoxをButtonにキャストしようとしていることが原因のように思えます。

CheckBoxとButtonを50個ずつ生成し、同じイベントハンドラを共用するサンプルを書いてみたので参考にしてみてください。
CheckBoxの名前は CheckBox00, CheckBox01 ・・・としてあります。
Buttonの名前は Button00, Button01 ・・・としてあります。


Public Class Form1

    Private ctlCheck As CheckBox() = {}
    Private ctlButton As Button() = {}

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Array.Resize(ctlCheck, 50)
        Array.Resize(ctlButton, 50)

        For i As Integer = 0 To 49
            ' CheckBoxの作成
            ctlCheck(i) = New CheckBox()
            ctlCheck(i).Name = "Check" + i.ToString("D2")
            ctlCheck(i).Text = i.ToString()
            ctlCheck(i).Location = New Point(4, i * 20)
            ctlCheck(i).Size = New Size(30, 18)

            ' Buttonの作成
            ctlButton(i) = New Button()
            ctlButton(i).Name = "Button" + i.ToString("D2")
            ctlButton(i).Text = i.ToString()
            ctlButton(i).Location = New Point(80, i * 20)
            ctlButton(i).Size = New Size(30, 18)

            ' イベントハンドラの登録(Clickイベントを同じメソッドで)
            AddHandler ctlCheck(i).Click, AddressOf ControlClick
            AddHandler ctlButton(i).Click, AddressOf ControlClick

            Panel1.Controls.Add(ctlCheck(i))
            Panel1.Controls.Add(ctlButton(i))
        Next
    End Sub

    Private Sub ControlClick(ByVal sender As Object, ByVal e As EventArgs)

        ' コントロールの種類で振り分ける

        If TypeOf sender Is Button Then ' senderがButtonの場合

            Select Case DirectCast(sender, Button).Name
                Case "" ' 割愛
            End Select

        ElseIf TypeOf sender Is CheckBox Then ' senderがCheckBoxの場合

            Select Case DirectCast(sender, CheckBox).Name
                Case "" ' 割愛
            End Select

        End If

        ' または

        ' ButtonもCheckBoxもControlから派生しているので、ControlにキャストすればどちらでもNameを取れる
        Select Case DirectCast(sender, Control).Name
            Case "" ' 割愛
        End Select

    End Sub

End Class


イベントハンドラをコントロールで分けるのであれば
AddHandler ctlCheck(i).Click, AddressOf CheckBoxClick
AddHandler ctlButton(i).Click, AddressOf ButtonClick

として、CheckBocClickメソッドとButtonClickメソッドを用意してください。引数は上記サンプルのControlClickメソッドと同じです。

Wizard_Zero · Answer

補足のコードを見る限り、a=0のときは
bb = bb + 1
aa(x, a) = bb
と
bb = 0
の２種類に分かれるようですね。さらに、bb = 0とするのは常に定数のようなので、

If a = 0 Then
　　Select Case x
　　　　Case 8, ?, ?, ?, 1148  ' ←ここに bb = 0 にする定数をkカンマ区切りで並べる
　　　　　　bb = 0
　　　　Case Else
　　　　　　bb += 1
　　　　　　aa(x, a) = bb
　　End Select
End If

といった具合にできると思います。次に、a = 1 については特定の値のときに cc = cc + 1 とし、すべてのパターンで aa(x, a) = cc が実施されるように見えます。

If a = 1 Then
　　Select Case x
　　　　Case 0, 10, ?, ?, ?
　　　　　　cc += 1
　　End Select

　　aa(x, a) = cc
End If

といった具合にできそうです。
条件判定はもっと複雑なのかもしれませんが全容が見えないのでご提示されたコードの範囲で考えてみました。
配列の上限値とループの上限値が異なるのが気になりますが、コピペミスですかね？（このまま動かすと配列限界を超えます）

またこの処理がチェックボックスの変動とどのように関連するのかも不明です。どのようなことをしたいのか、が明確に教えてもらえればより解決に近い回答が得られると思いますよ。

複数のチェックボックス

CheckBoxをButtonにキャストしようとしていることが原因のように思えます。

補足のコードを見る限り、a=0のときは

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング