EXCEL VLOOKUPの結合時の表示について

EXCEL計算式　VLOOKUPについて教えてください。


具体的には添付データ（エクセル.jpg）を見て頂きたいのですが、

(1)のような社員データ一覧があるときに、VLOOKUP機能を使って(2)にあるような
社員カードを作りたいと思っています。

資格欄と研修履歴欄のように複数段あるときには、2段目以降どのような計算式
を入れればいいのか悩んでいます。

一段目の”普通車運転免許”には氏名や性別欄と同様に
”=VLOOKUP(C18,A3:E14,4,FALSE)”の計算式を入れています。

２、３段目以降を同様に表示させたい場合はどのようにすればいいのでしょうか。

INDEXとか、MATCHを使えばいいとは聞きましたが
具体的な事が分かりません。

どうぞよろしくお願いします。

No.3 回答者： CoalTar 回答日時： 2013/01/24 15:45

No2です。

肝心なところの説明が間違っていましたm(_ _)m

MATCH関数でIDを検索する
D18セル =MATCH(C18,A:A,0)
D19セル =INDEX(B:B,$D$18)
D20セル =INDEX(C:C,$D$18)
D21セル =INDEX(D:D,$D$18)&""
D22セル =INDEX(D:D,$D$18+1)&""
以下同様

D18セル で何行目にあるかを検索しています。
C18セルの値を変えて、変化を確認してください

この回答へのお礼

詳しくご説明頂き有難うございました。
実際に値を投入して変化を確認し、理解しました。

無事表作成も出来ました。

お礼日時：2013/01/24 16:06

No.2 回答者： CoalTar 回答日時： 2013/01/24 15:39

1レコードにつき4行分あるとします。

(ふつうは1レコード(件)につき1行使う。

まずは INDEXの基礎から
IDが連番なら
C19セル =INDEX(B:B,$C$18*4-1)
C20セル =INDEX(C:C,$C$18*4-1)
C21セル =INDEX(D:D,$C$18*4-1)&""
C22セル =INDEX(D:D,$C$18*4)&""
C23セル =INDEX(D:D,$C$18*4+1)&""
C24セル =INDEX(D:D,$C$18*4+2)&""
C25セル =INDEX(E:E,$C$18*4-1)&""
C26セル =INDEX(E:E,$C$18*4)&""
C27セル =INDEX(E:E,$C$18*4+1)&""
C28セル =INDEX(E:E,$C$18*4+2)&""

MATCH関数でIDを検索する
D18セル =INDEX(B:B,$D$18)
D19セル =INDEX(B:B,$C$18*4-1)
D20セル =INDEX(C:C,$D$18)
D21セル =INDEX(D:D,$D$18)&""
D22セル =INDEX(D:D,$D$18+1)&""
以下同様

INDEX/MATCHを組み合わせて
=INDEX(B:B,MATCH($C$18,A:A,0))

ちなみに&""はセルを文字列にすることで 未記入欄の0の表示を消すため

No.1 回答者： keithin 回答日時： 2013/01/24 15:39

まず基本の理解として，結合されたセルのデータは結合セル範囲の一番左上のセルにあります。

たとえばＡ３，Ａ７，Ａ１１セルですね。

今欲しい，例えば資格のデータはＡ３に対してＤ３，Ｄ４に，Ａ７に対してＤ７，Ｄ８…に，それぞれあります。Ｅ列も同じですね。


以上の理解から，
Ｃ２１には
=INDEX(D:D,MATCH(C18,A:A,0))&""
Ｃ２２には一つ下の
=INDEX(D:D,MATCH(C18,A:A,0)+1)&""
Ｃ２３には二つ下の
=INDEX(D:D,MATCH(C18,A:A,0)+2)&""
のようにしておきます。


＋１とか＋２とかイチイチ式を変えるのがメンドクサイと思うなら，
Ｃ２５には
=INDEX(E:E,MATCH($C$18,A:A,0)+ROW(C1)-1)&""
と記入し，下向けにコピーします。上述の式とどっちが簡単か，好きなやり方で作成して下さい。

この回答へのお礼

具体的にご説明いただき有難うございました。
良く理解できました。

実際に問題無く表作成ができました。

お礼日時：2013/01/24 16:04