ＶＢＡのコピー

ＶＢＡのコピー

Dim xls As New Excel.Application
Dim wbk As New Excel.Workbook

Dim sh3 As Worksheet


Set sh3 = Worksheets("全")

sh3.Activate


sh3.Range("A1:Z65536").Select
Selection.Clear

Set wbk = xls.Workbooks.Open("\\***.***.*.***\管理\全データ抽出.xls")


wbk.Worksheets("全").Activate 'ワークシートをアクティブにする

wbk.Worksheets("全").Range("A1:Z65536").Copy 'コピーする

'ActiveSheet.Paste Destination:=Worksheets("全").Range("A1") '貼り付ける

Worksheets("全").Range("A1").PasteSpecial Paste:=xlPasteValues



wbk.Close SaveChanges:=False


'Worksheets("メイン").Cells(1, 1).Select

を実行すると　『wbk.Close SaveChanges:=False』のところで

クリップボードに大きな情報があります。・・・・

と言うメッセージがでて必ずとまってしまうのですが

メッセージをでないようにしたいのですが

教えてください。お願いします。

No.2 ベストアンサー 回答者： end-u 回答日時： 2010/03/22 15:01

ExcelVBAでの話という認識でいいですか？

『クリップボードに大きな情報があります...』というメッセージそのまま、
コピーモードが解除されていないわけですから
Application.CutCopyMode = False
wbk.Close SaveChanges:=False
とすれば良いです。
Excelのマクロ記録を活用すると、コピー時によく記録される記述です。

また
>Worksheets("全").Range("A1").PasteSpecial Paste:=xlPasteValues
これはActiveWorkbookのWorksheets("全")に対する処理になってしまいますから
目的の処理とは違うのでは？
変数sh3を使いましょう。

Dim wbk As Workbook
Dim sh3 As Worksheet

Set sh3 = ThisWorkbook.Worksheets("全") 'or ActiveWorkbook.Worksheets("全")
sh3.UsedRange.Clear
Set wbk = Workbooks.Open(Filename:="\\***.***.*.***\管理\全データ抽出.xls", ReadOnly:=True)
wbk.Worksheets("全").UsedRange.Copy
sh3.Range("A1").PasteSpecial Paste:=xlPasteValues
Application.CutCopyMode = False
wbk.Close SaveChanges:=False

Set sh3 = Nothing
Set wbk = Nothing

画面のちらつきが気になるようであれば
Application.ScreenUpdating
で制御できます。（ヘルプ参照のこと）

この回答へのお礼

すごい完璧な答えありがとうございます。

勉強になります。

お礼日時：2010/03/24 12:36

No.1 回答者： 0909union 回答日時： 2010/03/21 18:32

この程度ならヘルプに出てきます。

ＶＢＡのエディターで、ヘルプを起動し、”SaveChanges”や”close”などのページに関連項目として下記のようにでています。

.Application.DisplayAlerts = False

ヘルプをもっと活用しましょう。私はヘルプだけで、１００％作っています。