エクセルでの抽出の仕方

２桁、３桁の数字と３桁にだけついているアルファベットがあります。数字はそのままでアルファベットを消すというか数字だけ抽出する方法がありましたら教えてください。

例
７５
１００
１００Ｍ
１００Ｂ
５５

で、数字だけにしたいです。

No.9 ベストアンサー 回答者： maruru01 回答日時： 2003/05/19 17:18

No.4は間違いでした。

少し手順が増えます。
まず、まったく関係ない列（他のシートでもOK）に、

A
B
C
・
・
・
Y
Z

と半角大文字のアルファベットを全部（26文字）入力し、その範囲を範囲選択します。
そしたら、メニューの[挿入]→[名前]→[定義]でその範囲に名前を付けます。
とりあえず「アルファベット」という名前にします。
そしたら、表示するセルに、

=LEFT(A1,MIN(FIND(アルファベット,UPPER(ASC(A1)) & CONCATENATE(アルファベット)))-1)

と入力して、No.4と同様に、[Ctrl]＋[Shift]＋[Enter]で配列数式にします。

もしこれでダメなら、実際にダメだった例を載せて下さい。
(1)元の値
(2)期待する値
(3)実際に関数で変換された値

この回答へのお礼

できました。こんなに親切に教えていただき
本当にありがとうございました。

お礼日時：2003/05/19 17:52

No.8 回答者： AQUALINE 回答日時： 2003/05/19 17:10

No5の修正です。

今度はいかが？

=VALUE(SUBSTITUTE(A1,IF(ISNUMBER(VALUE(RIGHT(A1,1))),"",RIGHT(A1,1)),""))

No.7 回答者： taisuke555 回答日時： 2003/05/19 16:43

#6の訂正です。

=VALUE(IF(ISNUMBER(VALUE(A1)),A1,LEFT(A1,LEN(A1)-1)))
でどうでしょう。

No.6 回答者： taisuke555 回答日時： 2003/05/19 16:33

数字の後のアルファベットは１文字のみですか？

=VALUE(IF(ISNUMBER(A1),A1,LEFT(A1,LEN(A1)-1)))
でどうでしょう？

No.5 回答者： AQUALINE 回答日時： 2003/05/19 14:53

失礼。

数字にするんでしたね。
下記では数字ですが文字列としての数字表示でした。

通常に数字として表示するなら

=VALUE(SUBSTITUTE(A1,IF(ISNUMBER(RIGHT(A1,1)),"",RIGHT(A1,1)),""))

にしてください。

この回答への補足

ん～、予定の数字にならない。。。

補足日時：2003/05/19 15:11

No.4 回答者： maruru01 回答日時： 2003/05/19 14:51

>２桁にもアルファベットついてました。

とりあえず、何桁かの数字＋アルファベット（ない場合もあり）というパターンをすべて、数字のみ取り出す方法です。

A1にデータがあるとすると、取り出すセルの数式バーに、

=LEFT(A1,MAX(IF(ISERROR(FIND({0,1,2,3,4,5,6,7,8,9},ASC(A1))),0,FIND({0,1,2,3,4,5,6,7,8,9},ASC(A1)))))

と入力して、まだ数式バーにカーソルがある状態で、[Ctrl]と[Shift]を押しながら[Enter]を押します。
（数式の両端に「{}」が付き、配列数式になります。）

この回答への補足

予定どうりにいかない・・・

補足日時：2003/05/19 15:15

No.3 回答者： AQUALINE 回答日時： 2003/05/19 14:47

A列にデータが入っており、数字の末尾の１文字だけが文字であった場合、その文字を消します。

文字が無い場合はそのまま表示します。数字は何桁にでも対応できます。

=SUBSTITUTE(A1,IF(ISNUMBER(RIGHT(A1,1)),"",RIGHT(A1,1)),"")

この式を表示したいセルに入れて、そのまま下にコピーしてください。

この回答への補足

100が10になっちゃう・・・

補足日時：2003/05/19 15:23

No.2 回答者： maruru01 回答日時： 2003/05/19 13:33

こんにちは。

maruru01です。

No.1の人の補足ですが、
IF文による条件分岐は不要です。

=VALUE(LEFT(A1,3))

でも同じ結果になります。

この回答への補足

ありがとうございます。すみません、質問自体間違えてました。２桁にもアルファベットついてました。どうすればよいでしょうか？

補足日時：2003/05/19 14:08

No.1 回答者： moon_myu 回答日時： 2003/05/19 13:29

A列にデータが入っているとしますね。

A列の数値が3桁以上のみ末尾にアルファベットが付くんですよね。

=IF(A1>=100,VALUE(LEFT(A1,3)),A1)

という関数が使えますが、どうでしょうか？

この回答への補足

すみません。質問自体間違えてました。
良く観たら２桁の数字にもアルファベットがついてました。どうすればよいでしょうか？

補足日時：2003/05/19 14:07